Kalkylbladsfunktioner

Det här avsnittet innehåller beskrivningar av funktioner för kalkylblad tillsammans med exempel.

[text/scalc/01/func_error_type.xhp#error_type_head not found].

Returns a number representing a specific Error type, or the error value #N/A, if there is no error.

ADRESS

Returnerar en celladress (referens) som text, enligt angivet rad- och kolumnnummer. Om du vill kan du bestämma om adressen ska tolkas som en absolut adress (till exempel $A$1), som en relativ adress (som A1) eller i blandad form (A$1 eller $A1). Du kan också ange tabellens namn.

För interoperabilitet stöder ADRESS- och INDIREKT-funktionerna en optimal parameter för att specificera om R1C1-adressnotationen istället för den valiga A1-notation bör användas.

I ADRESS infogas parametern som den fjärde parametern och den valfria parametern flyttas till femte position.

I INDIREKT läggs parametern till som den andra parametern.

I båda funktionerna, om argumentet anges med värdet 0, används R1C1-notationen. Om argumentet inte ges eller har ett annat värde än 0 används A1-notationen.

Vid R1C1-notation returnerar ADRESS adressträngar som använder utropstecken '!' som avgränsare för tabellnamn, och INDIREKT beräknar att utropstecknet ska vara avgränsare för tabellnamn. Båda funktionerna använder fortfarande '.' som avgränsare för tabellnamn med A1-notation.

When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.

Om ADRESS-funktionerna har en fjärde parameter kommer denna att tas bort när ett dokument sparas i ODF 1.0/1.1-format.

ADDRESS(Row; Column [; Abs [; A1 [; "Sheet"]]])

Rad representerar radnumret för cellreferensen

Kolumn representerar kolumnnumret för cellreferensen (talet, inte bokstaven)

Abs anger referensens typ:

1: absolut ($A$1)

2: Rad absolut, kolumn relativ (A$1)

3: Rad relativ, kolumn absolut ($A1)

4: Relativ (A1)

A1 (valfritt) - om du anger 0 används R1C1-notation. Om den här parametern saknas eller har ett annat värde än 0 så används A1-notation.

Blad representerar bladets namn. Det måste sättas inom dubbla citattecken.

Exempel

=ADRESS(1;1;2;"Blad2") returnerar följande: Blad2.A$1

If the formula above is in cell B2 of current sheet, and the cell A1 in sheet 2 contains the value -6, you can refer indirectly to the referenced cell using a function in B2 by entering =ABS(INDIRECT(B2)). The result is the absolute value of the cell reference specified in B2, which in this case is 6.

DDE

Returnerar resultatet av en DDE-baserad länk. Om innehållet i det länkade området eller avsnittet ändras så ändras också det returnerade värdet. Om du vill visa de uppdaterade länkarna måste du ladda om tabellen eller välja Redigera - Länkar. Länkar mellan olika plattformar, till exempel från en Collabora Office-installation på en Windows-dator till ett dokument som är skapat på en Linux-dator, är inte tillåtna.

DDE("Server"; "File"; "Range" [; Mode])

Server is the name of a server application. Collabora Office applications have the server name "soffice".

fil är namnet på filen, inklusive dess fullständiga sökväg.

område är ett område ur vilket data ska läsas.

Läge är en valfri parameter som styr hur data omvandlas till tal av DDE-servern.

Läge	Effekt
0 eller saknas	Talformat ur "standard"-cellformatmallen
1	Data tolkas alltid med standardformatet för engelska (US)
2	Data övertas som text, ingen omvandling till tal

=DDE("soffice";"c:\office\document\data1.ods";"sheet1.A1") reads the contents of cell A1 in sheet1 of the Collabora Office Calc spreadsheet data1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Today's motto") returns a motto in the cell containing this formula. First, you must enter a line in the motto.odt document containing the motto text and define it as the first line of a section named Today's Motto (in Collabora Office Writer under Insert - Section). If the motto is modified (and saved) in the Collabora Office Writer document, the motto is updated in all Collabora Office Calc cells in which this DDE link is defined.

FELTYP

Returnerar talet som motsvarar ett felvärde som uppstår i en annan cell. Med hjälp av det här talet kan du skapa en meddelandetext.

FELTYP(referens)

referens är en referens till en cell i vilken ett fel har rapporterats.

Om cell A1 visar Err:518, returnerar funktionen =FELTYP(A1) nummer 518.

ORG.OPENOFFICE.ERRORTYPE

FORMAT

Applies a style to the cell containing the formula. After a set amount of time, another style can be applied. This function always returns the value 0, allowing you to add it to another function without changing the value. Together with the CURRENT function you can apply a color to a cell depending on the value. For example: =...+STYLE(IF(CURRENT()>3;"red";"green")) applies the style "red" to the cell if the value is greater than 3, otherwise the style "green" is applied. Both cell formats, "red" and "green" have to be defined beforehand.

STYLE("Style" [; Time [; "Style2"]])

Format är namnet på en cellformatmall som tilldelas cellen. Mallarnas namn ska omges av citattecken.

tid är ett valfritt tidsintervall i sekunder. Om den här parametern saknas byts formatmallen inte ut efter en viss tid.

Format2 är det valfria namnet på en cellformatmall som tilldelas cellen efter en viss tid. Om den här parametern saknas används "Standard".

I Collabora Office Calc-funktioner kan de parametrar som markeras som "valfria" bara utelämnas när inga efterföljande parametrar finns. I till exempel en funktion med fyra parametrar, där de två sista parametrarna markeras som "valfria", kan du utelämna parameter 4 eller parametrarna 3 och 4, men inte utelämna enbart parameter 3.

=FORMAT("Osynlig";60;"Standard") formaterar cellen i transparent format under 60 sekunder efter att dokumentet räknats om eller lästs in. Sedan används standardformatet. Båda cellformaten måste definieras i förväg.

Since STYLE() has a numeric return value of zero, this return value gets appended to a string. This can be avoided using T() as in the following example:

="Text"&T(FORMAT("MittFormat"))

Det finns ett ytterligare exempel i AKTUELL().

ORG.OPENOFFICE.STYLE

FÖRSKJUTA

Returnerar värdet i en cell med en förskjutning på ett visst antal rader och kolumner från en given referenspunkt.

OFFSET(Reference; Rows; Columns [; Height [; Width]])

Referens är den referens från vilken funktionen eftersöker den nya referensen.

Rader är det antal rader som referensen flyttades uppåt (negativt värde) eller nedåt.

Rader är det antal rader som referensen flyttades uppåt (negativt värde) eller nedåt.

Höjd (valfritt) är den vertikala höjden för ett område som startar vid den nya referenspositionen.

Bredd (valfritt) är den horisontella bredden för ett område som startar vid den nya referenspositionen.

Argumenten Rader och Kolumner behöver inte innebära noll eller negativ startrad eller kolumn.

Argumenten Höjd och Bredd behöver inte innebära noll eller negativ beräkning av rader eller kolumner.

I Collabora Office Calc-funktioner kan de parametrar som markeras som "valfria" bara utelämnas när inga efterföljande parametrar finns. I till exempel en funktion med fyra parametrar, där de två sista parametrarna markeras som "valfria", kan du utelämna parameter 4 eller parametrarna 3 och 4, men inte utelämna enbart parameter 3.

=FÖRSKJUTA(A1;2;2) returnerar värdet i cell C3 (A1 flyttades ner två rader och två kolumner). Om C3 innehåller värdet 100 returnerar den här funktionen värdet 100.

=FÖRSKJUTA(B2:C3;1;1) returnerar en referens till B2:C3 som har flyttats ner 1 rad och 1 kolumn till höger (C3:D4).

=FÖRSKJUTA(B2:C3;-1;-1) returnerar en referens till B2:C3 som flyttats upp av 1-rad och en kolumn till vänster (A1:B2).

=FÖRSKJUTA(B2:C3;0;0;3;4) returnerar en referens till B2:C3 med ändrad storlek till 3 rader och 4 kolumner (B2:E4).

=FÖRSKJUTA(B2:C3;1;0;3;4) returnerar en referens till B2:C3 som har flyttats ner en rad och ändrat storlek till 3 rader och 4 kolumner (B2:E4).

=SUMMA(FÖRSKJUTA(A1;2;2;5;6)) anger summan av det område som startar i cell C3, är 5 rader högt och 6 kolumner brett (område=C3:H7).

GETPIVOTDATA

Funktionen GETPIVOTDATA returnerar ett resultatvärde från en pivottabell. Värdet specificeras med hjälp av fält- och objektnamn, och förblir därför giltigt även om layouten för pivottabellen ändras.

Två olika syntaxdefinitioner får användas:

GETPIVOTDATA(TargetField; pivot table[; Field 1; Item 1][; ... [Field 126; Item 126]])

or

GETPIVOTDATA(pivottabell; villkor)

Den andra syntaxen används om två parametrar anges, varav den första parametern är en referens till en cell eller ett cellområde. Den första syntaxen används i alla övriga fall. Funktionsguiden visar den första syntaxen.

First Syntax

Målfält är en sträng som väljer ett av pivottabellens datafält. Strängen kan vara namnet på källkolumnen, eller det datafältsnamn som visas i tabellen (t.ex. "Summa - Försäljning").

pivottabell är en referens till en cell eller ett cellområde som är placerat i en pivottabell eller som innehåller en pivottabell. Om cellområdet innehåller flera pivottabeller så används den tabell som skapades senast.

Om inga par med Fältnamn / Objektnamn anges returneras totalsumman. Annars utgör varje par ett ytterligare villkor som resultatet måste uppfylla. Fältnamn är namnet på ett fält i pivottabellen. Objektnamn är namnet på ett objekt från det fältet.

Om pivottabellen endast innehåller ett enda resultatvärde, som uppfyller alla villkor, eller ett resultat för delsumma som summerar alla matchande värden, returneras det resultatet. Om det inte finns något matchande resultat, eller flera stycken utan delsumma, returneras ett fel. De här villkoren gäller för resultat som ingår i pivottabellen.

Om dina källdata innehåller poster som är dolda med inställningar för pivottabellen ignoreras posterna. Ordningsföljden för Fält/Objekt-paren saknar betydelse. Fält- och objektnamnen är inte skiftlägeskänsliga.

If no constraint for a filter is given, the field's selected value is implicitly used. If a constraint for a filter is given, it must match the field's selected value, or an error is returned. Filters are the fields at the top left of a pivot table, populated using the "Filters" area of the pivot table layout dialog. From each filter, an item (value) can be selected, which means only that item is included in the calculation.

Värden för delsumma från pivottabellen används endast om du använder funktionen "auto" (utom när de anges i villkoret, se Andra syntax nedan).

Second Syntax

pivottabell har samma innebörd som i den första syntaxen.

Villkor är en blankstegsavgränsad lista. Posterna kan omges med citattecken (enkla citattecken). Hela strängen måste omges av citattecken (dubbla citattecken), såvida du inte refererar till strängen från en annan cell.

En av posterna kan vara datafältets namn. Datafältets namn kan endast utelämnas på villkor att pivottabellen endast innehåller ett datafält.

Var och en av de andra posterna anger ett villkor med utseendet Fält[Objekt] (med literala tecken [ och ]), eller endast Objekt om objektnamnet endast förekommer en gång i pivottabellen.

Ett funktionsnamn kan läggas till i formeln Fält[Objekt;Funktion], vilket gör att villkoret endast matchar delsummor som använder den funktionen. Möjliga funktionsnamn är Summa, Antal, Genomsnitt, Max, Min, Produkt, Antal (endast tal) Stdav (exempel), StdAvP (population), Varians (exempel) och VariansP (population). De är inte skriftlägeskänsliga.

INDEX

INDEX returnerar ett underordnat område, som definieras av rad och kolumnnummer eller ett valfritt områdesindex. INDEX returnerar en referens eller ett innehåll beroende på sammanhanget.

INDEX(Reference [; Row [; Column [; Range]]])

Referens är en referens som antingen anges direkt eller genom att ett områdesnamn anges. Om referensen består av flera områden måste du sätta referensen eller områdesnamnet inom parentes.

Rad (valfritt) representerar referensområdets radindex dit ett värde returneras. Om det är noll (ingen specifik rad) returneras alla refererade rader.

Kolumn (valfritt) representerar referensområdets kolumnindex dit ett värde ska returneras. Om det är noll (ingen specifik kolumn) returneras alla refererade kolumner.

Område (valfritt) representerar index för underområdet om referensen gäller ett större område.

=INDEX(Priser;4;1) returnerar värdet från rad 4 och kolumn 1 i det databasområde som är definierat i Data - Definiera som Priser.

=INDEX(SumX;4;1) returns the value from the range SumX in row 4 and column 1 as defined in Sheet - Named Ranges and Expressions - Define.

=INDEX(A1:B6;1) returnerar en referens till den första raden i A1:B6.

=INDEX(A1:B6;0;1) returnerar en referens till den första kolumnen i A1:B6.

=INDEX((multi);4;1) indicates the value contained in row 4 and column 1 of the (multiple) range, which you named under Sheet - Named Ranges and Expressions - Define as multi. The multiple range may consist of several rectangular ranges, each with a row 4 and column 1. If you now want to call the second block of this multiple range enter the number 2 as the range parameter.

=INDEX(A1:B6;1;1) anger värdet i området högst upp till vänster i A1:B6.

=INDEX((multi);0;0;2) returnerar en referens till det andra området i det större området.

INDIREKT

Returnerar den referens som anges med en textsträng. Den här funktionen kan också användas om du vill returnera området för en motsvarande sträng.

INDIRECT(Ref [; A1])

Ref representerar en referens till en cell eller ett område (i textformat) dit innehåll ska returneras.

A1 (valfritt) - om du anger 0 används R1C1-notation. Om den här parametern saknas eller har ett annat värde än 0 så används A1-notation.

=INDIREKT(A1) är lika med 100 om A1 innehåller C108 som en referens och cell C108 innehåller värdet 100.

=SUMMA(INDIREKT("a1:" & ADRESS(1;3))) räknar samman cellerna i A1-området upp till den cell vars adress definieras av rad 1 och kolumn 3. Detta innebär att området A1:C1 räknas samman.

KOLUMN

Returns the column number of a cell reference. If the reference is a cell the column number of the cell is returned; if the parameter is a cell area, the corresponding column numbers are returned in a single-row array if the formula is entered as an array formula. If the COLUMN function with an area reference parameter is not used for an array formula, only the column number of the first cell within the area is determined.

COLUMN([Reference])

referens är referensen till en cell eller ett cellområde vars första kolumnnummer ska hittas.

Om Du inte anger någon referens, så fastställs kolumnnumret för den cell i vilken formeln matas in. Collabora Office Calc sätter automatiskt referensen till den aktuella cellen.

=KOLUMN(A1) är lika med 1. Kolumn A är den första kolumnen i tabellen.

=KOLUMN(C3:E3) är lika med 3. Kolumn C är den tredje kolumnen i tabellen.

=KOLUMN(D3:G10) returnerar 4 eftersom kolumn D är den fjärde kolumnen i tabellen och KOLUMN-funktionen inte används som en matrisformel. (I sådana fall används alltid det första värdet i matrisen som resultat.)

{=KOLUMN(B2:B7)} och =KOLUMN(B2:B7) returnerar båda 2 eftersom referensen endast innehåller kolumn B som den andra kolumnen i tabellen. Eftersom enradiga områden endast har ett kolumnnummer är det oväsentligt om formeln används som en matrisformel.

=KOLUMN() returnerar 3 om formeln har angetts i kolumn C.

{=KOLUMN(Kanin)} returnerar den enradiga matrisen (3, 4) om "Kanin" är det namngivna området (C1:D3).

KOLUMNER

Returnerar antalet kolumner i en given referens.

KOLUMNER(Matris)

Matris är referensen till ett cellområde vars totala kolumnantal ska räknas fram. Argumentet kan också vara en enda cell.

=KOLUMNER(B5) returnerar 1 eftersom en cell endast innehåller en kolumn.

=KOLUMNER(A1:C5) är lika med 3. Referensen utgör tre kolumner.

=KOLUMNER(Kanin) returnerar 2 om Kanin är det namngivna området (C1:D3).

LETAKOLUMN

Söker efter ett värde och en referens till cellerna under det markerade området. Den här funktionen kontrollerar om den första raden i en matris innehåller ett visst värde. Funktionen returnerar sedan värdet i en rad i matrisen, som namnges i index i samma kolumn.

HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

For an explanation on the parameters, see: VLOOKUP (columns and rows are exchanged)

Suppose we have built a small database table occupying the cell range A1:DO4 and containing basic information about 118 chemical elements. The first column contains the row headings “Element”, “Symbol”, “Atomic Number”, and “Relative Atomic Mass”. Subsequent columns contain the relevant information for each of the elements, ordered left to right by atomic number. For example, cells B1:B4 contain “Hydrogen”, “H”, “1” and “1.008”, while cells DO1:DO4 contain “Oganesson”, “Og”, “118”, and “294”.

	A	B	C	D	...	DO
1	Element	Hydrogen	Helium	Lithium	...	Oganesson
2	Symbol	H	He	Li	...	Og
3	Atomic Number	1	2	3	...	118
4	Relative Atomic Mass	1.008	4.0026	6.94	...	294

=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returns “Pb”, the symbol for lead.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) returns 79, the atomic number for gold.

