Utilizar variáveis

O texto seguinte descreve a utilização básica de variáveis no Collabora Office Basic.

Convenções de nomenclatura para identificadores de variáveis

O nome de uma variável pode ter, no máximo, 255 caracteres. O primeiro carácter do nome de uma variável tem que ser uma letra de A-Z ou a-z. Também pode utilizar números no nome de uma variável, mas sinais de pontuação e caracteres especiais não são permitidos, à exceção do traço de sublinhado ("_"). No Collabora Office Basic, os identificadores de variáveis não diferenciam maiúsculas de minúsculas. Os nomes das variáveis podem conter espaços mas, nesse caso, têm que estar entre parênteses retos.

Exemplos de identificadores de variáveis:

    MyNumber=5      'Correct'
    MyNumber5=15    'Correct'
    MyNumber_5=20   'Correct'
    My Number=20    'Not valid, variable with space must be enclosed in square brackets'
    [My Number]=12  'Correct'
    DéjàVu=25       'Not valid, special characters are not allowed'
    5MyNumber=12    'Not valid, variable may not begin with a number'
    Number,Mine=12  'Not valid, punctuation marks are not allowed'

Declarar variáveis

No Collabora Office Basic não precisa declarar variáveis explicitamente. Uma declaração de variável pode ser executada com a instrução Dim. Pode declarar mais do que uma variável por vez, separando os nomes com uma vírgula. Para definir o tipo de variável, utilize um sinal de declaração de tipo depois do nome ou uma palavra-chave adequada.

Exemplos de declarações de variáveis:

    Dim a$               'Declares the variable "a" as a String'
    Dim a As String      'Declares the variable "a" as a String'
    Dim a$, b As Integer 'Declares one variable as a String and one as an Integer'
    Dim c As Boolean     'Declares c as a Boolean variable that can be TRUE or FALSE'

Assim que tiver declarado uma variável como um certo tipo, não pode declará-la novamente com o mesmo nome e um tipo diferente!

When you declare multiple variables in a single line of code you need to specify the type of each variable. If the type of a variable is not explicitly specified, then Basic will assume that the variable is of the Variant type.

  ' Both variables "a" and "b" are of the Integer type
  Dim a As Integer, b As Integer
  ' Variable "c" is a Variant and "d" is an Integer
  Dim c, d As Integer
  ' A variable can also be explicitly declared as a Variant
  Dim e As Variant, f As Double

The Variant type is a special data type that can store any kind of value. To learn more, refer to the section The Variant type below.

Forçar declarações de variáveis

Para forçar a declaração de variáveis, utilize o seguinte comando:

Option Explicit

A instrução Option Explicit terá de ser a primeira linha do módulo, antes da primeira SUB. Normalmente, só as matrizes precisam de ser declaradas de forma explícita. Todas as restantes variáveis são declaradas de acordo com o carácter de declaração de tipo ou, caso este esteja omisso, como o tipo Simples.

Tipos de variáveis

O Collabora Office Basic possui suporte a quatro classes de variáveis:

• As variáveis Numéricas podem contar valores numéricos. Algumas variáveis são utilizadas para armazenar números grandes ou pequenos, enquanto que outras são utilizadas para vírgula flutuante ou números fracionários.

• As variáveis String contêm cadeias de caracteres.

• As variáveis Booleanas contêm o valor VERDADEIRO ou FALSO.

• As variáveis deObjeto podem armazenar objetos de diversos tipos, tais como tabelas e documentos dentro de um documento.

Variáveis de números inteiros

As variáveis de números inteiros vão desde -32768 até 32767. Se atribuir um valor de vírgula flutuante a uma variável de números inteiros, as casas decimais são arredondadas para o próximo número inteiro. As variáveis de números inteiros são rapidamente calculadas através de procedimentos e são apropriadas para contagem de variáveis em ciclos. Uma variável de números inteiros só necessita de dois bytes de memória. "%" é o carácter de declaração de tipo.

Dim Variable%
Dim Variable As Integer

Variáveis de números inteiros longos

As variáveis de números inteiros longos vão desde -2147483648 até 2147483647. Se atribuir um valor de vírgula flutuante a uma variável de números inteiros longos, as casas decimais são arredondadas para o próximo número inteiro. As variáveis de números inteiros longos são rapidamente calculadas em procedimentos e são apropriadas para contagem de variáveis em ciclos para grandes valores. Uma variável de números inteiros longos necessita de 4 bytes de memória. "&" é o carácter de declaração de tipo.

Dim Variable&
Dim Variable As Long

Variáveis decimais

As variáveis decimais podem ter números positivos, negativos ou zero. A precisão é até um máximo de 29 dígitos.

Pode utilizar o sinal de soma (+) ou o sinal de subtração (-) como prefixo de números decimais (com ou sem espaços).

Se um número decimal for atribuído a uma variável inteira, o Collabora Office Basic arredonda o número por excesso ou por defeito.

Variáveis únicas

Single variables can take positive or negative values ranging from 3.402823 x 10E38 to 1.401298 x 10E-45. Single variables are floating-point variables, in which the decimal precision decreases as the non-decimal part of the number increases. Single variables are suitable for mathematical calculations of average precision. Calculations require more time than for Integer variables, but are faster than calculations with Double variables. A Single variable requires 4 bytes of memory. The type-declaration character is "!".

