MAXIFS funtzioa

Barruti anitzetan irizpide anitz betetzen dituzten gelaxketako balioen maximoa ematen du.

Sintaxia

MAXIFS(FuntzioBarrutia; Barrutia1; Irizpidea1[; Barrutia2; Irizpidea2][; … ; [Barrutia127; Irizpidea127]])

FuntzioBarrutia – derrigorrezko argumentua. Gelaxka-barruti bat, izendun barruti baten izen bat, edo zutabe edo errenkada baten etiketa bat da, maximoa kalkulatzeko erabiliko diren balioak dituena.

Barrutia1: Derrigorrezko argumentua. Gelaxken barruti bat, izendun barruti baten izena edo zutabe edo errenkada baten etiketa da. Irizpidea barruti horri aplikatuko zaio.

Irizpidea: Irizpide bat gelaxka bakarreko erreferentzia, zenbaki edo testu bat da. Gelaxka-edukiekin konparazioak egiteko erabiltzen da.

Gelaxka huts baten erreferentzia 0 zenbakitzat hartzen da.

Bat datorren adierazpen bat honakoa izan daiteke:

Zenbaki bat edo balio logiko bat. Bat datorren gelaxka-edukia zenbaki edo balio logiko horren berdina izango da.
Konparatzaile batekin (<, <=, =, >, >=, <>) hasten den balio bat.

= ikurrarekin, balioa hutsik badago, gelaxka hutsekin bat egingo du.

<> ikurrarekin, balioa hutsik badago, hutsik ez dauden gelaxkekin bat egingo du.

<> ikurrarekin, balioa ez badago hutsik, edozein gelaxka-edukirekin bat egingo du, gelaxka hutsak barne, balio horrekin salbu.

Oharra: "=0" balioak ez du bat egiten gelaxka hutsekin.

= eta <> eragileetarako, balioa hutsik ez badago eta zenbaki mota gisa edo horren azpimota gisa interpretatu ezin bada eta = eta <> bilaketa-irizpideak gelaxka osoei aplikatu behar zaizkie propietatea markatuta badago, konparazioa gelaxka-eduki osoekin egingo da. Markatuta ez badago, konparazioa irizpideekin bat datorren eremu-zatiarekin egingo da.
Beste testu-balio batzuk. = eta <> bilaketa-irizpideak gelaxka osoei aplikatu behar zaizkie propietatea egia bada, konparazioa gelaxka-eduki osoekin egingo da. Faltsua bada, konparazioa irizpideekin bat datorren eremu-zatiarekin egingo da. Adierazpenak testua, zenbakiak adierazpen erregularrak zein komodinak (kalkulu-aukeretan gaituta badaude) eduki ditzake.

Barrutia2 – Aukerakoa. Barrutia2 eta hurrengoek Barrutia1 parametroaren esanahi bera dute.

Irizpidea2: Aukerakoa. Parametro hau eta ondoren datozenak 'Irizpidea' parametroaren berdinak dira.

Bilaketan komodinak eta adierazpen erregularrak onartzen dira. Adierazpen erregularrak gaitzen badira, "egun.*" sartu daiteke, adibidez, hasieran "egun" duen lehen hitza aurkitzeko. Adierazpen erregularra den testu bat aurkitu nahi izanez gero, erabili "\" karaktere bat horietako edozeinen aurrean edo inguratu testua \Q...\E karaktereekin. Komodinen eta adierazpen erregularren ebaluazio automatikoa aktibatu edo desaktibatu daiteke - Collabora Office Calc - Kalkulatu aukeran.

Adierazpen erregular bat ordezkatzen duten bilaketa-irizpideko kateak diren argumentu bat edo gehiago dituzten funtzioak erabiltzean, lehen aldian kate-irizpide horiek zenbaki bihurtzeko saialdia egingo da. Adibidez, ".0" katea 0.0 bihurtuko da, eta abar. Ongi bihurtzen bada, bat etortzea ez da izango adierazpen erregularreko bat etortzea, baizik eta zenbakizko bat etortzea. Hala ere, dezimalen bereizlea puntua ez den eskualde-ezarpen batean, adierazpen erregularraren bihurketak funtzionatu egingo du. Zenbakizko adierazpen bat sortu ordez adierazpen erregularraren ebaluazioa behartzeko, erabili zenbakitzat hartu ezin daitezkeen adierazpenak, adibidez ".[0]" edo ".\0" edo "(?i).0".