=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) returns 12.011, the relative atomic mass of carbon.

LETARAD

Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the Sorted parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact Lookup is not found, the last value that is smaller than the criterion will be returned. If Sorted is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.

=VLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Lookup is the value of any type looked for in the first column of the array.

Array is the reference, which is to comprise at least as many columns as the number passed in Index argument.

Index är numret på den kolumn i matrisen som innehåller värdet som ska returneras. Den första kolumnen har nummer 1.

SortedRangeLookup is an optional parameter that indicates whether the first column in the array contains range boundaries instead of plain values. In this mode, the lookup returns the value in the row with first column having value equal to or less than Lookup. E.g., it could contain dates when some tax value had been changed, and so the values represent starting dates of a period when a specific tax value was effective. Thus, searching for a date that is absent in the first array column, but falls between some existing boundary dates, would give the lower of them, allowing to find out the data being effective to the searched date. Enter the Boolean value FALSE or zero if the first column is not a range boundary list. When this parameter is TRUE or not given, the first column in the array must be sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is greater than the lowest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return #N/A with message: Error: Value Not Available.

You want to enter the number of a dish on the menu in cell A1, and the name of the dish is to appear as text in the neighboring cell (B1) immediately. The Number to Name assignment is contained in the D1:E100 array. D1 contains 100, E1 contains the name Vegetable Soup, and so forth, for 100 menu items. The numbers in column D are sorted in ascending order; thus, the optional Sorted parameter is not necessary.

