Finansfunktioner del ett
Den här kategorin innehåller de matematiska finansfunktionerna för Collabora Office Calc.
AMORDEGRC
Beräknar avskrivningsbeloppet för en avräkningsperiod som degressiv amortering. I motsats till AMORLINC används här en avskrivningskoefficient som beror på tillgångarnas livslängd.
AMORDEGRC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate [; Basis])
Kostnad är anskaffningskostnaderna.
Inköpsdatum är anskaffningsdatumet.
Första periodär slutdatumet för den första avräkningsperioden.
RV är restvärdet på kapitaltillgångar i slutet av avskrivningstiden.
Period är avräkningsperioden som gäller.
Ränta är avskrivningssatsen.
An asset was acquired on 2020-02-01 at a cost of 2000 currency units. The end date of the first settlement period was 2020-12-31. The salvage value of the asset at the end of its depreciable life will be 10 currency units. The rate of depreciation is 0.1 (10%) and the year is calculated using the US method (Basis 0). Assuming degressive depreciation, what is the amount of depreciation in the fourth depreciation period?
=AMORDEGRC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) returns a depreciation amount of 163 currency units.
Be aware that Basis 2 is not supported by Microsoft Excel. Hence, if you use Basis 2 and export your document to XLSX format, it will return an error when opened in Excel.
AMORLINC
Beräknar avskrivningsbeloppet för en avräkningsperiod som linjär amortering. Om tillgången anskaffas under avräkningsperioden tas det proportionella avskrivningsbeloppet med i beräkningen.
AMORLINC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate [; Basis])
Kostnad avser anskaffningskostnader.
Inköpsdatum är anskaffningsdatumet.
Första periodär slutdatumet för den första avräkningsperioden.
RV är restvärdet på kapitaltillgångar i slutet av avskrivningstiden.
Period är avräkningsperioden som gäller.
Ränta är avskrivningssatsen.
An asset was acquired on 2020-02-01 at a cost of 2000 currency units. The end date of the first settlement period was 2020-12-31. The salvage value of the asset at the end of its depreciable life will be 10 currency units. The rate of depreciation is 0.1 (10%) and the year is calculated using the US method (Basis 0). Assuming linear depreciation, what is the amount of depreciation in the fourth depreciation period?
=AMORLINC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) returns a depreciation amount of 200 currency units.
Be aware that Basis 2 is not supported by Microsoft Excel. Hence, if you use Basis 2 and export your document to XLSX format, it will return an error when opened in Excel.
BELOPP
beräknar beloppet som betalas ut vid en viss tidpunkt för ett värdepapper med fast ränta.
RECEIVED(Settlement; Maturity; Investment; Discount [; Basis])
Avräkning är värdepapprets inköpsdatum.
Förfallotid är det datum som värdepappret förfaller (upphör att gälla).
Investering är köpeskillingen.
Diskontering är den procentuella diskonteringen vid värdepapprets anskaffande.
Avbetalningsdatum: 15 februari 1999, Förfallodag: 15 maj 1999, Investering: 1000 valutaenheter, Diskonteringsränta: 5,75 procent, Bas: faktisk/360 = 2.
Beloppet som betalas ut på förfallodagen beräknas på följande sätt:
=BELOPP("1999-02-15";"1999-05-15";1000;0,0575;2) returnerar 1014,420266.
DB
Returnerar avskrivningen på en tillgång för en given period med hjälp av metoden för fast degressiv avskrivning.
Den här avskrivningsformen använder du när du vill att avskrivningsvärdet ska vara störst i början av avskrivningen (i motsats till linjär avskrivning). Avskrivningsvärdet minskar för varje avskrivningsperiod med de avskrivningar som redan har dragits av från anskaffningsvärdet.
DB(Cost; Salvage; Life; Period [; Month])
Kostnad är tillgångens anskaffningsvärde.
Restvärde är tillgångens restvärde vid livslängdens slut.
Livslängd anger avskrivningsperioden för en tillgång.
P är periodlängden. Du måste ange perioden i samma tidsenhet som livslängden.
MÅ (valfritt) är antalet månader under första avskrivningsåret. Om inget annat anges används faktorn 12.
A computer system with an initial cost of 25,000 currency units is to be depreciated over a three-year period. The salvage value is to be 1,000 currency units. The first period of depreciation comprises 6 months. What is the fixed-declining balance depreciation of the computer system in the second period, which is a full year starting from the end of the first six-month period?
=DB(25000; 1000; 3; 2; 6) returns 11,037.95 currency units.
DEGAVSKR
Returnerar avskrivningen enligt den aritmetisk-degressiva metoden för en viss avskrivningsperiod.
Använd den här avskrivningsformen om du vill att avskrivningsvärdet ska vara störst i början av avskrivningen, till skillnad från vid linjär avskrivning. Avskrivningsvärdet minskar för varje avskrivningsperiod och används vanligen för tillgångar vars värdeminskning är snabbast strax efter anskaffningen. Det kan röra sig om t.ex. bilar och datorer. Lägg märke till att bokföringsvärdet aldrig kan gå ned till noll med den här beräkningsformen.
DDB(Cost; Salvage; Life; Period [; Factor])
Kostnad är tillgångens anskaffningsvärde.
RV är tillgångens restvärde vid livslängdens slut.
Livslängd är livslängden uttryckt i antalet avskrivningsperioder (t.ex. år eller månader) under vilken tillgången skall användas.
TP anger den tidsperiod för vilken värdet ska beräknas.
FA (valfritt) är avskrivningsfaktorn. Om inget annat anges används faktorn 2.
Ett datorsystem med ett anskaffningsvärde på 75 000 valutaenheter ska skrivas av månatligen under fem år. Restvärdet ska vara 1 valutaenhet. Faktorn är 2.
=DDB(75000;60;12;1;2) = 1 721,81 valutaenheter Därför är den dubbeldegressiva avskrivningen den tolfte månaden efter inköpet 1 721,81 valutaenheter.
DISK
Beräknar ersättning (diskonteringsränta) för ett värdepapper i procent.
DISC(Settlement; Maturity; Price; Redemption [; Basis])
Avräkning är värdepapprets inköpsdatum.
Förfallotid är det datum som värdepappret förfaller (upphör att gälla).
Pris är värdepapprets pris per 100 valutaenheter av det nominella värdet.
Återköp är återköpsvärdet för värdepappret per 100 valutaenheter av nominellt värde.
Ett värdepapper köps den 25 januari 2001. Förfallodagen är den 15 november 2001. Priset ligger på 97, inlösningsvärdet på 100. Hur hög är diskonteringsräntan vid faktisk/365-beräkning (bas 3)?
=DISK("2001-01-25";"2001-11-15";97;100;3) returnerar 0,0372 eller 3,72 procent.
DURATION
Beräknar löptiden i år för ett värdepapper med periodisk räntebetalning.
DURATION(Settlement; Maturity; Coupon; Yield; Frequency [; Basis])
Avräkning är värdepapprets inköpsdatum.
Förfallotid är det datum som värdepappret förfaller (upphör att gälla).
Kupong är den årliga kupongräntan (nominell ränta)
Avkastning är den årliga avkastningen för värdepappret.
Frekvens är antalet räntebetalningar per år (1, 2 eller 4).
Ett värdepapper köps den 1 januari 2001. Förfallodatum är den 1 januari 2006. Den nominella räntesatsen är 8%. Avkastningen är 9,0%. Räntan betalas halvårsvis (frekvensen är 2). Hur lång är löptiden om daglig ränteberäkning (bas 3) används?
=DURATION("2001-01-01";"2006-01-01";0.08;0.09;2;3) returns 4.2 years.
EFFECT
Returnerar den årliga nettoräntesatsen för en nominell räntesats.
Normalräntan beräknas för en räntebetalning i slutet av beräkningstidsrymden. Räntebetalningarna förfaller däremot ofta per månad, per kvartal eller någon annan tidsrymd fram till beräkningsrymdens slut. I praktiken betalas normalräntan alltså i praktiken i förväg, och därigenom ökas den effektiva räntan med räntebetalningarna.
EFFECT(Nom; P)
Nom är den nominella räntan.
P är antalet periodiska räntebetalningar per år.
Om nominalräntan per år är 9,75 % och räntan ska betalas fyra gånger, hur hög blir då den verkliga räntan (effektivräntan)?
=EFFECT(9.75%;4) = 10.11% The annual effective rate is therefore 10.11%.
EFFRÄNTA_ADD
Beräknar effektiv årlig ränta på basis av nominell ränta och antalet räntebetalningar per år.
De funktioner vars namn slutar med _ADD eller _EXCEL2003 returnerar samma resultat som motsvarande funktioner i Microsoft Excel 2003 utan suffixen. Funktioner utan suffix ger resultat som är baserade på internationell standard.
EFFRÄNTA_ADD(Nominell ränta; P)
Nominell ränta är den årliga nominella räntan.
P är antalet periodiska räntebetalningar per år.
Vad uppgår den effektiva räntan till vid 5,25% nominell ränta och kvartalsvis betalning?
=EFFRÄNTA_ADD(0,0525;4) returnerar 0,053543 eller 5,3543%.
IR
Beräknar den interna räntan för en investering. Värdena representerar penningflödesvärden vid regelbundna intervaller, minst ett värde måste vara negativt (betalningar), och minst ett måste vara positivt (inkomst).
If the payments take place at irregular intervals, use the XIRR function.
IRR(Values [; Guess])
Värden representerar en matris som innehåller värdena.
Gissning (valfritt) är det uppskattade värdet. En iterativ metod som används för att beräkna intern ränta. Om du bara kan ange ett fåtal värden bör du ange en gissning för att aktivera iterationerna.
This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.
Om man antar att cellinnehållet är A1=-10000, A2=3500, A3=7600 och A4=1000, blir resultatet för formeln =IR(A1:A4) 11.33%.
Because of the iterative method used, it is possible for IRR to fail and return Error 523, with "Error: Calculation does not converge" in the status bar. In that case, try another value for Guess.
NUVÄRDE
Returnerar nuvärdet av en investering som resulterar från en serie regelbundna betalningar.
Du kan använda den här funktionen till att beräkna hur stort belopp du måste investera i dag för att det ska räcka till utbetalning av ett visst belopp (annuitet) vid ett visst antal utbetalningar. Du kan om du vill ange hur mycket pengar som ska återstå när alla utbetalningar har gjorts. Du kan även ange om utbetalningen ska göras i början eller slutet av varje period.
Du anger värdena som tal, uttryck eller referenser. Om du t.ex. får 8% i ränta per år men skulle vilja ange månad som period, skriver du 8%/12 i fältet ränta. Collabora Office Calc beräknar automatiskt den korrekta faktorn.
PV(Rate; NPer; Pmt [; FV [; Type]])
Ränta är räntesatsen för en periods betalning.
Perioder är det totala antalet perioder (betalningsperiod).
BETALNING är den regelbundna betalningen per period.
Slutvärde (valfritt) är det framtida värdet som ska bli över när alla betalningar är gjorda.
F (valfritt) är förfallotidpunkten. F = 1 om betalningen görs under periodens början; F = 0 (standardvärde) om den görs vid dess slut.
I Collabora Office Calc-funktioner kan de parametrar som markeras som "valfria" bara utelämnas när inga efterföljande parametrar finns. I till exempel en funktion med fyra parametrar, där de två sista parametrarna markeras som "valfria", kan du utelämna parameter 4 eller parametrarna 3 och 4, men inte utelämna enbart parameter 3.
Hur högt är nuvärdet av en investering om 500 valutaenheter betalas ut varje månad och räntesatsen är 8% per år? Betalningstiden är 48 månader och som slutvärde ska 20 000 valutaenheter återstå.
=NUVÄRDE(8 %/12;48;500;20000) = -35 019,37 valutaenheter. Under de omnämnda villkoren måste du sätta in 35 019,37 valutaenheter idag om du vill få 500 valutaenheter per månad under 48 månader och ha 20 000 valutaenheter kvar i slutet av perioden. Dubbelkontrollen visar att 48 x 500 valutaenheter + 20 000 valutaenheter = 44 000 valutaenheter. Skillnaden mellan den här summan och de 35 000 valutaenheter som sattes in är den inbetalda räntan.
Om du inte skriver in värdena direkt utan som referens i formeln, kan du låta programmet räkna igenom valfria "Vad-händer-om..."-scenarion. Tänk på att referenserna till konstanter ska vara absoluta referenser. Avskrivningsfunktionerna är ett exempel på den här typen av användning.
RALÅN
Beräknar hur höga räntorna blir vid konstanta amorteringar.
RALÅN(Ränta; Period; Totala perioder; Investera)
Ränta definierar den periodiska räntesatsen.
Period är antalet amorteringsperioder för beräkningen av räntorna.
Totala perioder är det totala antalet avbetalningsperioder.
investering är investeringsbeloppet.
Vid en kreditsumma på 120 000 valutaenheter med två års löptid och amortering månadsvis, med en räntesats på 12 %, efterfrågas hur höga räntorna är efter 1,5 år.
=RALÅN(1 %;18;24;120000) = - 300 valutaenheter. Månadsräntan efter 1,5 år uppgår till 300 valutaenheter.
UPPLOBLRÄNTA
Beräknar ett värdepappers upplupna räntor som betalas ut på förfallodagen.
ACCRINTM(Issue; Settlement; Rate [; Par [; Basis]])
Emission (obligatorisk) är värdepapprets emissionsdatum.
Avräkning (obligatorisk) är det datum som den upplupna räntan upptill en viss tidpunkt beräknas utifrån.
Ränta (obligatorisk) är den årliga nominella räntan (kupongränta)
Par (optional) is the par value of the security. If omitted, a default value of 1000 is used.
We recommend that you always specify the value that you require for ACCRINTM’s Par argument, rather than allowing Calc to apply an arbitrary default. This will make your formula easier to understand and easier to maintain.
Ett värdepapper ges ut den 1 april 2001. Förfallodagen anges till den 15 juni 2001. Nominell ränta är 0,1 eller 10% och det nominella värdet är 1000 valutaenheter. Bas för dags/årsberäkningen är faktisk/365 (3). Hur höga är de upplupna räntorna?
=UPPLOBLRÄNTA("2001-04-01";"2001-06-15";1000;0,1;3) returnerar 20,54795.
UPPLRÄNTA
Beräknar upplupen ränta för ett värdepapper med periodiska betalningar.
ACCRINT(Issue; FirstInterest; Settlement; Rate; [Par]; Frequency [; Basis])
Emission (obligatorisk) är värdepapprets emissionsdatum.
Första räntedatum (obligatorisk) är det första räntedatumet för värdepappret.
Avräkning (obligatorisk) är det datum som den upplupna räntan upptill en viss tidpunkt beräknas utifrån.
Ränta (obligatorisk) är den årliga nominella räntesatsen (kupongräntesatsen)
Par (optional) is the par value of the security. If omitted, a default value of 1000 is used.
We recommend that you always specify the value that you require for ACCRINT’s Par argument, rather than allowing Calc to apply an arbitrary default. This will make your formula easier to understand and easier to maintain.
Frekvens (obligatorisk) är antalet räntebetalningar per år (1, 2 eller 4).
Ett värdepapper ges ut den 28 februari 2001. Det första räntedatumet är den 31 augusti 2001. Betalningsdatumet är den 1 maj 2001. Nominell ränta är 0,1 eller 10% och det nominella värdet är 1000 valutaenheter. Räntan betalas halvårsvis (frekvensen är 2). Bas är US-metoden (0). Hur höga är de upplupna räntorna?
=UPPLRÄNTA("2001-02-28";"2001-08-31";"2001-05-01";0,1;1000;100;2;0) returnerar 16,94444.
ÅRSAVSKR
Returnerar den aritmetiska degressiva avskrivningshastigheten.
Den här funktionen använder du för att beräkna avskrivningsdelen för en period i den totala avskrivningstiden för ett objekt. Vid digital avskrivning minskas avskrivningssumman från period till period med ett konstant belopp.
ÅRSAVSKR(Kostnad; Restvärde; Livslängd; Period)
Kostnad är tillgångens anskaffningsvärde.
RV är tillgångens restvärde vid livslängdens slut.
Livslängd är livslängden uttryckt i antalet avskrivningsperioder.
TP är den tidsperiod för vilken avskrivningen ska beräknas.
En videoanläggning med ett anskaffningsvärde på 50 000 valutaenheter ska skrivas av årligen under fem år. Restvärdet ska vara 10 000 valutaenheter. Avskrivningen ska beräknas för det första året.
=ÅRSAVSKR(50000;10000;5;1)=13 333,33 valutaenheter. Avskrivningssumman för det första året är 13 333,33 valutaenheter.
Du bör helst skapa en avskrivningstabell, så att du lätt kan se avskrivningarna per tidsperiod. Om du skriver in de olika avskrivningsformlerna i Collabora Office Calc ser du också vilken form av avskrivning som är den lämpligaste i det här fallet. Fyll i tabellen enligt nedan:
|
A |
B |
C |
D |
E |
|
|---|---|---|---|---|---|
|
1 |
Startkostnad |
Restvärde |
Livslängd |
Tidsperiod |
Avskrivn. ÅRSAVSKR |
|
2 |
50 000 valutaenheter |
10 000 valutaenheter |
5 |
1 |
13,333.33 valutaenheter |
|
3 |
2 |
10 666,67 valutaenheter |
|||
|
4 |
3 |
8,000.00 valutaenheter |
|||
|
5 |
4 |
5,333.33 valutaenheter |
|||
|
6 |
5 |
2,666.67 valutaenheter |
|||
|
7 |
6 |
0.00 valutaenheter |
|||
|
8 |
7 |
||||
|
9 |
8 |
||||
|
10 |
9 |
||||
|
11 |
10 |
||||
|
12 |
|||||
|
13 |
>0 |
Totalt |
40,000.00 valutaenheter |
Formeln i E2 lyder som följer:
=ÅRSAVSKR($A$2;$B$2;$C$2;D2)
Den här formeln dupliceras i kolumn E till E10 (markera E2 och dra sedan nedåt i det nedre högra hörnet med musen).
I cell E13 står den formel som kontrollsummerar alla avskrivningsbelopp. Du använder funktionen SUMMA.OM, eftersom de negativa värdena i E8:E11 inte får påverka resultatet. Villkoret >0 står i cell A13. Formeln i E13 lyder som följer:
=SUMMA.OM(E2:E11;A13)
Nu kan du se hur det blir om avskrivningstiden är 10 år, eller om restvärdet ska vara 1 valutaenhet, eller också anger du ett annat anskaffningsvärde och så vidare.