FuntzioBarrutia eta Barrutia1,Barrutia2... parametroek tamaina bera izan behar dute, bestela funtzioak 'err:502 - Baliogabeko argumentua' errorea itzuliko du.

Irizpideen arteko erlazio logikoa AND logiko modura definitu daiteke. Alegia, emandako irizpide guztiak betetzen badira (eta soilik horrela bada), hartuko da kontuan kalkuluan emandako FuntzioBarrutia parametroari dagokion balio bat.

Funtzioak 255 argumentu arte izan ditzake; alegia, 127 irizpide-barruti eta irizpide zehaztu daitezke funtziorako.

Gelaxka batek TRUE (Egiazkoa) badu, 1 baliotzat hartzen du; FALSE (Gezurra) badu, 0 (zero) baliotzat.

Adibidea

Begiratu honako taula

	A	B	C
1	Produktuaren izena	Salmentak	Diru-sarrerak
2	arkatza	20	65
3	luma	35	85
4	koadernoa	20	190
5	liburua	17	180
6	arkatz-kutxa	ez	ez

Beheko adibide guztietan batuketa kalkulatzeko barrutiek #6 errenkada dute, baina hura ez ikusi egingo da testua duelako.

Erabilera sinplea

=MAXIFS(B2:B6;B2:B6;"<35")

B2:B6 barrutian 20 balioaren berdina edo handiagoak diren balioen maximoa kalkulatzen du. 35 ematen du, bosgarren errenkadak ez duelako irizpidea betetzen.

=MAXIFS(C2:C6;B2:B6;">=20";C2:C6;"<90")

C2:C6 barrutian 90 baino txikiagoak diren eta B2:B6 barrutian 20ren berdinak edo handiagoak diren balioen maximoa kalkulatzen du. 85 ematen du, laugarren eta bosgarren errenkadek gutxienez irizpide bat ez baitute betetzen.

Adierazpen erregularrak eta habiaratutako funtzioak erabiltzea

=MAXIFS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

C2:C6 barrutian B2:B6 barrutiko balio guztiei dagozkien balioak hartu, minimoa eta maximoa salbu, eta maximoa kalkulatzen du. 190 ematen du, laugarren errenkadak soilik betetzen dituelako irizpideak.

=MAXIFS(C2:C6;A2:A6;"pen.*";B2:B6;"<="&MAX(B2:B6))

C2:C6 barrutiko balioen maximoa kalkulatzen du, "pen" katearekin hasten diren A2:A6 barrutiko gelaxkekin eta B2:B6 barrutiko gelaxka guztiekin (maximoa salbu) bat datozen balioak soilik hartuta. 85 ematen du, hirugarren errenkadak soilik betetzen dituelako irizpide guztiak.

Irizpidetzat gelaxka baten erreferentzia erabiltzea

Irizpide bat erraz aldatu nahi baduzu, aparteko gelaxka batean zehaztu dezakezu eta gelaxka horretarako erreferentzia bat erabili MAXIFS funtzioaren baldintzan. Adibidez, goiko funtzioa honako moduan berridatzi daiteke:

=MAXIFS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

E2 = "pen" bada, funtzioak 65 ematen du, gelaxkarako erreferentzia bere edukiarekin ordezkatuko delako.

Ireki fitxategia adibide bat ikusteko:

Informazio teknikoa

Funtzio hau Collabora Office 5.2 bertsiotik dago erabilgarri.

Funtzio hau ez dago Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format estandarrean. Izen-espazioa honakoa da:

COM.MICROSOFT.MAXIFS

MAXIFS wiki page.

MAX, MAXA, MIN, MINA,

COUNTIFS, MINIFS, MAXIFS, AVERAGEIFS, SUMIFS

Adierazpen erregularren zerrenda