Infoga följande formel i B1:

=LETARAD(A1;D1:E100;2)

Så snart du skriver in ett nummer i A1 visas i B1 den motsvarande texten som står i den andra kolumnen till referensen D1:E100. Om du skriver in ett icke-existerande nummer visas texten med det närmast lägre numret. Om du vill förhindra det infogar du FALSK som sista parameter i formeln. Då visas ett felmeddelande om ett icke-existerande nummer skrivs in.

LETAUPP

Returns the contents of a cell either from a one-row or one-column range. Optionally, the assigned value (of the same index) is returned in a different column and row. As opposed to VLOOKUP and HLOOKUP, search and result vector may be at different positions; they do not have to be adjacent. Additionally, the search vector for the LOOKUP must be sorted ascending, otherwise the search will not return any usable results.

LOOKUP(Lookup; SearchVector [; ResultVector])

Lookup is the value of any type to be looked for; entered either directly or as a reference.

Sökvektor är ett område med en rad eller en kolumn som ska genomsökas.

Resultatvektor är ett annat område med en rad eller en kolumn där funktionens resultat hämtas. Resultatet är resultatvektorscellen som har samma index som den instans som hittades i sökvektorn.

=LETAUPP(A1;D1:D100;F1:F100) söker efter motsvarande cell i området D1:D100 för det tal du har angett i A1. Index bestäms för den instans som hittades, t.ex. den tolfte cellen i det här området. Innehållet i den tolfte cellen returneras sedan som funktionens värde (i resultatvektorn).

