CreateUnoServiceWithArguments-functie

Creëert een UNO-service met de ProcessServiceManager, inclusief aanvullende optionele argumenten.

CreateUnoServiceWithArguments(ServiceName As String, Arguments() As Variant) As Object

UNO-services die kunnen worden gebruikt met de functie CreateUnoServiceWithArguments zijn identificeerbaar met methodenamen die een naampatroon van createInstanceWith.. of createWith.. volgen.

ServiceName: De naam van de UNO-service die moet worden gemaakt.

Arguments: Eén tot veel argumenten die de instantie van de service specificeren. Argumenten worden opgeslagen als een eendimensionale matrix, volgens hun posities in de definitie van de constructormethode.

Een instantie van de opgegeven UNO-servicenaam, anders Null-waarde.

Ga voor een lijst met beschikbare services naar de referentiepagina com::sun::star-module.

Het voorbeeld van com.sun.star.ui.dialogs.FilePicker hieronder geeft een dialoogvenster Opslaan als weer met twee extra bedieningselementen: een keuzelijst en een selectievakje.

Sub FileSaveAsDialog()
   td = com.sun.star.ui.dialogs.TemplateDescription
   options = td.FILESAVE_AUTOEXTENSION_TEMPLATE
   dlg = CreateUnoServiceWithArguments( _
      "com.sun.star.ui.dialogs.FilePicker", _
      Array(options))
End Sub ' FileSaveAsDialog

UNO-diensten hebben een uitgebreide online documentatie op de website api.libreoffice.org. Bezoek de referentiepagina FilePicker Service voor meer informatie over de methoden die door de service gebruikt in het bovenstaande voorbeeld.

De volgende code gebruikt de service com.sun.star.security.DocumentDigitalSignatures om het huidige document te ondertekenen:

Sub  SignCurrentDocDialog
   Dim pv(0) as new com.sun.star.beans.PropertyValue
   pv(0).Name  = "StorageFormat"
   pv(0).Value = "ZipFormat"
   mode = com.sun.star.embed.ElementModes
   sf = CreateUnoService("com.sun.star.embed.StorageFactory")
   storage = sf.createInstanceWithArguments(Array(ThisComponent.URL, mode.WRITE, pv))
   dds = CreateUnoServiceWithArguments( _
      "com.sun.star.security.DocumentDigitalSignatures", _
      Array("1.2", True))
   dds.signDocumentContent(storage, Null)
End Sub ' SignCurrentDocDialog

CreateWithVersion en createWithVersionAndValidSignature constructormethoden in com.sun.star.security.DocumentDigitalSignatures UNO-service geeft twee verschillende manieren aan om deze service te instantiëren met de functie CreateUnoServiceWithArguments.