Použitie premenných

Následujúca časť popisuje základné použitie premenných v Collabora Office Basic.

Konvencie pre pomenovanie identifikátorov premenných

Názov premennej môže obsahovať maximálne 255 znakov. Prvý znak názvu premennej musí byť písmeno A-Z alebo a-z. V názve premennej je možné taktiež použiť čísla, ale interpunkčné a špeciálne symboly nie sú povolené, s výnimkou podtržníka ("_"). V Collabora Office Basic nezáleží na veľkosti písmen v názvoch premenných. Názvy premenných môžu obsahovať medzery, ale v tom prípade musia byť uzatvorené do hranatých zátvoriek.

Príklad pre mená premenných:

    MyNumber=5      'Correct'
    MyNumber5=15    'Correct'
    MyNumber_5=20   'Correct'
    My Number=20    'Not valid, variable with space must be enclosed in square brackets'
    [My Number]=12  'Correct'
    DéjàVu=25       'Not valid, special characters are not allowed'
    5MyNumber=12    'Not valid, variable may not begin with a number'
    Number,Mine=12  'Not valid, punctuation marks are not allowed'

Deklarácia Premenných

V Collabora Office Basic nemusíte premenné explicitne deklarovať. Deklaráciu premennej je možné previesť príkazom Dim. Jedným príkazom je možné deklarovať niekoľko premenných, stačí oddeliť názvy čiarkou. Ak chcete definovať typ premennej, použite po názve buď znamienko typovej deklarácie alebo zodpovedajúce kľúčové slovo.

Príklady pre deklaráciu premenných:

    Dim a$               'Declares the variable "a" as a String'
    Dim a As String      'Declares the variable "a" as a String'
    Dim a$, b As Integer 'Declares one variable as a String and one as an Integer'
    Dim c As Boolean     'Declares c as a Boolean variable that can be TRUE or FALSE'

Akonáhle v deklarácii priradíte premennej určitý typ, nie je už možné deklarovať premennú rovnakého názvu ako iný typ!

When you declare multiple variables in a single line of code you need to specify the type of each variable. If the type of a variable is not explicitly specified, then Basic will assume that the variable is of the Variant type.

  ' Both variables "a" and "b" are of the Integer type
  Dim a As Integer, b As Integer
  ' Variable "c" is a Variant and "d" is an Integer
  Dim c, d As Integer
  ' A variable can also be explicitly declared as a Variant
  Dim e As Variant, f As Double

The Variant type is a special data type that can store any kind of value. To learn more, refer to the section The Variant type below.

Vynútenie deklarácie premenných

Ak chcete, aby každá premenná bola deklarovaná, použite nasledujúci príkaz:

Option Explicit

Príkaz Option Explicit musí byť na prvom riadku modulu, pred prvým SUB. Všeobecne je potrebné explicitne deklarovať iba pole. Všetky ostatné premenné sa deklarujú podľa znaku typovej deklarácie alebo (ak je vynechaný) ako implicitný typ Single.

Typy premenných

Collabora Office Basic podporuje štyri typy premenných:

• Premenné typu Numeric môžu obsahovať číselné hodnoty. Niektoré premenné sa používajú na ukladanie veľkých alebo malých čísel, iné pre čísla s plávajúcou desatinnou čiarkou.

• Premenné typu String obsahujú znakové reťazce.

• Logické premenné typu obsahujú hodnotu TRUE alebo FALSE.

• Premenné typu Object môžu obsahovať objekty rôznych typov, napríklad tabuľky alebo dokumenty.

Premenné typu Integer

Premenné typu Integer (celé čísla) môžu byť v rozsahu od -32768 do 32767. Pokiaľ celočíselnej premenné priradíte hodnotu s desatinnou čiarkou, zaokrúhli sa na najbližšie celé číslo. S celočíselnými premennými sa počíta veľmi rýchlo a sú vhodné pre počítadlá v slučkách. Premenná typu integer vyžaduje v pamäti iba dva bajty. Znak typovej deklarácie je "%".

Dim Variable%
Dim Variable As Integer

Premenné typu Long Integer

Premenné typu Long Integer (dlhé celé čísla) môžu byť v rozsahu od -2147483648 do 2147483647. Pokiaľ dlhej celočíselnej premennej priradíte hodnotu s desatinnou čiarkou, zaokrúhli sa na najbližšie celé číslo. S dlhými celočíselnými premennými sa počíta veľmi rýchlo a sú vhodné pre počítadlá v slučkách pre veľké hodnoty. Premenná typu Long Ingteger vyžaduje v pamäti štyri bajty. Znak typovej deklarácie je "&".

Dim Variable&
Dim Variable As Long

Desatinné premenné

Premenné typu Float môžu obsahovať kladné alebo záporné čísla s presnosťou až na 29 desatinných miest.

Ako prefix desatinných čísel môžete použiť znaky plus ( ) alebo mínus (-) (s medzerami alebo bez).

Pokiaľ priradíte desatinné číslo do celočíselnej premennej, Collabora Office Basic zaokrúhli číslo nahor alebo nadol.

Premenné typu Single

Single variables can take positive or negative values ranging from 3.402823 x 10E38 to 1.401298 x 10E-45. Single variables are floating-point variables, in which the decimal precision decreases as the non-decimal part of the number increases. Single variables are suitable for mathematical calculations of average precision. Calculations require more time than for Integer variables, but are faster than calculations with Double variables. A Single variable requires 4 bytes of memory. The type-declaration character is "!".