LÄNK

När du klickar i en cell som innehåller funktionen LÄNK öppnas hyperlänken.

If you use the optional CellValue parameter, the formula locates the URL, and then displays the text or number.

HYPERLINK("URL" [; CellValue])

URL specifies the link target. The optional CellValue parameter is the text or a number that is displayed in the cell and will be returned as the result. If the CellValue parameter is not specified, the URL is displayed in the cell text and will be returned as the result.

Talet 0 returneras för tomma celler och matriselement.

=HYPERLINK("http://www.example.org") displays the text "http://www.example.org" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";"Click here") displays the text "Click here" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";12345) displays the number 12345 and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK($B4) where cell B4 contains http://www.example.org. The function adds http://www.example.org to the URL of the hyperlink cell and returns the same text which is used as formula result.

=HYPERLINK("http://www.";"Click ") & "example.org" displays the text Click example.org in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("#Sheet1.A1";"Go to top") displays the text Go to top and jumps to cell Sheet1.A1 in this document.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") displays the text "Open Documents folder" and shows the folder contents using the standard file manager in your operating system.

OMRÅDEN

Returnerar antalet områden som tillhör ett större område. Ett område kan bestå av flera sammanhängande celler eller av en enda cell.

Funktionen kräver ett enskilt argument. Om du anger flera områden måste de omslutas av ytterligare parenteser. Flera områden kan anges med semikolon (;) som avgränsare, men dessa konverteras automatiskt till tildetecken (~). Tildetecken används för att sammanfoga områden.