Dim Variable!
Dim Variable As Single

Variáveis duplas

Double variables can take positive or negative values ranging from 1.79769313486232 x 10E308 to 4.94065645841247 x 10E-324. Double variables are floating-point variables, in which the decimal precision decreases as the non-decimal part of the number increases. Double variables are suitable for precise calculations. Calculations require more time than for Single variables. A Double variable requires 8 bytes of memory. The type-declaration character is "#".

Dim Variable#
Dim Variable As Double

Variáveis monetárias

As variáveis monetárias são armazenadas internamente como números de 64 bits (8 Bytes) e mostradas como um número decimal fixo com 15 casas não decimais e 4 decimais. Os valores vão desde -922337203685477,5808 até +922337203685477,5807. As variáveis monetárias são utilizadas para calcular os valores com grande precisão. O carácter de declaração de tipo é "@".

Dim Variable@
Dim Variable As Currency

Literals for integers

Numbers can be encoded using octal and hexadecimal forms.

  xi = &o13 '    8 + 3
  ci = &h65 ' 6*16 + 5
  MAX_Integer =  &o77777 '  32767 = &h7FFF
  MIN_Integer = &o100000 ' -32768 = &h8000
  MAX_Long = &h7fffffff '  2147483647 = &o17777777777
  MIN_Long = &h80000000 ' -2147483648 = &o20000000000

Variáveis de cadeia

String variables can hold character strings with up to 2,147,483,648 characters. Each character is stored as the corresponding Unicode value. String variables are suitable for word processing within programs and for temporary storage of any non-printable character up to a maximum length of 2 Gbytes. The memory required for storing string variables depends on the number of characters in the variable. The type-declaration character is "$".

In BASIC String functions, the first character of the string has index 1.

Dim Variable$
Dim Variable As String

Variáveis booleanas

As variáveis booleanas só guardam um de dois valores: VERDADEIRO ou FALSO. Um número 0 é avaliado como FALSO, enquanto que qualquer outro valor é avaliado como VERDADEIRO.

Dim Variable As Boolean

Variáveis de data

As variáveis de data só podem conter valores de data e hora num formato interno. Os valores atribuídos às variáveis de data com Dateserial, Datevalue, Timeserial ou Timevalue são automaticamente convertidos para o formato interno. As variáveis de data são convertidas em números normais utilizando a função Dia, Mês, Ano ou a função de Hora, Minuto, Segundo. O formato interno permite comparar os valores de data e hora calculando a diferença entre dois números. Estas variáveis só podem ser declaradas com a palavra-chave Data.

Dim Variable As Date

Literals for Dates

Date literals allow to specify unambiguous date variables that are independent from the current language. Literals are enclosed between hash signs #. Possible formats are:

• #yyyy-mm-dd#

• #mm/dd/yyyy#

  start_date = #12/30/1899# ' = 1
  dob = #2010-09-28#

The Variant type

Variables declared as Variant can handle any data type. This means that the actual data type is defined during runtime as a value is assigned to the variable.

There are three main ways to create a Variant variable, as shown below:

  Dim varA            ' The type is not specified, hence the variable is a Variant
  Dim varB as Variant ' The variable is explicitly declared as a Variant
  varC = "abc"        ' Previously undeclared variables are treated as Variants

The example below uses the TypeName function to show how the type of a Variant variable changes upon assignment.

  Dim myVar As Variant
  MsgBox TypeName(myVar) ' Empty
  myVar = "Hello!"
  MsgBox TypeName(myVar) ' String
  myVar = 10
  MsgBox TypeName(myVar) ' Integer

A Variant variable is initialized with the Empty special data type. You can use the IsEmpty function to test if a variable is an Empty Variant.

You can also use the keyword Any to declare a variable as a Variant. However, Any is deprecated and is available for backward compatibility.

Arguments with type Variant or Any passed in function calls are not checked for their types.

  Dim myVar As Any ' Variable "myVar" is a Variant

Valores de variáveis iniciais

Assim que a variável for definida, fica automaticamente definida com o valor "Nulo". Atenção às seguintes convenções:

As variáveis numéricas recebem automaticamente o valor "0" assim que são definidas.

As variáveis de data recebem o valor 0 internamente; o que é equivalente a converter o valor para "0" com a função Dia, Mês, Ano ou Hora, Minuto, Segundo.

Quando declaradas, as variáveis de cadeia recebem uma cadeia vazia ("").

Matrizes

O Collabora Office Basic reconhece matrizes unidimensionais ou multidimensionais, definidas por um tipo de variável especificado. As matrizes são adequadas para editar listas e tabelas em programas. Pode aceder aos elementos de uma matriz através de um índice numérico.

As matrizes têm de ser declaradas com a instrução Dim. Há diversas formas de definir o intervalo de um índice numa matriz:

    Dim Text$(20)       '21 elements numbered from 0 to 20'
    Dim Text$(5,4)      '30 elements (a matrix of 6 x 5 elements)'
    Dim Text$(5 To 25)  '21 elements numbered from 5 to 25'
    Dim Text$(-15 To 5) '21 elements (including 0), numbered from -15 to 5'

O intervalo do índice pode incluir números positivos e números negativos.

Constantes

As constantes têm um valor fixo. Apenas são definidas uma vez no programa e não podem ser redefinidas mais tarde:

Const ConstName=Expression