Funciones de texto
Esta sección contiene descripciones de las funciones de Texto.
Utilizar comillas dactilográficas dobles (") en fórmulas
Para incluir una cadena de texto en una fórmula, coloque la cadena de texto entre comillas dobles ("), Calc toma los caracteres de la cadena sin intentar interpretarlos. Por ejemplo, la fórmula ="¡Hola mundo!" muestra la cadena de texto ¡Hola mundo! en la celda, sin las comillas dobles envolventes.
La fórmula más compleja =CONCATENAR("La vida es realmente sencilla, "; "pero insistimos en complicarla "; "(Confucio).") concatena tres cadenas individuales entre comillas dobles, dando como resultado La vida es realmente sencilla, pero insistimos en complicarla (Confucio).
Para colocar una comilla doble literal dentro de una cadena en de una fórmula, se pueden usar dos métodos:
-
Puede codificar con «escape» las comillas dobles con una comilla doble adicional; Calc trata las comillas dobles escapadas como un valor literal. Por ejemplo, la fórmula ="Mi nombre es ""Juan Pérez""." genera la cadena Mi nombre es "Juan Pérez". Otro ejemplo simple es la fórmula =UNICODE("""") que devuelve 34, el valor decimal del carácter de comillas Unicode (U+0022); aquí las comillas dobles primera y cuarta indican el principio y el final de la cadena, mientras que la segunda comilla doble escapa a la tercera.
-
Puede usar la función CARACTER o la función UNICAR para insertar una comilla doble. Por ejemplo, la fórmula =UNICAR(34) & "El Guardián entre el centeno" & UNICAR(34) & " es un libro famoso de JD Salinger". muestra la cadena "El Guardián entre el centeno" es un famoso libro de JD Salinger.
Be aware that Calc's AutoCorrect function may modify double quotation marks. AutoCorrect should not change the double quotation marks within formula cells but may change those used in non-formula cells containing text. For example, if you copy a string that is surrounded by some other form of typographical double quotation marks, such as the left double quotation mark (U+201C) and the right double quotation mark (U+201D), and then paste into a formula cell, an error may result. Open the Double Quotes area of the dialog to set the characters used to automatically correct the start and end typographical double quotation marks. Uncheck the toggle button to disable the feature.
BASE
Convierte un número entero positivo a una base especificada en un texto del sistema de numeración. Se utilizan los dígitos 0-9 y las letras A-Z.
BASE(Número; Base [; Longitud mínima])
Número es el número entero positivo se debe convertir.
Base indica la base del sistema numérico. Puede ser cualquier número entero positivo entre 2 y 36.
LongitudMínima (opcional) determina la longitud mínima de la secuencia de caracteres que se ha creado. Si el texto es más corto que la longitud mínima indicada, se agregan ceros a la izquierda de la cadena.
=BASE(17;10;4) devuelve 0017 en el sistema decimal.
=BASE(17;2) devuelve 10001 en el sistema binario.
=BASE(255;16;4) devuelve 00FF en el sistema hexadecimal.
CARACTER
Convierte un número en un carácter según la tabla de códigos actual. El número puede ser un entero de dos o de tres dígitos.
CARACTER(Número)
Número es un número entre 1 y 255 que representa el valor de código del carácter.
=CARACTER(100) devuelve el carácter «d».
="abc" & CARACTER(10) & "def" inserta un carácter de salto de renglón en la cadena.
CODIGO
Devuelve un código numérico para el primer carácter de una cadena de texto.
CODIGO("Texto")
Texto es el texto para el que se buscará el código del primer carácter.
=CODIGO("Jerónimo") devuelve 74, =CODIGO("jeroglífico") devuelve 106.
El código utilizado en este caso no es el código ASCII, sino el código de la tabla de códigos actual.
CONCATENAR
Combina varias cadenas de caracteres en una sola.
CONCATENAR(Cadena 1 [; Cadena 2 [[; … [; Cadena 255]]])
Cadena 1[; Cadena 2][; ... ;[Cadena 255]] son cadenas o referencias a celdas que contienen cadenas.
=CONCATENAR("Buenos ";"días, ";"Sra. ";"López") devuelve «Buenos días, Sra. López».
DECIMAL
Convierte el texto que representa un número en un sistema numérico con la base que se dé a un entero positivo. La base debe estar en el intervalo de 2 a 36. Se ignoran los espacios y los tabuladores. El campo Texto no distingue entre mayúsculas y minúsculas.
Si la base es 16, no se tiene en cuenta una x o X o 0x o 0X inicial, ni una h o H añadida. Si la base es 2, no se tiene en cuenta una b o B añadida. Otros caracteres que no pertenecen al sistema numérico generan un error.
DECIMAL("Texto"; Base)
Texto es el texto que se va a convertir.
Base indica la base del sistema numérico. Puede ser cualquier número entero positivo entre 2 y 36.
=DECIMAL("17";10) devuelve 17.
=DECIMAL("FACE";16) devuelve 64206.
=DECIMAL("0101";2) devuelve 5.
DERECHA
Devuelve el último carácter o los últimos caracteres de un texto.
DERECHA("Texto" [; Número])
Texto es el texto cuya parte derecha se determinará.
Número (opcional) es la cantidad de caracteres de la parte derecha del texto. Si no se define este parámetro, se devuelve un carácter.
=DERECHA("Sol";2) devuelve «ol».
DERECHAB
Devuelve el último carácter o caracteres de un texto en DBCS (conjunto de caracteres de bytes dobles).
DERECHAB("Texto" [; Número bytes])
Texto es el texto cuya parte derecha se determinará.
Número_bytes (opcional) especifica el número de caracteres que quieres que extraiga DERECHAB, basado en bytes. Si no se define este parámetro, nos devuelve un byte.
IZQUIERDAB("中国";1) devuelve « » (1 byte es solo la mitad de un carácter DBCS y, por lo tanto, se devuelve un espacio en su lugar).
DERECHAB("中国";2) devuelve «国» (2 bytes constituyen un carácter DBCS completo).
DERECHAB("中国";3) devuelve « 国» (3 bytes constituyen un carácter DBCS y una mitad, se devuelve un espacio por la primera mitad).
DERECHAB("中国";4) devuelve «中国» (4 bytes constituyen dos caracteres DBCS completos).
DERECHAB("capuchino";5) devuelve «chino» (5 caracteres no DBCS, cada uno con la medida de 1 byte).
ENCONTRAR
Devuelve la posición de una cadena de texto dentro de otra cadena. También puede definirse el punto de inicio de la búsqueda. El término buscado puede ser un número o una cadena de caracteres. La búsqueda distingue entre mayúsculas y minúsculas.
ENCONTRAR("Buscar texto"; "Texto" [; Posición])
QuéEncontrar hace referencia al texto que se debe buscar.
Texto es el texto donde se realiza la búsqueda.
Posición (opcional) es la posición en el texto donde se iniciará la búsqueda.
=BUSCAR(76;998877665544) devuelve 6.
ESPACIOS
Elimina los espacios de una cadena de caracteres y deja un solo espacio entre palabras.
ESPACIOS("Texto")
Text se refiere al texto cuyos espacios se han de eliminar.
=ESPACIOS(" hola, mundo ") devuelve «hola, mundo» sin los espacios inicial y final y con un único espacio entre las palabras.
EXTRAE
Devuelve una cadena de texto de un texto. Los parámetros especifican la posición inicial y el número de caracteres.
EXTRAE("Texto"; Comienzo; Número)
Texto es el texto que contiene los caracteres que se van a extraer.
Inicio es la posición del primer carácter del texto que se va a extraer.
Número especifica el número de caracteres en la parte del texto.
=EXTRAE("oficina";2;2) devuelve «fi».
EXTRAEB
Devuelve una cadena de texto en DBCS. Los parámetros especifican la posición inicial y la cantidad de caracteres.
EXTRAEB("Texto"; Comienzo; Número_de_bytes)
Texto es el texto que contiene los caracteres que se van a extraer.
Inicio es la posición del primer carácter del texto que se extraerá.
Número_de_bytes especifica la cantidad de caracteres que EXTRAEB extraerá del texto, en bytes.
=EXTRAEB("中国";1;0) devuelve «» (0 bytes siempre es una cadena vacía).
=EXTRAEB("中国";1;1) devuelve « » (1 byte es solo la mitad de un carácter DBCS y, por lo tanto, el resultado es un carácter de espacio).
=EXTRAEB("中国";1;2) devuelve «中» (2 bytes constituyen un carácter DBCS completo).
=EXTRAEB("中国";1;3) devuelve «中 » (3 bytes constituyen un carácter DBCS y medio; el último byte da como resultado un carácter de espacio).
=EXTRAEB("中国";1;4) devuelve «中国» (4 bytes constituyen dos caracteres DBCS completos).
=EXTRAEB("中国";2;1) devuelve « » (la posición de byte 2 no está al principio de un carácter en una cadena DBCS; se devuelve 1 carácter de espacio).
=EXTRAEB("中国";2;2)nos devuelve " " (la posición del byte 2 apunta a la última mitad del primer carácter de la cadena DBCS; los 2 bytes solicitados constituyen, por tanto, la última mitad del primer carácter y la primera mitad del segundo carácter de la cadena; devuelven, por tanto, 2 caracteres de espacio).
=EXTRAEB("中国";2;3) nos devuelve " 国" (la posición de byte 2 no está al principio de un carácter en una cadena DBCS; nos devuelve un carácter de espacio para la posición de byte 2).
=EXTRAEB("中国";3;1) nos devuelve " " (la posición de byte 3 está al principio de un carácter en una cadena DBCS, pero 1 byte es sólo la mitad de un carácter DBCS y, por tanto, nos devuelve un carácter de espacio en su lugar).
=EXTRAEB("中国";3;2) devuelve «国» (la posición de byte 3 está al comienzo de un carácter en una cadena DBCS, y 2 bytes constituyen un carácter DBCS).
=EXTRAEB("office";2;3) devuelve «ffi» (la posición de byte 2 está al comienzo de un carácter en una cadena que no es DBCS, y 3 bytes de un cadena que no es DBCS constituye 3 caracteres).
FIJO
Nos devuelve un número como texto con un número especificado de decimales y separadores de miles opcionales.
FIJO(Número; [Decimales = 2 [; Sin separadores de miles = FALSo]])
Número se redondea a Decimales (después del separador decimal) y el resultado se formatea como texto, utilizando la configuración específica de la localidad.
Decimales (opcional) se refiere al número de decimales que se mostrarán. Si Decimales es negativo, Número se redondea a ABS(Decimales) lugares a la izquierda del punto decimal. Si Decimales es una fracción, se trunca realmente ignorando cuál es el entero más cercano.
Sin separadores de miles (opcional) determina si se utiliza el separador de miles. Si es VERDAD o distinto de cero, los separadores de grupos se omiten en la cadena resultante. Si el parámetro es igual a 0 o si falta por completo, se muestran los separadores de miles de su configuración local actual.
=FIJO(1234567,89;3) devuelve 1.234.567,890 como cadena de texto.
=FIJO(123456.789;VERDADERO)nos devuelve 123456.79 como cadena de texto.
=FIJO(12345,6789;-2) devuelve 12 300 como una cadena de texto.
=FIJO(12134567.89;-3;1) devuelve 12135000 como una cadena de texto.
=FIJO(12345.789;3/4) devuelve 12,346 como una cadena de texto.
=FIJO(12345.789;8/5) devuelve 12.345,8 como cadena de texto.
HALLAR
Devuelve la posición de un segmento de texto dentro de una cadena de caracteres. Opcionalmente puede fijar el inicio de la búsqueda. El texto buscado puede ser un número o una cadena de caracteres. La búsqueda no distingue mayúsculas de minúsculas. Si no se encuentra el texto, se devuelve el error 519 (#VALOR).
La búsqueda admite tanto comodines como expresiones regulares. Si activa las expresiones regulares, puede introducir «tod.*», por ejemplo, para encontrar la primera localización de «tod» seguido de cualesquier caracteres. Si desea localizar un texto que es también una expresión regular, debe anteponer a cada uno de los metacaracteres u operadores de la expresión una contrabarra «\», o circundarlo con \Q...\E. Puede activar o desactivar la valoración automática de los comodines o las expresiones regulares en .
Al utilizar funciones en las que uno o más argumentos son cadenas de criterios de búsqueda que representan una expresión regular, en primer lugar se intentará convertir los criterios de la cadena en números. Por ejemplo, «.0» se convertirá en 0.0 y así sucesivamente. Si el intento es fructuoso, la correspondencia no será por expresión regular, sino numérica. No obstante, si se cambia a una configuración regional en la cual el separador decimal no es el punto, pasará a valer la expresión regular. Para forzar la evaluación de la expresión regular en lugar de una expresión numérica, utilice una expresión que no pueda confundirse con un número, como por ejemplo «.\0» o «(?i).0».
HALLAR("Buscar texto"; "Texto" [; Posición])
Encontrar_Texto es el texto que se debe buscar.
Texto es el texto donde se realiza la búsqueda.
Posición (opcional) es la posición en el texto donde se debe iniciar la búsqueda.
=HALLAR(54;998877665544) devuelve 10.
IGUAL
Compara dos cadenas de texto y devuelve VERDADERO si son iguales. Esta función distingue entre mayúsculas y minúsculas.
IGUAL("Texto1"; "Texto2")
Texto1 hace referencia al primer texto que se comparará.
Texto2 es el segundo texto que se va comparar.
=IGUAL("microsystems";"Microsystems") devuelve FALSO.
IZQUIERDA
Devuelve el primer carácter o los primeros caracteres de un texto.
IZQUIERDA("Texto" [; Número])
Texto es la cadena de texto cuyas palabras parciales iniciales se determinarán.
Número (opcional) especifica el número de caracteres para el texto inicial. Si no se ha definido este parámetro, se devuelve un carácter.
=IZQUIERDA("salida";3) devuelve «sal».
IZQUIERDAB
Devuelve los primeros caracteres de un texto en DBCS.
IZQUIERDAB("Texto" [; Número_bytes])
Texto es la cadena de texto cuyas palabras parciales iniciales se determinarán.
Número_de_bytes (opcional) especifica la cantidad de caracteres que extraerá IZQUIERDAB, medido en bytes. Si no se define este parámetro, se devolverá un carácter.
=IZQUIERDAB("中国";1) devuelve « » (1 byte es solo la mitad de un carácter DBCS y en su lugar se devuelve un carácter de espacio).
=IZQUIERDAB("中国";2) devuelve "中" (2 bytes conforman un carácter DBCS completo).
=IZQUIERDOB("中国";3) devuelve "中 " (3 bytes conforman un carácter DBCS y medio; el último carácter devuelto es por tanto un carácter de espacio).
=IZQUIERDAB("中国";4) devuelve "中国" (4 bytes conforman dos caracteres DBCS completos).
=IZQUIERDAB("oficina";3) devuelve «ofi» (3 caracteres que no son DBCS, cada uno de los cuales consta de 1 byte).
LARGO
Calcula la longitud de una cadena, incluidos los espacios.
LARGO("Texto")
Texto es el texto cuya longitud debe determinarse.
=LARGO("Buenas tardes") devuelve 13.
=LARGO(12345.67) devuelve 8.
LARGOB
Para los idiomas que utilizan un conjunto de caracteres de bytes dobles (DBCS), devuelve la cantidad de bytes usada para representar los caracteres de una cadena de texto.
LARGOB("Texto")
Texto es el texto cuya longitud debe determinarse.
LARGOB("中") devuelve 2 (1 carácter DBCS, equivalente a 2 bytes).
LARGOB("中国") devuelve 4 (2 caracteres DBCS, cada uno equivalente a 2 bytes).
LARGOB("Caifanes") devuelve 8 (8 caracteres no DBCS, cada uno con la medida de 1 byte).
=LARGOB("Buenas tardes") devuelve 13.
=LARGOB(12345.67) devuelve 8.
LIMPIAR
Elimina de la cadena todos los caracteres que no se pueden imprimir.
LIMPIAR("Texto")
Texto hace referencia al texto del que se eliminarán todos los caracteres no imprimibles.
=LARGO(LIMPIAR(CARACTER(7) & "LibreOffice Calc" & CARACTER(8))) nos devuelve 16, mostrando que la función LIMPIAR elimina los caracteres Unicode no imprimibles U+0007 ("BEL") y U+0008 ("BS") al principio y al final del argumento de la cadena. LIMPIAR no elimina los espacios.
MAYUSC
Pasa la cadena especificada en el campo de texto a mayúsculas.
MAYUSC("Texto")
Texto hace referencia a las letras en minúsculas que desea convertir a mayúsculas.
=MAYUSC("Buenos días") devuelve BUENOS DÍAS.
MINUSC
Convierte todas las letras mayúsculas de una cadena de texto en minúsculas.
MINUSC("Texto")
Texto hace referencia al texto que se debe convertir.
=MINUSC("Sun";2) devuelve sun.
MONEDA
Convierte un número en una cadena que representa el importe en el formato de moneda, redondeado a unos decimales especificados, utilizando el separador decimal que corresponde al configuración local actual. En el campo Valor introduce el número de decimales a convertir. Opcionalmente, puede introducir el número de decimales en el campo Decimales. Si no se especifica ningún valor, todos los números en formato de moneda se mostrarán con dos decimales.
Debe establecer el formato de la divisa en la configuración del sistema.
MONEDA(Valor [; Decimales])
Valor es un número, una referencia a una celda que contiene un número o una fórmula que da como resultado un número.
Decimales es el número opcional de posiciones decimales.
=MONEDA(255) nos devuelve $255,00 para la configuración regional inglesa (USA) y la moneda USD (dólar); ￥255,00 para la configuración regional japonesa y la moneda JPY (yen); o 255,00 € para la configuración regional alemana (Alemania) y la moneda EUR (euro).
=MONEDA(367,456;2) devuelve 367,46 unidades monetarias.
NOMPROPIO
En el caso de una cadena de texto, convierte en mayúscula la inicial de todas las palabras de la cadena.
NOMPROPIO("Texto")
Texto hace referencia al texto que se debe convertir.
=NOMPROPIO("the document foundation") devuelve The Document Foundation.
REEMPLAZAR
Sustituye parte de una cadena de texto con una cadena de texto distinta. Esta función se puede utilizar para sustituir caracteres y números (que se convierten automáticamente en texto). El resultado de la función siempre es un texto. Para proseguir con la operación de cálculo con un número reemplazado por texto, es preciso transformar el resultado de nuevo en número; para ello, se utiliza la función VALOR.
Si no desea que un texto que contenga números se interprete como número y se convierta en texto automáticamente deberá escribirlo entre comillas.
REEMPLAZAR("Texto"; Posición; Longitud; "texto_nuevo")
Texto hace referencia al texto del que se sustituirá una parte.
Posición hace referencia a la posición del texto en la que comenzará la sustitución.
Longitud es el número de caracteres en Texto que se va a sustituir.
texto_nuevo hace referencia al texto que sustituye a Texto.
=REEMPLAZAR("1234567";1;1;"444") devuelve "444234567". Un carácter en la posición 1 se sustituye por el texto_nuevo completo.
REPETIR
Repite una cadena de caracteres el número de veces especificado.
REPETIR("Texto"; Número)
Texto es el texto que se debe repetir.
Número es el número de repeticiones.
=REPETIR("Buenos días") devuelve Buenos díasBuenos días.
Consulte la página wiki REPETIR para obtener más detalles sobre esta función.
SUSTITUIR
Reemplaza un fragmento de texto por otro nuevo dentro de una cadena de caracteres.
SUSTITUIR("Texto"; "Texto de búsqueda"; "Nuevo texto" [; Ocurrencia])
Texto es el texto en el que se van a intercambiar los segmentos de texto.
Buscar_texto es el segmento de texto que se va a sustituir (un número de veces).
texto_nuevo es el texto que va a sustituir al segmento de texto.
Aparición (opcional) indica la aparición del texto buscado que se reemplazará. Si no se especifica este parámetro, el texto de la búsqueda se reemplazará en todas partes.
=SUSTITUIR("123123123";"3";"abc") devuelve 12abc12abc12abc.
=SUSTITUIR("123123123";"3";"abc";2) devuelve 12312abc123.
T
Esta función devuelve el texto de destino, o una cadena de texto vacía si el destino no es texto.
T(Valor)
Si Valuor es una cadena de texto o se refiere a una cadena de texto. T devolverá esa cadena; de lo contrario devolvera una cadena en vacia.
=T(12345) devuelve una cadena vacía.
=T("12345") devuelve la cadena 12345.
TEXTO
Convierte un valor en texto según un formato determinado.
TEXTO(Valor; Formato)
Valor es el valor (numérico o textual) a convertir.
Formato es el texto que define el formato. Use separadores de decimales y millares de acuerdo con el idioma definido en el formato de celda.
=TEXTO(12,34567;"###,##") devuelve el texto 12,35.
=TEXTO(12,34567;"000,00") devuelve el texto 012,35.
=TEXTO("xyz";"=== @ ===") devuelve el texto === xyz ===
Consulte también Códigos de formato numérico: códigos de formato personalizados definidos por el usuario.
TEXTOBAHT
Convierte un número en texto tailandés, incluso los nombres de monedas tailandeses.
TEXTOBAHT(Número)
Número es cualquier número. "Baht" se agrega a la parte entera del número y "Satang" se agrega a la parte decimal del número.
=TEXTOBAHT(12,65) devuelve una cadena de caracteres tailandeses que representan «Doce bahts y sesentaicinco satangs».
COM.MICROSOFT.BAHTTEXT
UNICAR
Convierte un número de código en un carácter o letra Unicode.
UNICAR(número)
=UNICAR(169) da como resultado el carácter de derechos de autor, ©.
Consulte también la función UNICODE().
UNICODE
Devuelve el código numérico del primer carácter Unicode de una cadena de texto.
UNICODE("Texto")
=UNICODE("©") devuelve el número Unicode 169 para el carácter de Copyright.
Consulte también la función UNICAR().