OMRÅDEN(referens)

referens är en referens till en cell eller ett cellområde.

=OMRÅDEN((A1:B3;F2;G1)) returnerar 3, eftersom referensen gäller tre celler och/eller områden. Efter inmatning konverteras detta till =OMRÅDEN((A1:B3~F2~G1)).

=OMRÅDEN(Alla) returnerar 1 om du angett ett område som kallas Alla under Data - Definiera område.

PASSA

Returnerar relativ position för ett objekt i en matris som matchar ett angivet värde. Funktionen returnerar det påträffade värdets position i sökmatrisen i form av ett tal.

MATCH(Search; LookupArray [; Type])

Search is the value which is to be searched for in the single-row or single-column array.

Letaeftermatris är den referens som eftersöks. En letaeftermatris kan vara en enskild rad eller kolumn, eller en del av en enskild rad eller kolumn.

Typ kan ha värdena 1, 0 eller -1. Om typ = 1 eller om den här valfria parametern saknas, så antas att den första kolumnen i sökmatrisen är sorterad i stigande ordning. Om typ = -1 så antas att kolumnen är sorterad i fallande ordning. Det här motsvarar samma funktion i Microsoft Excel.

If Type = 0, only exact matches are found. If the search criterion is found more than once, the function returns the index of the first matching value. Only if Type = 0 can you search for regular expressions (if enabled in calculation options) or wildcards (if enabled in calculation options).

