Funções de texto
Essa seção contém descrições das funções de Texto.
Utilizar aspas duplas em fórmulas
Para incluir um texto numa fórmula, coloque o texto entre aspas duplas (") e o Calc irá interpretá-los. Por exemplo, a fórmula "Olá mundo!" exibe o texto Olá mundo! na célula, sem aspas duplas ao redor.
A fórmula mais complexa =CONCATENAR ("A vida é realmente simples, "; "mas insistimos em torná-la complicada "; "(Confúcio).") concatena três textos individuais entre aspas duplas, gerando A vida é muito simples, mas insistimos em torná-la complicada (Confúcio).
Para colocar aspas duplas literalmente num texto dentro de uma fórmula, dois métodos podem ser usados:
-
Você pode "escapar" as aspas duplas com aspas duplas adicionais, e o Calc trata as aspas duplas de escape como um valor literal. Por exemplo, a fórmula ="Meu nome é ""João""." retorna o texto Meu nome é "João". Outro exemplo simples é a fórmula =UNICODE ("""") que retorna 34 , o valor decimal do caractere de aspas Unicode (U+0022) - aqui a primeira e a quarta aspas duplas indicam o início e fim do texto, enquanto a segunda aspa dupla escapa da terceira.
-
Você pode usar a função CARACT ou a função CARACT.UNICODE para inserir aspas duplas. Por exemplo, a fórmula =CARACT.UNICODE(34) & "Gabriela, Cravo e Canela" & CARACT.UNICODE(34) & "é um livro famoso de Jorge Amado." exibe o texto "Gabriela, Cravo e Canela" é um livro famoso de Jorge Amado.
Tenha em conta que a função de Autocorreção do Calc pode modificar aspas duplas. A Autocorreção não deve alterar as aspas duplas nas células de fórmula, mas pode alterar aquelas usadas em células que não são de fórmula que contêm texto. Por exemplo, se copiar uma string envolta por alguma outra forma de aspas duplas tipográficas, como as aspas duplas à esquerda (U+201C) e as aspas duplas à direita (U+201D), e depois colar em um célula de fórmula, pode ocorrer um erro. Abra a área Aspas duplas da caixa de diálogo para definir os caracteres usados para corrigir automaticamente as aspas duplas tipográficas iniciais e finais. Desmarque o botão de alternância para desativar o recurso.
ARRUMAR
Remove os espaços de uma cadeia de caracteres, deixando apenas um único caractere de espaço entre as palavras.
ARRUMAR("Texto")
Texto refere-se ao texto com espaços removidos.
ARRUMAR(" Olá mundo ") devolve Olá mundo, sem os espaços antes e depois do texto e com apenas um espaço entre as palavras.
BAHTTEXT
Converte um número em texto tailandês, incluindo nomes da moeda tailandesa.
BAHTTEXT(Número)
Número é qualquer número. "Baht" será anexado à parte integral do número, e "Satang" será anexado à parte decimal do número.
=BAHTTEXT(12.65) retorna um texto em caracteres tailandeses significando "Doze Baht e sessenta e cinco Satang".
COM.MICROSOFT.BAHTTEXT
BASE
Converte um número inteiro positivo para uma base específica num texto a partir do sistema de numeração. São usados os dígitos 0–9 e as letras A–Z.
BASE(Número; Radical [; TamanhoMínimo])
Número é o inteiro positivo a converter.
Radical indica a base do sistema de numeração. Pode ser qualquer inteiro positivo entre 2 e 36.
TamanhoMínimo (opcional) determina o tamanho mínimo da cadeia de caracteres criada. Se o texto for mais curto que o indicado em TamanhoMínimo, zeros são adicionados à esquerda do texto.
=BASE(17;10;4) retorna 0017 no sistema decimal.
=BASE(17;2) retorna 10001 no sistema binário.
=BASE(255;16;4) retorna 00FF no sistema hexadecimal.
CARACT
Converte um número em um caractere de acordo com a tabela de código atual. O número pode ser um inteiro de dois ou três dígitos.
CARACT(Número)
Número é um número entre 1 e 255 representando o código do caractere.
=CARACT(100) retorna o caractere «d».
="abc" & CHAR(10) & "def" insere um caractere de nova linha em uma cadeia de caracteres.
CARACT.UNICODE
Converte um número de código em um caractere Unicode ou letra.
CARACT.UNICODE(número)
=CARACT.UNICODE(169) retornará o caractere de Copyright ©.
Veja também a função UNICODE().
CONCATENAR
Combina várias cadeias de caracteres de texto em apenas uma cadeia de caracteres.
CONCATENAR(Texto 1[; Texto 2 [; … [; Texto 255]]])
Texto 1[; Texto 2][; … ;[Texto 255]] são textos ou referencia a células contendo textos.
=CONCATENAR("Bom ";"dia ";"Dona ";"Maria") retorna: Bom dia Dona Maria.
CÓDIGO
Retorna um código numérico para o primeiro caractere em uma cadeia de caracteres de texto.
CÓDIGO("Texto")
Texto é o texto onde o código do primeiro caractere será encontrado.
=CÓDIGO("Hieronymus") retorna 72, =CÓDIGO("hieroglyphic") retorna 104.
O código utilizado aqui não se refere ao ASCII, mas à tabela de códigos carregada no momento.
DECIMAL
Converte texto com caracteres de um sistema de numeração para um inteiro positivo na base do radical. O radical deve estar entre 2 e 36. Espaços e tabulações são ignorados. O campo Texto não é sensível à caixa.
Se o radical for 16, serão ignorados x, 0x, X ou 0X anteriores ao número e h ou H posteriores ao número. Se o radical for 2, serão ignorados b ou B posteriores ao número. Caracteres que não pertencem ao sistema de numeração geram um erro.
DECIMAL("Texto"; Radical)
Texto é o texto a converter.
Radical indica a base do sistema de numeração. Pode ser qualquer inteiro positivo entre 2 e 36.
=DECIMAL("17";10) retorna 17.
=DECIMAL("FACE";16) retorna 64206.
=DECIMAL("0101";2) retorna 5.
DEF.NÚM.DEC
Retorna um número como texto com um número determinado de casas decimais e separadores de milhar opcionais.
DEF.NÚM.DEC(Número; [Decimais = 2 [; SemSeparadorDeMilhar = FALSO]])
Número é arredondado para casas Decimais (após o separador decimal) e o resultado formatado como texto, usando as configurações específicas de localidade.
Decimais (opcional) refere-se ao número de casas decimais a serem exibidas. Se Decimais for negativo, Número é arredondado para casas de ABS (Decimais) à esquerda da vírgula decimal. Se Decimais for uma fração, ele será truncado, ignorando qual é o número inteiro mais próximo.
SemSeparadorDeMilhar (opcional) determina se o separador de milhar será utilizado. Se VERDADEIRO ou não nulo, o separador de milhar será suprimido to texto resultante. Se o separador for zero ou se for omitido, será exibido o separador de milhar de sua configuração atual de local.
=DEF.NÚM.DEC(1234567,89;3) retorna 1.234.567,890 como um texto.
=DEF.NÚM.DEC(123456,789;;VERDADEIRO) retorna 123456,79 como um texto.
=DEF.NÚM.DEC(12345,6789; -2) retorna 12.300 como um texto.
=DEF.NÚM.DEC(1234567,89;-3;1) retorna 12135000 como um texto.
=DEF.NÚM.DEC(123456,789;3/4) retorna 12.3456 como um texto.
=DEF.NÚM.DEC(123456,789;8/5) retorna 12.345,8 como um texto.
DIREITA
Retorna o último caractere ou caracteres de um texto.
DIREITA("Texto" [; Número])
Texto é o texto cuja parte direita será determinada.
Número (opcional) especifica o número de caracteres da parte direita do texto. Se o parâmetro estiver ausente, retorna apenas um caractere.
=DIREITA("Sun";2) retorna un.
DIREITAB
Retorna o último caractere ou caracteres dum texto com DBCS (conjunto de caracteres de bytes duplos).
DIREITAB("Texto" [; Número])
Texto é o texto em que a parte direita será determinada.
Núm_bytes (opcional) especifica o número de caracteres a extrair com DIREITAB, em bytes. Se este parâmetro não for definido, retorna um byte.
DIREITAB("中国";1) retorna " " (1 byte é só metade de um caractere DBCS e um caractere de espaço será retornado).
DIREITAB("中国";2) retorna "国" (2 bytes constituem um caractere DBCS completo).
DIREITAB("中国";3) retorna " 国" (3 bytes constituem meio caractere DBCS e um caractere DBCS inteiro, um espaço em branco será retornado para a primeira metade).
DIREITAB("中国";4) retorna "中国" (4 bytes constituem dois caracteres DBCS completos).
DIREITAB("office";3) retorna "ice" (3 caracteres não-DBCS cada um consistindo de 1 byte).
ESQUERDA
Retorna o primeiro caractere ou caracteres de um texto.
ESQUERDA("Texto" [; Número])
Texto é o texto onde as palavras iniciais parciais serão determinadas.
Número (opcional) especifica o número de caracteres do texto inicial. Se o parâmetro estiver ausente, apenas um caractere será retornado.
=ESQUERDA("saída";3) retorna “saí”.
ESQUERDAB
Retorna os primeiros caracteres de um texto em DBCS (conjunto de caracteres de bytes duplos).
ESQUERDAB("Texto" [; Número])
Texto é a cadeia de texto cujas letras iniciais deseja determinar.
Número (opcional) especifica o número de caracteres a extrair com ESQUERDAB, em bytes. Se este parâmetro não for definido, um caractere será retornado.
=ESQUERDAB("中国";1) retorna " " (1 byte é só metade de um caractere DBCS e a função retorna um espaço no lugar).
=ESQUERDAB("中国";2) retorna "中" (2 bytes constituem um caractere DBCS completo).
=ESQUERDAB("中国";3) retorna "中 " (3 bytes constituem um caractere DBCS e meio; o último caractere retornado é portanto um caractere de espaço).
=ESQUERDAB("中国";4) retorna "中国" (4 bytes constituem dois caracteres DBCS completos).
=ESQUERDAB("office";3) retorna "off" (3 caracteres não-DBCS, cada um consistindo de 1 byte).
EXATO
Compara duas cadeias de caracteres de texto e retorna VERDADEIRO se elas forem idênticas. Esta função faz distinção entre maiúsculas e minúsculas.
EXATO("Texto1"; "Texto2")
Texto1 refere-se ao primeiro texto da comparação.
Texto2 é o segundo texto para comparar.
=EXATO("microsystems";"Microsystems") retorna FALSO.
EXT.TEXTO
Retorna uma cadeia de caracteres de texto de um texto. Os parâmetros especificam a posição inicial e o número de caracteres.
EXT.TEXTO("Texto"; Início; Número)
Texto é o texto contendo os caracteres a extrair.
Início é a posição do primeiro caractere no texto a extrair.
Número especifica o número de caracteres na parte do texto.
=EXT.TEXTO("office";2;2) retorna ff.
EXT.TEXTOB
Retorna uma cadeia de caracteres de um texto em DBCS (conjunto de caracteres de bytes duplos). Os parâmetros especificam a posição inicial e o número de caracteres.
EXT.TEXTOB("Texto"; Início; Número)
Texto é o texto contendo os caracteres a extrair.
Início é a posição do primeiro caractere no texto a extrair.
Número especifica o número de caracteres a retornar do texto, em bytes.
=EXT.TEXTOB("中国";1;0) retorna "" (0 bytes é sempre uma cadeia de caracteres vazia).
=EXT.TEXTOB("中国";1;1) retorna " " (1 byte é só meio caractere DBCS e, portanto, o resultado é um caractere de espaço).
=EXT.TEXTOB("中国";1;2) retorna "中" (2 bytes constituem um caractere DBCS completo).
=EXT.TEXTOB("中国";1;3) retorna "中 " (3 bytes constituem um caractere DBCS e meio, e o último byte resulta num caractere de espaço).
=EXT.TEXTOB("中国";1;4) retorna "中国" (4 bytes constituem dois caracteres DBCS completos).
=EXT.TEXTOB("中国";2;1) retorna " " (o byte na posição 2 não está no início de um caractere de uma cadeia DBCS; retorna 1 caractere de espaço).
=EXT.TEXTOB("中国";2;2) retorna " " (o byte na posição 2 aponta para a última metade do primeiro caractere na cadeia DBCS; os dois bytes demandados constituem o último byte do primeiro caractere e a primeira metade do segundo caractere na cadeia; dois caracteres de espaço são então retornados).
=EXT.TEXTOB("中国";2;3) retorna " 国" (o byte na posição 2 não está no início de um caractere numa cadeia DBCS; retorna um espaço para o byte na posição 2).
=EXT.TEXTOB("中国";3;1) retorna " " (o byte na posição 3 está no começo de um caractere numa cadeia DBCS, mas 1 byte é somente metade de um caractere DBCS e um espaço será retornado em seu lugar).
=EXT.TEXTOB("中国";3;2) retorna "国" (o byte na posição 3 está no começo de um caractere numa cadeia DBCS, e 2 bytes constituem um caractere DBCS).
=EXT.TEXTOB("office";2;3) retorna "ffi" (o byte na posição 2 está no começo de um caractere numa cadeia que não é DBCS, e 3 bytes de uma cadeia não-DBCS constituem 3 caracteres).
LOCALIZAR
Retorna a posição de um segmento de texto dentro de uma cadeia de caracteres. Você pode definir o início da pesquisa como uma opção. O texto de pesquisa pode ser um número ou qualquer cadeia de caracteres. A pesquisa não distingue maiúsculas e minúsculas. Se o texto não for encontrado, retorna o erro 519 (#VALOR).
A pesquisa suporta caracteres coringa ou expressões regulares. Com as expressões regulares ativadas, você pode inserir "all.*", por exemplo, para encontrar a primeira ocorrência de "all" seguida de qualquer outro caractere. Se deseja pesquisar por um texto que também é uma expressão regular, você deve preceder cada caractere com o caractere "\", ou incluir o texto entre \Q...\E. Você pode ativar a avaliação de caracteres coringa ou expressões regulares em .
Ao usar funções onde um ou mais argumentos são textos de critérios de pesquisa que representam uma expressão regular, a primeira tentativa é de converter o texto do critério em número. Por exemplo, ".0" se converterá em 0.0 e assim por diante. Se tiver sucesso, a verificação não será por expressão regular, mas por conversão numérica. Entretanto, ao mudar de região onde o separador decimal não é mais o ponto, a expressão regular passa a valer. Para forçar a avaliação da expressão regular de uma expressão numérica, utilize uma expressão que não possa ser confundida com um número, como por exemplo, .[0]" ou ".\0" or mesmo "(?i).0".
LOCALIZAR("ProcurarTexto"; "Texto" [; Posição])
ProcurarTexto é o texto a ser localizado.
Texto é o texto onde a pesquisa ocorrerá.
Posição (opcional) é a posição no texto onde a pesquisa deve começar.
=LOCALIZAR(54;998877665544) retorna 10.
MAIÚSCULA
Converte a cadeia de caracteres especificada no campo texto em letras maiúsculas.
MAIÚSCULAS("Texto")
Texto refere-se às letras minúsculas que deseja converter em maiúsculas.
=MAIÚSCULA("Bom dia") retorna BOM DIA.
MINÚSCULA
Converte todas as letras maiúsculas de uma cadeia de caracteres de texto em letras minúsculas.
MINÚSCULAS("Texto")
Texto refere-se ao texto a ser convertido.
=MINÚSCULA("Sun") retorna sun.
MOEDA
Converte um número em uma string representando o valor no formato de moeda, arredondado para casas decimais especificadas, usando o separador decimal que corresponde ao configuração de localidade atual. No campo Valor digite o número a ser convertido. Opcionalmente, você pode inserir o número de casas decimais no campo Decimais. Se nenhum valor for especificado, todos os números em formato de moeda serão exibidos com duas casas decimais.
Você define o formato monetário nas configurações do seu sistema.
MOEDA(Valor [; Decimais])
Valor é um número, uma referência a uma célula contendo um número, ou uma fórmula que retorna um número.
Decimais é o número opcional de casas decimais.
=MOEDA(255) retorna $255.00 para a região Inglês (USA) e moeda USD (dollar); ￥255.00 para a região japonesa e moeda JPY (yen); ou 255,00 € para a região Alemanha e moeda EUR (euro).
=MOEDA(367,456;2) retorna R$367,46.
NUM.CARACTB
Para idiomas em DBCS (conjunto de caracteres em duplo byte), retorna o número de bytes usados para representar os caracteres num texto.
NÚM.CARACTB("Texto")
Texto é o texto cujo tamanho será determinado.
NÚM.CARACTB("中") retorna 2 (1 caractere DBCS consistindo de 2 bytes).
NÚM.CARACTB("中国") retorna 4 (2 caracteres DBCS cada um consistindo de 2 bytes).
NÚM.CARACTB("office") retorna 6 (6 caracteres não-DBCS cada um consistindo de 1 byte).
=NÚM.CARACTB("Boa tarde") retorna 9.
=NÚM.CARACTB(12345.67) retorna 8.
NÚM.CARACT
Retorna o tamanho da cadeia de caracteres incluindo espaços.
NÚM.CARACT("Texto")
Texto é o texto cujo tamanho será determinado.
=NÚM.CARACT("Boa tarde") retorna 9.
=NÚM.CARACT(12345.67) retorna 8.
PRI.MAIÚSCULA
Coloca em maiúscula a primeira letra de cada palavra de uma cadeia de caracteres de texto.
PRI.MAIÚSCULA("Texto")
Texto refere-se ao texto a ser convertido.
=PRI.MAIÚSCULA("the document foundation") retorna The Document Foundation
PROCURAR
Retorna a posição de um segmento de texto dentro de uma cadeia de caracteres. Você pode definir o início da pesquisa como uma opção. O texto de pesquisa pode ser um número ou qualquer cadeia de caracteres. A pesquisa não distingue maiúsculas e minúsculas.
PROCURAR("ProcurarTexto"; "Texto" [; Posição])
ProcurarTexto refere-se ao texto a encontrar.
Texto é o texto onde a pesquisa ocorre.
Posição (opcional) é a posição no texto a partir da qual a pesquisa começa.
=PROCURAR(76;998877665544) retorna 6.
REPT
Repete uma cadeia de caracteres pelo número de cópias.
REPT("Texto"; Número)
Texto é o texto a repetir.
Número é o número de repetições.
=REPT("Bom dia";2) retorna Bom diaBom dia.
Consulte a página wiki REPT para mais detalhes
SUBSTITUIR
Substitui parte de uma cadeia de caracteres de texto por uma cadeia de caracteres de texto diferente. Esta função pode ser usada para substituir caracteres e números (que são automaticamente convertidos para texto). O resultado da função é sempre exibido como texto. Se você pretende executar outros cálculos com um número que foi substituído por texto, você precisará convertê-lo de volta para um número usando a função VALOR.
Todos os textos que contém números deverão estar entre aspas se você não desejar que eles sejam interpretados como números e convertidos automaticamente em texto.
MUDAR("Texto"; Posição; Tamanho; "NovoTexto")
Texto refere-se ao texto no qual uma parte será substituída.
Posição refere-se à posição dentro do texto onde a substituição começa.
Tamanho é o número de caracteres no Texto a substituir.
NovoTexto refere-se ao texto que substitui Texto.
=MUDAR("1234567";1;1;"444") retorna "444234567". Um caractere na posição 1 é a substituído pelo texto NovoTexto.
SUBSTITUIR
Substitui o texto antigo pelo novo em uma cadeia de caracteres.
SUBSTITUIR("Texto"; "PesquisarTexto"; "NovoTexto" [; Ocorrência])
Texto é o texto no qual os segmentos de texto serão trocados.
PesquisarTexto é o segmento de texto que será substituído (repetidas vezes).
NovoTexto é o texto que deve substituir o trecho de texto.
Ocorrência (opcional) indica qual ocorrência do texto de pesquisa deve ser substituído. Se o parâmetro for omitido, o texto de pesquisa é substituído em todo o texto.
=SUBSTITUIR("123123123";"3";"abc") retorna 12abc12abc12abc.
=SUBSTITUIR("123123123";"3";"abc";2) retorna 12312abc123.
T
Essa função retorna o texto de destino ou uma cadeia de caracteres de texto em branco se o destino não for texto.
T(Valor)
Se Valor for um texto ou se referir a um texto, T retorna esse texto; caso contrário, ele retorna um texto em branco.
=T(12345) retorna uma cadeia de caracteres vazia.
=T("12345") retorna o texto 12345.
TEXTO
Converte um valor em texto de acordo com um formato especificado.
TEXTO(Valor; Formato)
Valor é o valor (numérico ou textual) a ser convertido.
Formato é o texto que define o formato. Utilize separadores de decimal e milhar de acordo com o idioma definido no formato de célula.
=TEXTO(12,34567;"###,##") retorna o texto 12,35
=TEXTO(12,34567;"000,00") retorna o texto 012,35
=TEXTO("xyz";"=== @ ===") retorna o texto === xyz ===
Veja também Códigos de formato numérico: códigos de formato numérico personalizados definidos pelo usuário.
TIRAR
Todos os caracteres não imprimíveis são removidos da cadeia de caracteres.
TIRAR("Texto")
Texto refere-se ao texto no qual deve-se remover todos os caracteres não imprimíveis.
=NÚM.CARACT(TIRAR(CARACT(7) & "LibreOffice Calc" & CARACT(8))) retorna 16, mostrando que a função TIRAR remove os caracteres Unicode não imprimíveis U+0007 ("BEL") e U+0008 ("BS") no começo e no fim do argumento de texto. A função TIRAR não remove espaços.
UNICODE
Retorna o código numérico para o primeiro caractere Unicode em uma cadeia de caracteres de texto.
UNICODE("Texto")
=UNICODE("©") retornará o número Unicode 169 para o caractere de Copyright.
Veja também a função CARACT.UNICODE()