Functie MkDir

Diagram instructie MkDir

Maakt een nieuwe directory aan op een gegevensmedium.

Syntaxis:


MkDir pad

Parameters:

path: Een tekst die de naam en het pad bevat van de map die moet worden aangemaakt. U kunt ook de URL-notatie gebruiken.

Als het pad niet kan worden bepaald, zal de gespecificeerde map in de huidige map worden gemaakt.

Foutcodes:

5 Ongeldige aanroep van procedure

76 Pad niet gevonden

Voorbeeld:


Sub ExampleFileIO
' Voorbeeld voor de functies die het bestand ordenen
Const sFile1 As String = "file://c|/autoexec.bat"
Const sDir1 As String = "file://c|/Temp"
Const sSubDir1 As String ="Test"
Const sFile2 As String = "Gekopieerd.tmp"
Const sFile3 As String = "Hernoemd.tmp"
Dim sFile As String
    sFile = sDir1 + "/" + sSubDir1
    ChDir( sDir1 )
    If Dir(sSubDir1,16)="" Then ' Bestaat de map?
        MkDir sSubDir1
        MsgBox sFile,0,"Maak de map"
    End If
    sFile = sFile + "/" + sFile2
    FileCopy sFile1 , sFile
    MsgBox fSysURL(CurDir()),0,"Huidige directory"
    MsgBox sFile & Chr(13) & FileDateTime(sFile),0,"= tijd waarop gemaakt:"
    MsgBox sFile & Chr(13)& FileLen(sFile),0,"Bestandsgrootte"
    MsgBox sFile & Chr(13)& GetAttr(sFile),0,"Bestandsattributen"
    Name sFile As sDir1 + "/" + sSubDir1 + "/" + sFile3
    ' Hernoemen in dezelfde map
    sFile = sDir1 + "/" + sSubDir1 + "/" + sFile3
    SetAttr(sFile, 0) ' Verwijder alle attributen
    MsgBox sFile & Chr(13) & GetAttr(sFile),0,"Nieuwe bestandsattributen"
    Kill sFile
    RmDir sDir1 + "/" + sSubDir1
End Sub
 
' Converteert een systeempad in URL
Function fSysURL( fSysFp As String ) As String
Dim iPos As String
    iPos = 1
    iPos = Instr(iPos,fSysFp, getPathSeparator())
    Do While iPos > 0
        Mid( fSysFp, iPos , 1,"/")
        iPos = Instr(iPos+1,fSysFp, getPathSeparator())
    Loop
    ' De dubbele punt met DOS
    iPos = Instr(1,fSysFp,":")
    If iPos > 0 Then Mid( fSysFp, iPos , 1,"|")
    fSysURL = "file://" & fSysFp
End Function