If Type = 1 or the third parameter is missing, the index of the last value that is smaller or equal to the search criterion is returned. For Type = -1, the index of the last value that is larger or equal is returned.

=PASSA(200;D1:D100) söker igenom området D1:D100, vilket sorteras efter kolumn D, efter värdet 200. Så snart värdet hittas returneras numret för den rad där det hittades. Om ett högre värde hittas under genomsökningen av kolumnen returneras numret för föregående rad.

RADER

Returnerar antalet rader i en referens eller matris.

RADER(Matris)

Matris är den referens eller det namngivna område vars totala antal radar ska fastställas.

=Rader(B5) returnerar 1 eftersom en cell endast innehåller en rad.

=RADER(A10;B12) returnerar 3.

=RADER(Kanin) returnerar 3 om "Kanin" är det namngivna området (C1:D3).

ROW

Returns the row number of a cell reference. If the reference is a cell, it returns the row number of the cell. If the reference is a cell range, it returns the corresponding row numbers in a one-column Array if the formula is entered as an array formula. If the ROW function with a range reference is not used in an array formula, only the row number of the first range cell will be returned.

ROW([Reference])

referens är en cell, ett område eller namnet på ett område.

Ifall Du inte anger någon referens, så fastställs radnumret för den cell i vilken formeln matas in. Collabora Office Calc sätter automatiskt referensen till den aktuella cellen.

