Categoria Testo
In questa sezione sono descritte le funzioni della categoria Testo.
Uso delle virgolette doppie nelle formule
Per includere una stringa di testo in una formula inseritela tra virgolette doppie ("), in tal modo i caratteri della stringa verranno acquisiti senza essere interpretati. Per esempio, la formula ="Ciao mondo!" visualizza la stringa di testo Ciao mondo! nella cella, senza virgolette doppie.
La formula più complessa =CONCATENA("La vita è davvero semplice, "; "ma ci ostiniamo a renderla complicata "; "(Confucio).") concatena tre stringhe distinte tra virgolette doppie, generando La vita è davvero semplice, ma ci ostiniamo a renderla complicata (Confucio).
Per inserire una virgoletta doppia letterale in una stringa all'interno di una formula, è possibile utilizzare due metodi:
-
È possibile eseguire l'escape delle doppie virgolette con un'ulteriore doppia virgoletta, nel qual caso Calc considera le doppie virgolette precedute da escape come un valore letterale. Ad esempio, la formula ="Il mio nome è ""Mario Rossi""." restituisce la stringa Il mio nome è "Mario Rossi". Un altro semplice esempio è la formula =UNICODE("""") che restituisce 34, il valore decimale del carattere Unicode delle virgolette (U+0022) — qui la prima e la quarta doppia virgoletta indicano l'inizio e la fine della stringa, mentre la seconda doppia virgoletta è un escape della terza.
-
È possibile usare la funzione CODICE.CARATT o la funzione CARATT.UNI per inserire una virgoletta doppia. Ad esempio, la formula =CARATT.UNI(34) & "Il giovane Holden" & CARATT.UNI(34) & " è un celebre romanzo di J.D. Salinger." visualizza la stringa "Il giovane Holden" è un celebre romanzo di J.D. Salinger.
È bene tenere presente che la funzione Correzione automatica di Calc può modificare le virgolette doppie. La correzione automatica non deve modificare le virgolette doppie all'interno delle celle delle formule, ma può modificare quelle utilizzate nelle celle non contenenti formule, ma testo. Ad esempio, se si copia una stringa racchiusa tra virgolette doppie di altro tipo, come le virgolette doppie di sinistra (U+201C) e le virgolette doppie di destra (U+201D), e la si incolla in una cella formula, potrebbe verificarsi un errore. Accedere quindi all'area Virgolette doppie della finestra di dialogo per impostare i caratteri utilizzati per la correzione automatica delle virgolette doppie tipografiche iniziali e finali. Deselezionare l'opzione per disattivare la funzione.
ANNULLA.SPAZI
Rimuove gli spazi da una stringa, lasciando un singolo spazio tra le parole.
ANNULLA.SPAZI("Testo")
Testo indica il testo in cui gli spazi devono essere rimossi.
=ANNULLA.SPAZI(" ciao mondo ") restituisce ciao mondo senza spazi davanti e dietro e con un singolo spazio tra le parole.
BASE
Converte un numero intero positivo in un testo da un sistema numerico alla base indicata. Vengono usate le cifre 0-9 e le lettere A-Z.
BASE(Numero; Radice [; Lunghezza_minima])
Numero è l'intero positivo da convertire.
Radice indica la base del sistema numerico. Può essere un intero positivo compreso tra 2 e 36.
Lunghezza minima (opzionale) determina la lunghezza minima della sequenza di caratteri creata. Indicando questo parametro, se il testo è più breve verrà completato con degli zeri a sinistra della stringa.
=BASE(17;10;4) restituisce 0017 nel sistema decimale.
=BASE(17;2) restituisce 10001 nel sistema binario.
=BASE(255;16;4) restituisce 00FF nel sistema esadecimale.
CARATT.UNI
Converte un numero di codice in un carattere o una lettera Unicode.
CARATT.UNI(Numero)
=CARATT.UNI(169) restituisce il carattere di copyright ©.
Vedere anche la funzione UNICODE().
CODICE
Restituisce il codice numerico del primo carattere di un testo o di una stringa.
CODICE("Testo")
Testo è il testo per il quale si desidera trovare il codice del primo carattere.
La funzione =CODICE("Geronimo") restituisce 71, la funzione =CODICE("geroglifico") 103.
Il codice qui utilizzato non è un codice ASCII ma il codice della tabella corrente.
CODICE.CARATT
Converte un numero in un carattere in base alla tabella codici attuale. Il numero può essere un numero intero di due o tre cifre.
CODICE.CARATT(Numero)
Numero è un numero tra 1 e 255 che rappresenta il codice per il carattere.
=CODICE.CARATT(100) restituisce il carattere "d".
="abc" & CODICE.CARATT(10) & "def" inserisce un carattere di nuova riga all'interno della stringa.
CONCATENA
Combina più stringhe di testo in un'unica stringa.
CONCATENA(Stringa 1 [; Stringa 2 [; … [; Stringa 255]]])
Stringa 1[; Stringa 2][; … ;[Stringa 255]] sono stringhe o riferimenti a celle contenenti stringhe.
=CONCATENA("Buon";"giorno ";"signora "; "Rossi") restituisce Buongiorno signora Rossi.
DECIMALE
Converte un testo rappresentante un numero in un sistema numerico con la radice base indicata elevata a un intero positivo. La radice deve essere compresa nell'intervallo da 2 a 36. Spazi e tabulazioni sono ignorati. Il campo testo non distingue tra maiuscole e minuscole.
Se la radice è 16, una x o X o 0x o 0X iniziali e una h o H finali non vengono considerate. Se la radice è 2, una b o B finale non vengono considerate. Altri caratteri che non appartengono al sistema numerico generano un errore.
DECIMALE("Testo"; Radice)
Testo è il testo da convertire.
Radice indica la base del sistema numerico. Può essere un numero intero tra 2 e 36.
=DECIMALE("17";10) restituisce 17.
=DECIMALE("CADE";16) restituisce 51934.
=DECIMALE("0101"; 2) restituisce 5.
DESTRA
Restituisce l'ultimo o gli ultimi caratteri di una stringa di testo.
DESTRA("Testo" [; Numero])
Testo è il testo la cui parte destra deve essere determinata.
Numero (opzionale) è il numero di caratteri da estrarre dalla parte destra del testo. Se questo parametro non è definito, viene restituito un solo carattere.
=DESTRA("Sole";2) restituisce le.
DESTRA.B
Restituisce l'ultimo o gli ultimi caratteri di un testo, con gruppi di caratteri a doppio byte (DBCS).
DESTRA.B("Testo" [; Numero_byte])
Testo è il testo la cui parte destra deve essere determinata.
Numero_byte (opzionale) specifica il numero di caratteri che DESTRA.B deve estrarre, basato sui byte. Se questo parametro non è definito, viene restituito un solo byte.
DESTRA.B("中国";1) restituisce " " (un byte è solo metà carattere DBCS, e viene invece restituito un carattere di spazio).
DESTRA.B("中国";2) restituisce "国" (due byte costituiscono un carattere DBCS completo).
DESTRA.B("中国";3) restituisce " 国" (tre byte costituiscono mezzo carattere DBCS e un carattere DBCS intero; viene restituito uno spazio per il primo mezzo carattere).
DESTRA.B("中国";4) restituisce "中国" (quattro byte costituiscono due caratteri DBCS completi).
DESTRA.B("office";3) restituisce "ice" (tre caratteri non DBCS, ciascuno formato da un byte).
FISSO
Restituisce un numero come testo con un numero di cifre decimali fisso e con o senza separatore delle migliaia.
FISSO(Numero; [Decimali = 2 [; Nessun separatore migliaia = FALSO]])
Numero è arrotondato alle cifre decimali (dopo il separatore decimale) e il risultato formattato come testo, utilizzando le impostazioni locali specifiche.
Decimali (opzionale) si riferisce al numero di cifre decimali da visualizzare. Se Decimali è negativo, Numero è arrotondato a ASS(Decimali) posizioni alla sinistra della virgola. Se Decimali è una frazione, viene troncato ignorando quale sia l'intero più vicino.
Nessun separatore migliaia (opzionale) determina se debba essere usato il separatore delle migliaia. Se è VERO o diverso da zero, allora i separatori di gruppo vengono omessi dalla stringa risultante. Se il parametro è uguale a 0 o totalmente mancante, vengono visualizzati i separatori delle migliaia delle vostre impostazioni locali attuali.
=FISSO(1234567,89;3) restituisce 1.234.567,890 come stringa di testo.
=FISSO(123456,789;;VERO) restituisce 123456,79 come stringa di testo.
=FISSO(12345,6789;-2) restituisce 12.300 come stringa di testo.
=FISSO(12134567,89;-3;1) restituisce 12135000 come stringa di testo.
=FISSO(12345,789;3/4) restituisce 12.346 come stringa di testo.
=FSSO(12345,789;8/5) restituisce 12.345,8 come stringa di testo.
IDENTICO
Confronta due stringhe e restituisce VERO se sono identiche. Questa funzione distingue tra maiuscole e minuscole.
IDENTICO("Testo 1"; "Testo 2")
Testo 1 è il primo testo da confrontare.
Testo 2 è il secondo testo da confrontare.
=IDENTICO("microsystems";"Microsystems") restituisce FALSE.
LIBERA
Rimuove dal testo tutti i caratteri non stampabili.
LIBERA("Testo")
Testo si riferisce al testo da cui rimuovere tutti i caratteri non stampabili.
=LUNGHEZZA(LIBERA(CARATT.UNI(7) & "LibreOffice Calc" & CARATT.UNI(8))) restituisce 16, poiché la funzione LIBERA rimuove tutti i caratteri non stampabili come gli Unicode U+0007 ("BEL") e U+0008 ("BS") all'inizio e alla fine dell'argomento della stringa. LIBERA non rimuove gli spazi.
LUNGH.B
Per le lingue con gruppo di caratteri a doppio byte (DBCS), restituisce il numero di byte utilizzato per rappresentare i caratteri in una stringa di testo.
LUNGH.B("Testo")
Testo è il testo la cui lunghezza deve essere determinata.
LUNGH.B("中") restituisce 2 (un carattere DBCS formato da due byte).
LUNGH.B("中国") restituisce 4 (due caratteri DBCS, ciascuno formato da due byte).
LUNGH.B("office") restituisce 6 (sei caratteri non DBCS, ciascuno formato da un byte).
=LUNGH.B("Buongiorno") restituisce 14.
=LUNGH.B(12345,67) restituisce 8.
LUNGHEZZA
Restituisce la lunghezza di una stringa, inclusi gli spazi.
LUNGHEZZA("Testo")
Testo è il testo la cui lunghezza deve essere determinata.
=LUNGHEZZA("Buongiorno") restituisce 10.
=LUNGHEZZA(12345,67) restituisce 8.
MAIUSC
Converte la stringa specificata nel campo di testo in maiuscolo.
MAIUSC("Testo")
Testo sono le lettere minuscole da convertire in maiuscole.
=MAIUSC("Buon giorno") restituisce BUON GIORNO.
MAIUSC.INIZ
Converte in maiuscolo la prima lettera di tutte le parole di una stringa di testo.
MAIUSC.INIZ("Testo")
Testo è il testo da convertire.
=MAIUSC.INIZ("the document foundation") restituisce The Document Foundation.
MINUSC
Converte tutto il testo in minuscolo.
MINUSC("Testo")
Testo è il testo da convertire.
=MINUSC("Sun") restituisce sun.
RICERCA
Restituisce la posizione di un segmento di testo all'interno di una stringa di caratteri. L'impostazione dell'inizio della ricerca è opzionale. Il testo da ricercare può essere un numero oppure una sequenza di caratteri. La ricerca non distingue tra maiuscole e minuscole. Se il testo non viene trovato, restituisce l'errore 519 (#VALORE).
La ricerca supporta i caratteri jolly o le espressioni regolari. Se queste ultime sono attivate, è possibile inserire "all.*" per trovare, ad esempio, la prima posizione di "all" seguito da qualsiasi carattere. Se si intende ricercare un testo che sia anche un'espressione regolare, è necessario far precedere sempre il metacarattere o l'operatore dell'espressione dal carattere "\", oppure racchiudere il testo tra \Q...\E. È possibile attivare o disattivare l'analisi dei caratteri jolly o delle espressioni regolari in .
Quando si utilizzano funzioni in cui uno o più argomenti sono stringhe di criteri di ricerca che rappresentano un'espressione regolare, innanzitutto si cerca di convertire i criteri della stringa in numeri. Per esempio, ".0" sarà convertito in 0.0 e così via. In caso di esito positivo, la corrispondenza non sarà quella di un'espressione regolare ma una corrispondenza numerica. Tuttavia, quando si passa a un'impostazione regionale in cui il separatore decimale non è il punto, tale passaggio fa funzionare la conversione in espressione regolare. Per forzare la valutazione dell'espressione regolare, anziché di quella numerica, utilizzare un'espressione che non possa essere erroneamente interpretata come numerica, per es., ".[0]", ".\0" oppure "(?i).0".
RICERCA("Testo ricercato"; "Testo" [; Posizione])
TrovaTesto è il testo da cercare.
Testo è il testo da cui parte la ricerca.
Posizione (opzionale) è la posizione nel testo da cui iniziare la ricerca.
=RICERCA(54; 998877665544) restituisce 10.
RIMPIAZZA
Sostituisce più volte testi parziali in un testo. Questa funzione permette di sostituire sia lettere che cifre (queste vengono convertite automaticamente in testo). Il risultato della funzione è sempre un testo. Se volete continuare a calcolare con un numero che è stato sostituito, è necessario prima convertirlo nel formato numerico ricorrendo alla funzione VALORE.
Ricordate di inserire qualsiasi testo contenente dei numeri tra virgolette, se non volete che sia interpretato come numero e convertito automaticamente in testo.
RIMPIAZZA("Testo"; Posizione; Numero caratteri; "Nuovo testo")
Testo è il testo nel quale si desidera sostituire una parte.
Posizione è la posizione all'interno del testo da cui partirà la sostituzione.
Numero caratteri è il numero di caratteri da sostituire nel Testo.
Nuovo testo è il testo che sostituirà i caratteri in Testo.
=RIMPIAZZA("1234567";1;1;"444") restituisce "444234567". Un carattere alla posizione 1 viene sostituito dai caratteri specificati come Nuovo testo.
RIPETI
Ripete una stringa di caratteri per il numero di volte specificato.
RIPETI("Testo"; Numero)
Testo è il testo da ripetere.
Numero è il numero delle ripetizioni.
=RIPETI("Buon giorno";2) restituisce Buon giornoBuon giorno.
Fare riferimento alla pagina wiki REPT per maggiori dettagli su questa funzione.
SINISTRA
Restituisce il primo o i primi caratteri di un testo.
SINISTRA("Testo" [; Numero caratteri])
Testo è il testo di cui determinare le parole comprese nella parte iniziale.
Numero (opzionale) specifica il numero di caratteri da estrarre da sinistra. Se questo parametro non è definito, viene restituito un solo carattere.
=SINISTRA("disattivare"; 3) restituisce “dis”.
SINISTRA.B
Restituisce i primi caratteri di un testo DBCS.
SINISTRA.B("Testo" [; Numero_byte])
Testo è il testo di cui determinare le parole comprese nella parte iniziale.
Numero_byte (opzionale) specifica il numero di caratteri che SINISTRA.B deve estrarre, basato sui byte. Se questo parametro non è definito, viene restituito un solo carattere.
=SINISTRA.B("中国";1) restituisce " " (un byte è solo metà carattere DBCS, e viene invece restituito un carattere di spazio).
=SINISTRA.B("中国";2) restituisce "中" (due byte costituiscono un carattere DBCS completo).
=SINISTRA.B("中国";3) restituisce "中 " (tre byte costituiscono un carattere DBCS e mezzo; l'ultimo carattere restituito è dunque un carattere di spazio).
=SINISTRA.B("中国";4) restituisce "中国" (quattro byte costituiscono due caratteri DBCS completi).
=SINISTRA.B("office";3) restituisce "off" (tre caratteri non DBCS, ciascuno formato da un byte).
SOSTITUISCI
Sostituisce in una stringa un testo esistente con un nuovo testo.
SOSTITUISCI("Testo"; "CercaTesto"; "Nuovo testo" [; Occorrenza])
Testo è il testo in cui i segmenti devono essere scambiati.
CercaTesto è il segmento di testo da sostituire (un determinato numero di volte).
Nuovo testo è il testo che deve sostituire la parola parziale.
Occorrenza (opzionale) indica quale occorrenza della ricerca deve essere sostituita. Se manca questo parametro, il testo ricercato sarà sostituito completamente.
=SOSTITUISCI("123123123"; "3"; "abc") restituisce 12abc12abc12abc.
=SOSTITUISCI("123123123";"3";"abc";2) restituisce 12312abc123.
STRINGA.ESTRAI
Restituisce una stringa di un testo. I parametri specificano la posizione iniziale e il numero di caratteri.
STRINGA.ESTRAI("Testo", Inizio; Numero)
Testo è il testo contenente i caratteri da estrarre.
Inizio è la posizione del primo carattere da estrarre dal testo.
Numero specifica il numero dei caratteri nella porzione di testo.
=STRINGA.ESTRAI("office";2;2) restituisce ff.
STRINGA.ESTRAI.B
Restituisce una stringa di un testo DBCS. I parametri specificano la posizione iniziale e il numero di caratteri.
STRINGA.ESTRAI.B("Testo", Inizio; Numero_byte)
Testo è il testo contenente i caratteri da estrarre.
Inizio è la posizione del primo carattere da estrarre dal testo.
Numero_byte specifica il numero di caratteri, in byte, che STRINGA.ESTRAI.B restituirà dal testo.
=STRINGA.ESTRAI.B("中国";1;0) restituisce "" (zero byte è sempre una stringa vuota).
=STRINGA.ESTRAI.B("中国";1;1) restituisce " " (un byte è solo mezzo carattere DBCS, dunque il risultato è un carattere di spazio).
=STRINGA.ESTRAI.B("中国";1;2) restituisce "中" (due byte costituiscono un carattere DBCS completo).
=STRINGA.ESTRAI.B("中国";1;3) restituisce "中 " (tre byte costituiscono un carattere DBCS e mezzo; l'ultimo byte è formato da un carattere di spazio).
=STRINGA.ESTRAI.B("中国";1;4) restituisce "中国" (quattro byte costituiscono due caratteri DBCS completi).
=STRINGA.ESTRAI.B("中国";2;1) restituisce " " (la posizione di byte 2 non si trova all'inizio di un carattere in una stringa DBCS; viene restituito uno spazio di carattere).
=STRINGA.ESTRAI.B("中国";2;2) restituisce " " (la posizione di byte 2 punta all'ultima metà del primo carattere nella stringa DBCS; i due byte richiesti costituiscono perciò nella stringa l'ultima metà del primo carattere e la prima metà del secondo; vengono restituiti dunque due spazi di carattere).
=STRINGA.ESTRAI.B("中国";2;3) restituisce " 国" (la posizione di byte 2 non si trova all'inizio di un carattere in una stringa DBCS; viene restituito uno spazio di carattere per la posizione di byte 2).
=STRINGA.ESTRAI.B("中国";3;1) restituisce " " (la posizione di byte 3 si trova all'inizio di un carattere in una stringa DBCS, ma un byte è solo mezzo carattere DBCS, e viene dunque restituito uno spazio di carattere).
=STRINGA.ESTRAI.B("中国";3;2) restituisce "国" (la posizione di byte 3 si trova all'inizio di un carattere in una stringa DBCS, e due byte costituiscono un carattere DBCS).
=STRINGA.ESTRAI.B("office";2;3) restituisce "ffi" (la posizione di byte 2 si trova all'inizio di un carattere in un stringa non DBCS, e tre byte di una stringa non DBCS costituiscono tre caratteri).
T
Questa funzione restituisce il testo di destinazione o una stringa di testo vuota se la destinazione non è il testo.
T(Valore)
Se Valore è una stringa di testo o si riferisce a essa, T restituisce quella stringa di testo; in caso contrario restituisce una stringa vuota.
=T(12345) restituisce una stringa vuota.
=T("12345") restituisce la stringa 12345.
TESTO
Converte un valore in testo in base al formato indicato.
TESTO(Valore; Formato)
Valore è il valore (numerico o di testo) da convertire.
Formato è il testo che definisce il formato. Utilizzate i separatori di decimali e migliaia secondo la lingua impostata nel formato cella.
=TESTO(12,34567;"###,##") restituisce il testo 12,35
=TESTO(12,34567;"000,00") restituisce il testo 012,35
=TESTO("xyz";"=== @ ===") restituisce il testo === xyz ===
Vedere anche Codici dei formati numerici: codici dei formati personalizzati definiti dall'utente.
TESTO.BAHT
Converte un numero in testo tailandese, inclusi i nomi di valute tailandesi.
TESTO.BAHT(Numero)
Numero è qualsiasi numero. "Baht" viene aggiunta alla parte integrale del numero e "Satang" viene aggiunta alla parte decimale del numero.
=TESTO.BAHT(12.65) restituisce una stringa in caratteri tailandesi con il significato di "12 Baht e 65 Satang".
COM.MICROSOFT.BAHTTEXT
TROVA
Restituisce la posizione di una stringa di testo all'interno di un'altra stringa. Potete anche definire la posizione da cui iniziare la ricerca. Il termine da ricercare può essere un numero o qualsiasi stringa di caratteri. La ricerca distingue tra maiuscole e minuscole.
TROVA("Testo ricercato"; "Testo" [; Posizione])
Testo ricercato è il testo che si desidera trovare.
Testo è il testo da cui parte la ricerca.
Posizione (opzionale) è la posizione nel testo da cui iniziare la ricerca.
=TROVA(76; 998877665544) restituisce 6.
UNICODE
Restituisce il codice numerico del primo carattere Unicode di una stringa di testo.
UNICODE("Testo")
=UNICODE("©") restituisce il numero Unicode 169 per carattere di copyright.
Vedere anche la funzione CARATT.UNI().
VALUTA
Converte un numero in una stringa che rappresenta l'importo nel formato valuta, arrotondato alle cifre decimali specificate, utilizzando il separatore decimale corrispondente alla impostazione locale corrente. Nel campo Valore inserire il numero da convertire. Opzionalmente, è possibile inserire il numero di cifre decimali nel campo Decimali. Se non viene specificato alcun valore, tutti i numeri in formato valuta verranno visualizzati con due cifre decimali.
Il formato della valuta viene definito nelle impostazioni del sistema.
VALUTA(Valore [; Decimali])
Valore può essere un numero, un riferimento a una cella che lo contiene o una formula che lo restituisce.
Decimali è il numero opzionale di cifre decimali.
=VALUTA(255) restituisce € 255,00 per l'impostazione locale Italiano (Italia) e valuta (EUR);￥255.00 per l'impostazione locale Giapponese (Giappone) e JPY (yes) come valuta o ancora $255.00 per l'impostazione locale Inglese (USA) e la valuta in USD (Dollari).
=VALUTA(367,456;2) restituisce € 367,46.