Financial Functions Part Three
COUPDAYBS
Returns the number of days from the first day of interest payment on a security until the settlement date.
COUPDAYBS(Settlement; Maturity; Frequency [; Basis])
Settlement is the date of purchase of the security.
Maturity is the date on which the security matures (expires).
Frequency is the number of interest payments per year (1, 2 or 4).
A security is purchased on 2001-01-25; the date of maturity is 2001-11-15. Interest is paid half-yearly (frequency is 2). Using daily balance interest calculation (basis 3) how many days is this?
=COUPDAYBS("2001-01-25"; "2001-11-15"; 2; 3) returns 71.
COUPDAYS
Returns the number of days in the current interest period in which the settlement date falls.
COUPDAYS(Settlement; Maturity; Frequency [; Basis])
Settlement is the date of purchase of the security.
Maturity is the date on which the security matures (expires).
Frequency is number of interest payments per year (1, 2 or 4).
A security is purchased on 2001-01-25; the date of maturity is 2001-11-15. Interest is paid half-yearly (frequency is 2). Using daily balance interest calculation (basis 3) how many days are there in the interest period in which the settlement date falls?
=COUPDAYS("2001-01-25"; "2001-11-15"; 2; 3) returns 181.
COUPDAYSNC
Returns the number of days from the settlement date until the next interest date.
COUPDAYSNC(Settlement; Maturity; Frequency [; Basis])
Settlement is the date of purchase of the security.
Maturity is the date on which the security matures (expires).
Frequency is number of interest payments per year (1, 2 or 4).
A security is purchased on 2001-01-25; the date of maturity is 2001-11-15. Interest is paid half-yearly (frequency is 2). Using daily balance interest calculation (basis 3) how many days are there until the next interest payment?
=COUPDAYSNC("2001-01-25"; "2001-11-15"; 2; 3) returns 110.
COUPNCD
Returns the date of the first interest date after the settlement date. Format the result as a date.
COUPNCD(Settlement; Maturity; Frequency [; Basis])
Settlement is the date of purchase of the security.
Maturity is the date on which the security matures (expires).
Frequency is number of interest payments per year (1, 2 or 4).
A security is purchased on 2001-01-25; the date of maturity is 2001-11-15. Interest is paid half-yearly (frequency is 2). Using daily balance interest calculation (basis 3) when is the next interest date?
=COUPNCD("2001-01-25"; "2001-11-15"; 2; 3) returns 2001-05-15.
COUPNUM
Returns the number of coupons (interest payments) between the settlement date and the maturity date.
COUPNUM(Settlement; Maturity; Frequency [; Basis])
Settlement is the date of purchase of the security.
Maturity is the date on which the security matures (expires).
Frequency is the number of interest payments per year (1, 2 or 4).
A security is purchased on 2001-01-25; the date of maturity is 2001-11-15. Interest is paid half-yearly (frequency is 2). Using daily balance interest calculation (basis 3) how many interest dates are there?
=COUPNUM("2001-01-25"; "2001-11-15"; 2; 3) returns 2.
COUPPCD
Returns the date of the interest date prior to the settlement date. Format the result as a date.
COUPPCD(Settlement; Maturity; Frequency [; Basis])
Settlement is the date of purchase of the security.
Maturity is the date on which the security matures (expires).
Frequency is the number of interest payments per year (1, 2 or 4).
A security is purchased on 2001-01-25; the date of maturity is 2001-11-15. Interest is paid half-yearly (frequency is 2). Using daily balance interest calculation (basis 3) what was the interest date prior to purchase?
=COUPPCD("2001-01-25"; "2001-11-15"; 2; 3) returns 2000-15-11.
FV
Returns the future value of an investment based on periodic, constant payments and a constant interest rate (Future Value).
FV(Rate; NPer; Pmt [ ; [ PV ] [ ; Type ] ])
Rate is the periodic interest rate.
NPer is the total number of periods (payment period).
Pmt is the annuity paid regularly per period.
PV (optional) is the (present) cash value of an investment.
Type (optional) defines whether the payment is due at the beginning or the end of a period.
In the Collabora Office Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.
What is the value at the end of an investment if the interest rate is 4% and the payment period is two years, with a periodic payment of 750 currency units. The investment has a present value of 2,500 currency units.
=FV(4%;2;750;2500) = -4234.00 currency units. The value at the end of the investment is 4234.00 currency units.
FVSCHEDULE
Calculates the accumulated value of the starting capital for a series of periodically varying interest rates.
FVSCHEDULE(Principal; Schedule)
Principal is the starting capital.
Schedule is a series of interest rates, for example, as a range H3:H5 or as a (List) (see example).
This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.
1000 currency units have been invested in for three years. The interest rates were 3%, 4% and 5% per annum. What is the value after three years?
=FVSCHEDULE(1000;{0.03;0.04;0.05}) returns 1124.76.
INTRATE
Calculates the annual interest rate that results when a security (or other item) is purchased at an investment value and sold at a redemption value. No interest is paid.
INTRATE(Settlement; Maturity; Investment; Redemption [; Basis])
Settlement is the date of purchase of the security.
Maturity is the date on which the security is sold.
Investment is the purchase price.
Redemption is the selling price.
A painting is bought on 1990-01-15 for 1 million and sold on 2002-05-05 for 2 million. The basis is daily balance calculation (basis = 3). What is the average annual level of interest?
=INTRATE("1990-01-15"; "2002-05-05"; 1000000; 2000000; 3) returns 8.12%.
IPMT
Calculates the periodic amortizement for an investment with regular payments and a constant interest rate.
IPMT(Rate; Period; NPer; PV [; FV [; Type]])
Rate is the periodic interest rate.
Period is the period, for which the compound interest is calculated. Period=NPER if compound interest for the last period is calculated.
NPer is the total number of periods, during which annuity is paid.
PV is the present cash value in sequence of payments.
FV (optional) is the desired value (future value) at the end of the periods.
Type is the due date for the periodic payments.
What is the interest rate during the fifth period (year) if the constant interest rate is 5% and the cash value is 15,000 currency units? The periodic payment is seven years.
=IPMT(5%;5;7;15000) = -352.97 currency units. The compound interest during the fifth period (year) is 352.97 currency units.
NPER
Returns the number of periods for an investment based on periodic, constant payments and a constant interest rate.
NPER(Rate; Pmt; PV [ ; [ FV ] [ ; Type ] ])
Rate is the periodic interest rate.
Pmt is the constant annuity paid in each period.
PV is the present value (cash value) in a sequence of payments.
FV (optional) is the future value, which is reached at the end of the last period.
Type (optional) is the due date of the payment at the beginning or at the end of the period.
In the Collabora Office Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.
How many payment periods does a payment period cover with a periodic interest rate of 6%, a periodic payment of 153.75 currency units and a present cash value of 2.600 currency units.
=NPER(6%;153.75;2600) = -12,02. The payment period covers 12.02 periods.
ODDFPRICE
Calculates the price per 100 currency units par value of a security, if the first interest date falls irregularly.
ODDFPRICE(Settlement; Maturity; Issue; FirstCoupon; Rate; Yield; Redemption; Frequency [; Basis])
Settlement is the date of purchase of the security.
Maturity is the date on which the security matures (expires).
Issue is the date of issue of the security.
FirstCoupon is the first interest date of the security.
Rate is the annual rate of interest.
Yield is the annual yield of the security.
Redemption is the redemption value per 100 currency units of par value.
Frequency is number of interest payments per year (1, 2 or 4).
ODDFYIELD
Calculates the yield of a security if the first interest date falls irregularly.
ODDFYIELD(Settlement; Maturity; Issue; FirstCoupon; Rate; Price; Redemption; Frequency [; Basis])
Settlement is the date of purchase of the security.
Maturity is the date on which the security matures (expires).
Issue is the date of issue of the security.
FirstCoupon is the first interest period of the security.
Rate is the annual rate of interest.
Price is the price of the security.
Redemption is the redemption value per 100 currency units of par value.
Frequency is number of interest payments per year (1, 2 or 4).
ODDLPRICE
Calculates the price per 100 currency units par value of a security, if the last interest date falls irregularly.
ODDLPRICE(Settlement; Maturity; LastInterest; Rate; Yield; Redemption; Frequency [; Basis])
Settlement is the date of purchase of the security.
Maturity is the date on which the security matures (expires).
LastInterest is the last interest date of the security.
Rate is the annual rate of interest.
Yield is the annual yield of the security.
Redemption is the redemption value per 100 currency units of par value.
Frequency is number of interest payments per year (1, 2 or 4).
Settlement date: February 7 1999, maturity date: June 15 1999, last interest: October 15 1998. Interest rate: 3.75 per cent, yield: 4.05 per cent, redemption value: 100 currency units, frequency of payments: half-yearly = 2, basis: = 0
The price per 100 currency units per value of a security, which has an irregular last interest date, is calculated as follows:
=ODDLPRICE("1999-02-07";"1999-06-15";"1998-10-15"; 0.0375; 0.0405;100;2;0) returns 99.87829.
ODDLYIELD
Calculates the yield of a security if the last interest date falls irregularly.
ODDLYIELD(Settlement; Maturity; LastInterest; Rate; Price; Redemption; Frequency [; Basis])
Settlement is the date of purchase of the security.
Maturity is the date on which the security matures (expires).
LastInterest is the last interest date of the security.
Rate is the annual rate of interest.
Price is the price of the security.
Redemption is the redemption value per 100 currency units of par value.
Frequency is number of interest payments per year (1, 2 or 4).
Settlement date: April 20 1999, maturity date: June 15 1999, last interest: October 15 1998. Interest rate: 3.75 per cent, price: 99.875 currency units, redemption value: 100 currency units, frequency of payments: half-yearly = 2, basis: = 0
The yield of the security, that has an irregular last interest date, is calculated as follows:
=ODDLYIELD("1999-04-20";"1999-06-15"; "1998-10-15"; 0.0375; 99.875; 100;2;0) returns 0.044873 or 4.4873%.
RATE
Returns the constant interest rate per period of an annuity.
RATE(NPer; Pmt; PV [ ; [ FV ] [ ; [ Type ] [ ; Guess ] ] ])
NPer is the total number of periods, during which payments are made (payment period).
Pmt is the constant payment (annuity) paid during each period.
PV is the cash value in the sequence of payments.
FV (optional) is the future value, which is reached at the end of the periodic payments.
Type (optional) is the due date of the periodic payment, either at the beginning or at the end of a period.
Guess (optional) determines the estimated value of the interest with iterative calculation.
In the Collabora Office Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.
What is the constant interest rate for a payment period of 3 periods if 10 currency units are paid regularly and the present cash value is 900 currency units.
=RATE(3;-10;900) = -75.63% The interest rate is therefore 75.63%.
RRI
Calculates the interest rate resulting from the profit (return) of an investment.
RRI(P; PV; FV)
P is the number of periods needed for calculating the interest rate.
PV is the present (current) value. The cash value is the deposit of cash or the current cash value of an allowance in kind. As a deposit value a positive value must be entered; the deposit must not be 0 or <0.
FV determines what is desired as the cash value of the deposit.
For four periods (years) and a cash value of 7,500 currency units, the interest rate of the return is to be calculated if the future value is 10,000 currency units.
=RRI(4;7500;10000) = 7.46 %
The interest rate must be 7.46 % so that 7,500 currency units will become 10,000 currency units.
VDB
Returns the depreciation of an asset for a specified or partial period using a variable declining balance method.
VDB(Cost; Salvage; Life; Start; End [; Factor [; NoSwitch]])
Cost is the initial value of an asset.
Salvage is the value of an asset at the end of the depreciation.
Life is the depreciation duration of the asset.
S is the start of the depreciation. A must be entered in the same date unit as the duration.
End is the end of the depreciation.
Factor (optional) is the depreciation factor. Factor = 2 is double rate depreciation.
NoSwitchis an optional parameter. NoSwitch = 0 (default) means a switch to linear depreciation. In NoSwitch = 1 no switch is made.
In the Collabora Office Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.
What is the declining-balance double-rate depreciation for a period if the initial cost is 35,000 currency units and the value at the end of the depreciation is 7,500 currency units. The depreciation period is 3 years. The depreciation from the 10th to the 20th period is calculated.
=VDB(35000;7500;36;10;20;2) = 8603.80 currency units. The depreciation during the period between the 10th and the 20th period is 8,603.80 currency units.
XIRR
Calculates the internal rate of return for a list of payments which take place on different dates. The calculation is based on a 365 days per year basis, ignoring leap years.
If the payments take place at regular intervals, use the IRR function.
XIRR(Values; Dates [; Guess])
Values and Dates refer to a series of payments and the series of associated date values. The first pair of dates defines the start of the payment plan. All other date values must be later, but need not be in any order. The series of values must contain at least one negative and one positive value (receipts and deposits).
Guess (optional) is a guess that can be input for the internal rate of return. The default is 10%.
This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.
Calculation of the internal rate of return for the following five payments (dates are in ISO 8601 format):
|
A |
B |
C |
|
|---|---|---|---|
|
1 |
2001-01-01 |
-10000 |
Received |
|
2 |
2001-02-01 |
2000 |
Deposited |
|
3 |
2001-03-15 |
2500 |
|
|
4 |
2001-05-12 |
5000 |
|
|
5 |
2001-08-10 |
1000 |
=XIRR(B1:B5; A1:A5; 0.1) returns 0.1828 or 18.28%.
XNPV
Calculates the capital value (net present value) for a list of payments which take place on different dates. The calculation is based on a 365 days per year basis, ignoring leap years.
If the payments take place at regular intervals, use the NPV function.
XNPV(Rate; Values; Dates)
Rate is the internal rate of return for the payments.
Values and Dates refer to a series of payments and the series of associated date values. The first pair of dates defines the start of the payment plan. All other date values must be later, but need not be in any order. The series of values must contain at least one negative and one positive value (receipts and deposits)
Calculation of the net present value for the above-mentioned five payments for a national internal rate of return of 6%.
=XNPV(0.06;B1:B5;A1:A5) returns 323.02.