=RAD(B3) returnerar 3 eftersom referensen hänvisar till den tredje raden i tabellen.

{=RAD(D5:D8)} returnerar den enskilda kolumnmatrisen (5, 6, 7, 8) eftersom referensen som angetts innehåller raderna 5 till 8.

=RAD(D5:D8) returnerar 5 eftersom RAD-funktionen inte används som matrisformel, och endast numret i referensens första rad returneras.

{=RAD(A1:E1)} och =RAD(A1:E1) returnerar båda 1 eftersom referensen endast innehåller rad 1 som den första raden i tabellen. (Eftersom enradiga områden endast har ett radnummer är det oväsentligt om formeln används som en matrisformel.)

=RAD() returnerar 3 om formeln anges i rad 3.

{=RAD(Kanin)} returnerar matrisen med en rad (1, 2, 3) om "Kanin" är det namngivna området (C1:D3).

SHEET

Returns the sheet number of either a reference or a string representing a sheet name. If you do not enter any parameters, the result is the sheet number of the spreadsheet containing the formula.

SHEET([Reference])

Referens är valfritt och hänvisar till en cells, ett områdes eller ett bladnamns teckensträng.

=SHEET(Sheet2.A1) returns 2 if Sheet2 is the second sheet in the spreadsheet document.

=SHEET("Sheet3") returns 3 if Sheet3 is the third sheet in the spreadsheet document.

TABELLER

Bestämmer antalet tabeller i en referens. Om du inte anger några parametrar returneras antalet tabeller i det aktuella dokumentet.

SHEETS([Reference])

referens är referensen till ett blad eller ett område. Den här parametern är valfri.

=BLAD(Blad1.A1:Blad3.G12) returnerar 3 om Blad1, Blad2 och Blad3 finns i den angivna sekvensen.

VÄLJ

Använder ett index för att returnera ett värde från en lista på högst 30 värden.

CHOOSE(Index; Value 1 [; Value 2 [; ... [; Value 30]]])

index som referens eller tal mellan 1 och 30. Anger vilket värde som ska tas ur listan.

Value 1, Value 2, ..., Value 30 is the list of values entered as a reference to a cell or as individual values.

=VÄLJ(A1;B1;B2;B3;"Idag";"Igår";"Imorgon") returnerar t.ex. innehållet i cell B2 för A1 = 2, och för A1 = 4 returneras texten "Idag".