Dim Variable!
Dim Variable As Single

Premenné typu Double

Double variables can take positive or negative values ranging from 1.79769313486232 x 10E308 to 4.94065645841247 x 10E-324. Double variables are floating-point variables, in which the decimal precision decreases as the non-decimal part of the number increases. Double variables are suitable for precise calculations. Calculations require more time than for Single variables. A Double variable requires 8 bytes of memory. The type-declaration character is "#".

Dim Variable#
Dim Variable As Double

Premenné typu Currency (mena)

Premenné typu Currency (mena) sa interne ukladajú ako 64bitové čísla (8 bajtov) a zobrazujú sa s pevným počtom desatinných miest - 15 miest v celej časti a 4 desatinné miesta. Rozsah hodnôt je od -922337203685477.5808 do 922337203685477.5807. Premenné Currency sa používajú pre výpočty s menami s vysokou presnosťou. Znak typovej deklarácie je "@".

Dim Variable@
Dim Variable As Currency

Literals for integers

Numbers can be encoded using octal and hexadecimal forms.

  xi = &o13 '    8 + 3
  ci = &h65 ' 6*16 + 5
  MAX_Integer =  &o77777 '  32767 = &h7FFF
  MIN_Integer = &o100000 ' -32768 = &h8000
  MAX_Long = &h7fffffff '  2147483647 = &o17777777777
  MIN_Long = &h80000000 ' -2147483648 = &o20000000000

Premenné typu String

String variables can hold character strings with up to 2,147,483,648 characters. Each character is stored as the corresponding Unicode value. String variables are suitable for word processing within programs and for temporary storage of any non-printable character up to a maximum length of 2 Gbytes. The memory required for storing string variables depends on the number of characters in the variable. The type-declaration character is "$".

In BASIC String functions, the first character of the string has index 1.

Dim Variable$
Dim Variable As String

Logické premenné

Logické premenné môžu obsahovať iba dve hodnoty: TRUE alebo FALSE. Číslo 0 sa vyhodnotí ako FALSE, všetky ostatné ako TRUE.

Dim Variable As Boolean

Premenné typu Date (dátum)

Premenné typu Date môžu obsahovať len dátumy alebo časy uložené v internom formáte. Hodnoty priradené premenným Date pomocouDateserial, Datevalue, Timeserial alebo Timevalue sa automaticky prevedú na interný formát. Dátumové premenné prevediete na normálne čísla pomocou funkcií Day, Month, Year alebo Hour, Minute, Second. Interný formát umožňuje porovnanie dvoch dátumových / časových hodnôt pomocou výpočtu rozdielu medzi číslami. Tieto premenneé sa môžu deklarovať len kľúčovým slovom Date.

Dim Variable As Date

Literals for Dates

Date literals allow to specify unambiguous date variables that are independent from the current language. Literals are enclosed between hash signs #. Possible formats are:

• #yyyy-mm-dd#

• #mm/dd/yyyy#

  start_date = #12/30/1899# ' = 1
  dob = #2010-09-28#

The Variant type

Variables declared as Variant can handle any data type. This means that the actual data type is defined during runtime as a value is assigned to the variable.

There are three main ways to create a Variant variable, as shown below:

  Dim varA            ' The type is not specified, hence the variable is a Variant
  Dim varB as Variant ' The variable is explicitly declared as a Variant
  varC = "abc"        ' Previously undeclared variables are treated as Variants

The example below uses the TypeName function to show how the type of a Variant variable changes upon assignment.

  Dim myVar As Variant
  MsgBox TypeName(myVar) ' Empty
  myVar = "Hello!"
  MsgBox TypeName(myVar) ' String
  myVar = 10
  MsgBox TypeName(myVar) ' Integer

A Variant variable is initialized with the Empty special data type. You can use the IsEmpty function to test if a variable is an Empty Variant.

You can also use the keyword Any to declare a variable as a Variant. However, Any is deprecated and is available for backward compatibility.

Arguments with type Variant or Any passed in function calls are not checked for their types.

  Dim myVar As Any ' Variable "myVar" is a Variant

Počiatočné hodnoty premenných

Akonáhle je premenná deklarovaná, jej hodnota je automaticky nastavená na "Null". Platia nasledujúce pravidlá:

Premenným typu Numeric sa po ich deklarácii automaticky priradí hodnota "0".

Premenným typu Date sa interne priradí 0, čo zodpovedá prevodu hodnoty na "0" pomocou funkcieDay, Month, Year alebo Hour, Minute, Second.

Premenným typu String sa pri deklarácii priradí prázdny reťazec ("").

Polia

Collabora Office Basic pozná jedno- alebo viacrozmerné polia, definované určeným typom premennej. Polia sú vhodné pre zoznamy a tabuľky v programe. K jednotlivým prvkom poľa je možné pristupovať pomocou číselného indexu.

Pole musí byť deklarované príkazom Dim. Existuje niekoľko možností, ako definovať rozsah poľa:

    Dim Text$(20)       '21 elements numbered from 0 to 20'
    Dim Text$(5,4)      '30 elements (a matrix of 6 x 5 elements)'
    Dim Text$(5 To 25)  '21 elements numbered from 5 to 25'
    Dim Text$(-15 To 5) '21 elements (including 0), numbered from -15 to 5'

Index môže obsahovať kladné aj záporné čísla.

Konštanty

Konštanty majú stálu hodnotu. V programe sa definujú iba raz a neskôr už nie je možné ich predefinovať:

Const ConstName=Expression