Tabellenfunktionen

Dieser Abschnitt enthält Beschreibungen der Funktionen aus der Kategorie Tabelle und Beispiele zur Veranschaulichung.

FEHLER.TYP

Ergibt eine Zahl, die dem Fehlertyp entspricht, oder den Fehlerwert #NV, wenn kein Fehler vorliegt.

ADRESSE

Ergibt für die angegebene Zeilen- und Spaltennummer eine Zelladresse (Bezug auf die Zelle) in Textform. Sie können auch bestimmen, ob die Adresse als absolute (beispielsweise $A$1) oder relative Adresse (beispielsweise A1) oder als Mischform (beispielsweise A$1 oder $A1) interpretiert wird. Außerdem können Sie den Namen der Tabelle angeben.

Für die Kompatibilität besitzen die Funktionen ADRESSE und INDIREKT nun einen optionalen Parameter, der angibt, ob die R1C1-Schreibweise anstatt der üblichen A1-Schreibweise verwendet werden soll.

In ADRESSE ist dieser Parameter als 4. Parameter eingefügt worden. Der optionale Tabellenname ist nun an die 5. Stelle gerutscht.

Bei INDIREKT wird dieser Parameter als 2. Parameter angehängt.

Bei beiden Funktionen gilt, wenn das Argument mit dem Wert 0 eingefügt wird, dann wird die R1C1-Schreibweise verwendet. Wenn das Argument nicht angegeben wird oder einen Wert ungleich 0 hat, dann wird die A1-Schreibweise verwendet.

Im Falle der R1C1-Schreibweise ergibt ADRESSE das Ausrufezeichen '!' als Trennzeichen für den Tabellennamen und INDIREKT erwartet das Ausrufezeichen als Trennzeichen für Tabellennamen. Beide Funktionen verwenden den Punkt '.' als Trennzeichen im Falle der A1-Schreibweise.

Wenn ein Dokument im Format ODF 1.0/1.1 geöffnet wird und die Funktion ADRESSE einen 4. Parameter als Tabellennamen besitzt, wird dieser an die Stelle des 5. Parameters verschoben. Ein neuer 4. Parameter mit dem Wert 1 wird eingefügt.

Wenn ein Dokument im Format ODF 1.0/1.1 gespeichert wird und für die Funktion ADRESSE ein 4. Parameter festgelegt ist, wird dieser entfernt.

ADRESSE(Zeile; Spalte [; Bezug [; A1 [; "Tabelle"]]])

Zeile stellt die Zeilennummer für den Zellbezug dar

Spalte stellt die Spaltennummer für den Zellbezug dar (als Zahl, nicht den Buchstaben)

Bezug (optional) bestimmt die Art des Bezuges:

1 oder leer: Absolut ($A$1)

2: Zeile absolut; Spalte relativ (A$1)

3: Zeile relativ; Spalte absolut ($A1)

4: Relativ (A1)

Wenn A1 (optional) auf 0 gesetzt ist, wird die R1C1-Schreibweise verwendet. Wenn dieser Parameter fehlt oder einen anderen Wert als 0 hat, wird die A1-Schreibweise verwendet.

Tabelle (optional) gibt den Namen der Tabelle an. Er muss in doppelten Anführungszeichen stehen.

Beispiel:

=ADRESSE(1;1;2;;"Tabelle2") ergibt Folgendes: Tabelle2.A$1

Wenn die Formel oberhalb in Zelle B2 der aktuellen Tabelle steht und die Zelle A1 in Tabelle2 den Wert -6 enthält, können Sie indirekt auf die referenzierte Zelle verweisen, indem Sie in B1 der Tabelle1 =ABS(INDIREKT(A1)) eingeben. Das Ergebnis ist der Betrag (absolute Wert) des in A1 angegebenen Zellbezugs, in diesem Falle 6.

BEREICHE

Ergibt die Anzahl der Einzelbereiche eines Mehrfachbereichs. Ein Bereich kann entweder aus aufeinander folgenden Zellen oder einer einzelnen Zelle bestehen.

Diese Funktion erwartet ein einziges Argument. Um mehrere Bereiche anzugeben, müssen Sie diese in zusätzlichen Klammern einschließen. Mehrfachbereiche können mithilfe des Semikolons (;) als Trennzeichen eingegeben werden, wobei dies automatisch in die Tilde (~) umgewandelt wird. Die Tilde ist der Verkettungsoperator für Bereiche.

BEREICHE(Bezug)

Bezug ist der Verweis auf eine Zelle oder einen Zellbereich.

=BEREICHE((A1:B3;F2;G1)) ergibt 3, da es sich um einen Bezug auf drei separate Zellen und/oder Bereiche handelt. Nach der Eingabe wird dies in =BEREICHE((A1:B3~F2~G1)) umgewandelt.

=BEREICHE(Alles) ergibt 1, wenn Sie einen Bereich mit der Bezeichnung „Alles“ unter Daten – Bereich festlegen… festgelegt haben.

DDE

Ergibt das Ergebnis einer DDE-Verknüpfung. Wenn sich der Inhalt des verknüpften Bereichs oder Abschnitts ändert, ändert sich auch der Rückgabewert. Um die aktualisierten Verknüpfungen anzuzeigen, müssen Sie entweder das Tabellendokument neu laden oder Bearbeiten – Verknüpfungen… wählen. Plattformübergreifende Verknüpfungen, wie beispielsweise von einer Collabora Office-Installation auf einem Windows-System zu einem auf einem Linux-System erstellten Dokument, sind nicht zulässig.

DDE("Server"; "Datei"; "Bereich" [; Modus])

Server ist der Name einer Serveranwendung. Die Collabora Office-Anwendungen haben den Servernamen "soffice".

Datei ist der Name der Datei mit vollständigem Pfad.

Bereich ist ein Bereich, aus dem Daten gelesen werden sollen.

Modus ist ein optionaler Parameter, der steuert, wie die Daten vom DDE-Server in Zahlen umgewandelt werden.

Modus	Wirkung
0 oder fehlend	Zahlenformat aus der Zellvorlage "Standard"
1	Daten werden immer mit Standardformat für US Englisch interpretiert
2	Daten werden als Text übernommen, keine Wandlung in Zahlen

=DDE("soffice";"c:\Office\Dokument\Daten1.ods";"Tabelle1.A1") liest den Inhalt der Zelle A1 in Tabelle1 des Collabora Office Calc-Tabellendokuments Daten1.ods.

=DDE("soffice";"c:\Office\Dokument\Motto.odt";"Heutiges Motto") gibt ein Motto in der Zelle zurück, in der diese Formel enthalten ist. Zunächst geben Sie eine Zeile im Dokument Motto.odt ein, in der das Motto enthalten ist. Dann definieren Sie die Zeile als erste Zeile eines Abschnitts mit der Bezeichnung Heutiges Motto (in Collabora Office Writer unter Einfügen – Bereich…). Wenn das Motto im Collabora Office Writer-Dokument geändert (und gespeichert) wird, wird es in allen Zellen in Collabora Office Calc aktualisiert, in denen diese DDE-Verknüpfung definiert ist.

FEHLERTYP

Ergibt die Nummer eines in einer anderen Zelle aufgetretenen Fehlercodes. Sie können dann beispielsweise mithilfe dieser Nummer einen eigenen Fehlertext ausgeben lassen.

FEHLERTYP(Bezug)

Bezug ist ein Bezug auf eine Zelle, in der ein Fehler gemeldet wird.

Wenn die Zelle A1 Err:518 anzeigt, ergibt die Funktion =FEHLERTYP(A1) die Zahl 518.

ORG.OPENOFFICE.ERRORTYPE

HYPERLINK

Wenn Sie auf eine Zelle klicken, die eine Funktion HYPERLINK enthält, wird der Hyperlink geöffnet.

Wenn Sie den optionalen Parameter Zellwert verwenden, verknüpft die Formel die URL und zeigt den Text oder die Zahl an.

HYPERLINK("URL" [; Zellwert])

URL gibt das Verknüpfungsziel an. Der optionale Parameter Zellwert ist der Text oder eine Zahl, die in der Zelle angezeigt und als Ergebnis zurückgegeben wird. Wird der Parameter Zellwert nicht angegeben, wird die URL im Zelltext angezeigt und als Ergebnis zurückgegeben.

Für leere Zellen und Matrixelemente wird die Zahl 0 zurückgegeben.

=HYPERLINK("http://www.beispiel.org") zeigt den Text "http://www.beispiel.org" in der Zelle an und ruft den Hyperlink "http://www.beispiel.org" beim Anklicken auf.

=HYPERLINK("http://www.beispiel.org";"Hier klicken") zeigt den Text "Hier klicken" in der Zelle an und ruft den Hyperlink "http://www.beispiel.org" beim Anklicken auf.

=HYPERLINK("http://www.beispiel.org";12345) zeigt die Zahl 12345 an und ruft den Hyperlink "http://www.beispiel.org" beim Anklicken auf.

=HYPERLINK($B4) wobei Zelle B4 http://www.beispiel.org enthält. Die Funktion fügt "http://www.beispiel.org" zur URL der Hyperlink-Zelle hinzu und gibt denselben Text zurück, der als Formelergebnis verwendet wird.

=HYPERLINK("http://www.";"Klicke ")&"beispiel.org" zeigt den Text "Klicke beispiel.org" in der Zelle an und ruft den Hyperlink "http://www.beispiel.org" beim Anklicken auf.

=HYPERLINK("#Tabelle1.A1";"Nach oben") zeigt den Text "Nach oben" an und springt zur Zelle Tabelle1.A1 in diesem Dokument.

=HYPERLINK("file:///C:/writer.odt#Spezifikation";"Wechsel zum Writer-Lesezeichen") zeigt den Text "Wechsel zum Writer-Lesezeichen" an, lädt das angegebene Textdokument und springt zum Lesezeichen "Spezifikation".

=HYPERLINK("file:///C:/Dokumente/";"Dokumentordner öffnen") zeigt den Text "Dokumentordner öffnen" an und ruft beim Anklicken den Ordnerinhalt mit der standardmäßigen Dateiverwaltung Ihres Betriebssystems auf.

INDEX

INDEX ergibt einen Unterbereich, der durch eine Zeilen- und eine Spaltennummer definiert ist, oder einen optionalen Bereichsindex. Je nach Kontext ergibt INDEX einen Bezug oder Inhalt.

INDEX(Bezug [; Zeile [; Spalte [; Bereich]]])

Bezug ist ein Bezug, der entweder direkt oder über einen Bereichsnamen eingegeben wird. Wenn der Bezug aus mehreren Bereichen besteht, müssen Sie den Bezug oder den Bereichsnamen in Klammern einschließen.

Zeile (optional) stellt den Zeilenindex des Bezugsbereichs dar, für den der Wert zurückgegeben wird. Im Falle von Null (keine bestimmte Zeile) werden alle referenzierten Zeilen zurückgegeben.

Spalte (optional) stellt den Spaltenindex des Bezugsbereichs dar, für den der Wert zurückgegeben wird. Im Falle von Null (keine bestimmte Spalte) werden alle referenzierten Spalten zurückgegeben.

Bereich (optional) stellt den Index des Unterbereichs dar, wenn der Bezug auf einen Mehrfachbereich verweist.

=INDEX(Preise;4;1) ergibt den Wert aus Zeile 4 und Spalte 1 des Datenbankbereichs, der unter Daten – Bereich festlegen… als Preise festgelegt wurde.

=INDEX(SummeX;4;1) gibt den Wert aus dem Bereich SummeX in Zeile 4 und Spalte 1 zurück, wie unter Tabelle – Benannte Bereiche – Festlegen… definiert.

=INDEX(A1:B6;1) ergibt einen Bezug auf die erste Zeile von A1:B6.

=INDEX(A1:B6;0;1) ergibt einen Bezug auf die erste Spalte von A1:B6.

=INDEX((mehrfach);4;1) gibt den Wert an, der in Zeile 4 und Spalte 1 des (Mehrfach-) Bereichs enthalten ist, welchen Sie unter Tabelle – Benannte Bereiche – Festlegen… als mehrfach definiert haben. Der Mehrfachbereich kann aus verschiedenen rechteckigen Bereichen bestehen, jeder mit einer Zeile 4 und einer Spalte 1. Um nun den zweiten Block dieses Mehrfachbereichs aufzurufen, geben Sie die Nummer 2 als Parameter für Bereich ein.

=INDEX(A1:B6;1;1) gibt den Wert im oberen linken Teil des Bereichs A1:B6 an.

=INDEX((mehrfach);0;0;2) ergibt einen Bezug auf den zweiten Bereich des Mehrfachbereichs.

INDIREKT

Gibt den durch eine Zeichenfolge angegebenen Bezug zurück. Diese Funktion kann auch einen Bereich aus einer entsprechenden Zeichenfolge zurückgeben.

INDIREKT(Bezug [; A1])

Bezug stellt einen Bezug auf eine Zelle oder einen Bereich dar (in Textform), für den der Inhalt zurückgegeben wird.

Wenn A1 (optional) auf 0 gesetzt ist, wird die R1C1-Schreibweise verwendet. Wenn dieser Parameter fehlt oder einen anderen Wert als 0 hat, wird die A1-Schreibweise verwendet.

=INDIREKT(A1) entspricht 100, wenn A1 als Bezug C108 enthält und die Zelle C108 den Wert 100 enthält.

=SUMME(INDIREKT("A1:"&ADRESSE(1;3))) summiert die Zellen im Bereich von A1 bis zur Zelle mit der Adresse, die durch Zeile 1 und Spalte 3 definiert ist. Das bedeutet, dass der Bereich A1:C1 summiert wird.

PIVOTDATENZUORDNEN

Die Funktion PIVOTDATENZUORDNEN ergibt einen Ergebniswert aus einer Pivot-Tabelle. Der Wert wird durch Feldnamen und Elementnamen ausgewählt, sodass der Bezug gültig bleibt, falls sich der Aufbau der Pivot-Tabelle ändert.

Zwei verschiedene Syntax-Varianten können verwendet werden:

PIVOTDATENZUORDNEN(Zielfeld; Pivot-Tabelle [; Feld 1; Element 1 [; … [; Feld 126; Element 126]]])

oder

PIVOTDATENZUORDNEN(Pivot-Tabelle; Bedingungen)

Von der zweiten Syntaxvariante wird ausgegangen, wenn genau zwei Parameter vorhanden sind, von denen der erste eine Zelle oder ein Zellbereich ist. In allen anderen Fällen wird von der ersten Syntaxvariante ausgegangen. Der Funktionsassistent zeigt die erste Syntaxvariante.

Erste Syntax

Zielfeld ist eine Zeichenfolge, die eines der Datenfelder in der Pivot-Tabelle auswählt. Die Zeichenfolge kann der Name der Quellspalte oder der Datenfeldname sein, der in der Tabelle angezeigt wird (etwa "Summe - Verkauf").

Pivot-Tabelle ist ein Bezug auf eine Zelle oder einen Zellbereich, dessen Position innerhalb einer Pivot-Tabelle liegt oder der eine Pivot-Tabelle enthält. Wenn der Zellbereich mehrere Pivot-Tabellen enthält, wird die als letztes erstellte verwendet.

Wenn kein Feld n / Element n Paar angegeben ist, wird das Gesamtergebnis der Pivot-Tabelle zurückgegeben. Anderenfalls fügt jedes Paar eine Bedingung hinzu, die das Funktionsergebnis erfüllen muss. Feld n ist ein Feldname der Pivot-Tabelle. Element n ist der Elementname eines Elements dieses Feldes.

Wenn die Pivot-Tabelle nur einen Wert enthält, der alle Bedingungen erfüllt, oder ein Teilergebnis, das alle auf die Bedingung passenden Werte zusammenfasst, dann wird dieses Ergebnis zurückgeliefert. Wenn es gar keinen passenden Wert gibt oder wenn es mehrere Werte gibt, ohne dass eine sie zusammenfassende Funktion existiert, dann wird ein Fehler zurückgeliefert. Diese Regeln beziehen sich auf Ergebnisse, die in der Pivot-Tabelle zu sehen sind.

Wenn die Quelldaten Einträge enthalten, die durch Einstellungen der Pivot-Tabelle verborgen sind, dann werden diese ignoriert. Die Reihenfolge der Feld/Element-Paare ist beliebig. Groß- und Kleinschreibung wird bei Feld- und Elementnamen außer Acht gelassen.

Wenn keine Einschränkung für einen Filter angegeben ist, wird implizit der ausgewählte Wert des Felds verwendet. Wenn eine Einschränkung für einen Filter angegeben wird, muss sie mit dem ausgewählten Wert des Felds übereinstimmen oder es wird ein Fehler zurückgegeben. Filter sind die Felder oben links in einer Pivot-Tabelle, die über den Bereich "Filter" des Dialogs Pivot-Tabellen-Layout ausgefüllt werden. Aus jedem Filter kann ein Element (Wert) ausgewählt werden, das heißt, nur dieses Element wird in die Berechnung einbezogen.

Teilergebnisse aus der Pivot-Tabelle sind nur erreichbar, wenn als Funktion "Automatisch" eingestellt ist (außer wenn die Funktion in der Bedingung angegeben ist, siehe unten Zweite Syntaxvariante).

Zweite Syntax

Pivot-Tabelle hat dieselbe Bedeutung wie in der ersten Syntaxvariante.

Bedingungen ist eine durch Leerzeichen getrennte Liste. Listeneinträge können mit einfachen Anführungszeichen eingeschlossen werden.

Einer der Einträge kann der Datenfeldname sein. Der Datenfeldname kann entfallen, wenn die Pivot-Tabelle nur ein Datenfeld besitzt, anderenfalls muss der Eintrag vorhanden sein.

Jeder der weiteren Parameter beschreibt eine Bedingung in der Form Feld[Element] (wobei [ und ] als Zeichen einzugeben sind) oder nur Element, sofern der Name des Elements eindeutig innerhalb aller in der Pivot-Tabelle verwendeten Felder ist.

Ein Funktionsname kann in Form von Feld[Element;Funktion] hinzugefügt werden, wodurch nur Teilergebnisse abgeglichen werden, die diese Funktion verwenden. Mögliche Funktionsnamen sind Summe, Count, Durchschnitt, Max, Min, Produkt, Count (nur Zahlen), StAbw (Stichprobe), StAbwN (Gesamtheit), Varianz (Stichprobe) und Varianzen (Gesamtheit), ohne Berücksichtigung der Groß- und Kleinschreibung.

SPALTE

Ergibt die Spaltennummer eines Zellbezugs. Handelt es sich bei dem Bezug um eine Zelle, dann wird die Spaltennummer der Zelle zurückgegeben; handelt es sich um einen Zellbereich, so werden die entsprechenden Spaltennummern in einer einzeiligen Matrix zurückgegeben, sofern die Formel als Matrixformel eingegeben wurde. Wenn die Funktion SPALTE einen Bereichsbezugsparameter aufweist und nicht als Matrixformel eingesetzt wird, dann wird nur die Spaltennummer der ersten Zelle innerhalb des Bereichs ermittelt.

SPALTE([Bezug])

Bezug ist der Bezug auf einen Zellbereich, dessen Spaltennummern ermittelt werden sollen. Das Argument kann auch eine einzige Zelle sein.

Wird kein Bezug angegeben, wird die Spaltennummer der Zelle ermittelt, in der die Formel eingegeben wird. Collabora Office Calc setzt automatisch den Bezug auf die aktuelle Zelle.

=SPALTE(A1) entspricht 1. Spalte A ist die erste Spalte in der Tabelle.

=SPALTE(C3:E3) entspricht 3. Spalte C ist die dritte Spalte in der Tabelle.

=SPALTE(D3:G10) ergibt 4, weil Spalte D die vierte Spalte in der Tabelle ist und die Funktion SPALTE nicht als Matrixformel verwendet wird. (In diesem Fall wird der erste Wert der Matrix immer als Ergebnis verwendet.)

{=SPALTE(B2:B7)} und =SPALTE(B2:B7) ergeben 2, weil der Bezug nur Spalte B als zweite Spalte in der Tabelle enthält. Da einspaltige Bereiche nur eine Spaltennummer haben, ist es egal, ob die Formel als Matrixformel verwendet wird oder nicht.

=SPALTE() ergibt 3, wenn die Formel in Spalte C eingegeben wurde.

{=SPALTE(Kaninchen)} ergibt eine einzeilige Matrix (3, 4), wenn "Kaninchen" der benannte Bereich (C1:D3) ist.

SPALTEN

Ergibt die Anzahl der Spalten eines gegebenen Bezugs.

SPALTEN(Matrix)

Matrix ist der Bezug auf eine Zelle, deren Gesamtanzahl von Spalten gefunden werden soll. Das Argument kann auch eine einzelne Zelle sein.

=SPALTEN(B5) ergibt 1, weil eine Zelle nur eine Spalte enthält.

=SPALTEN(A1:C5) entspricht 3. Der Bezug umfasst drei Spalten.

=SPALTEN(Kaninchen) ergibt 2, wenn Kaninchen der benannte Bereich (C1:D3) ist.

SVERWEIS

Vertikale Suche mit Bezug auf benachbarte Zellen rechts. Diese Funktion prüft, ob ein bestimmter Wert in der ersten Spalte einer Matrix enthalten ist. Die Funktion gibt dann den Wert in derselben Zeile aber der Spalte mit dem Namen Index zurück. Wird der Parameter Sortiert weggelassen oder auf WAHR oder eins gesetzt, wird davon ausgegangen, dass die Daten in aufsteigender Reihenfolge sortiert sind. Wenn in diesem Fall der genaue Suchwert nicht gefunden wird, wird der letzte Wert zurückgegeben, der kleiner als das Kriterium ist. Wenn Sortiert auf FALSCH oder Null gesetzt ist, muss eine exakte Übereinstimmung gefunden werden, ansonsten wird der Fehler Fehler: Wert nicht verfügbar ausgegeben. Bei einem Wert von Null müssen die Daten also nicht aufsteigend sortiert werden.

=SVERWEIS(Suchwert; Matrix; Index [; Sortiert])

Suchwert ist der Wert eines beliebigen Typs, der in der ersten Spalte der Matrix gesucht wird.

Matrix ist der Bezug, der mindestens so viele Spalten enthalten muss, wie die als Index übergebene Zahl angibt.

Index ist die Nummer der Spalte in der Matrix, die den Wert enthält, der zurückgegeben wird. Die erste Spalte hat die Nummer 1.

Sortiert ist ein optionaler Parameter, der angibt, ob die erste Spalte in der Matrix Bereichsgrenzen anstelle von einfachen Werten enthält. In diesem Modus gibt die Suche den Wert in der Zeile mit der ersten Spalte mit einem Wert gleich oder kleiner als Suche zurück. Er könnte beispielsweise Datumsangaben enthalten, an denen ein Steuerwert geändert wurde, und die Werte repräsentieren daher das Anfangsdatum einer Periode, in der ein bestimmter Steuerwert gültig war. Somit würde die Suche nach einem Datum, das in der ersten Matrixspalte fehlt, aber zwischen einigen existierenden Grenzdaten liegt, das niedrigere von ihnen ergeben, was es ermöglicht, herauszufinden, ob die Daten für das gesuchte Datum gültig sind. Geben Sie den booleschen Wert FALSCH oder Null ein, wenn die erste Spalte keine Liste mit Bereichsgrenzen ist. Wenn dieser Parameter WAHR ist oder nicht angegeben ist, muss die erste Spalte im Array aufsteigend sortiert werden. Sortierte Spalten können viel schneller durchsucht werden und die Funktion gibt immer einen Wert zurück, auch wenn der Suchwert nicht exakt gefunden wurde, wenn dieser größer als der kleinste Wert der sortierten Liste ist. In unsortierten Listen muss der Suchwert exakt übereinstimmen. Anderenfalls gibt die Funktion #N/V mit der Meldung zurück: Fehler: Wert nicht verfügbar.

Sie können die Nummer eines Gerichts, das Teil einer Speisekarte ist, in Zelle A1 eingeben, woraufhin der Name des Gerichts sofort als Text in der benachbarten Zelle (B1) erscheint. Die Zuweisung der Nummer zum Namen ist in der Matrix D1:E100 enthalten. D1 enthält 100, E1 enthält den Namen Gemüsesuppe und so weiter, wodurch 100 Gerichte erfasst sind. Die Zahlen in Spalte D werden in aufsteigender Reihenfolge sortiert; darum ist der optionale Parameter Sortiert nicht erforderlich.

Fügen Sie in B1 die folgende Formel ein:

=SVERWEIS(A1;D1:E100;2)

Sobald Sie in A1 eine Nummer eingeben, wird in B1 der zugehörige Text angezeigt, der in der zweiten Spalte des Bezugs D1:E100 steht. Geben Sie eine nicht existente Nummer ein, wird der Text mit der nächstkleineren Nummer angezeigt. Um dies zu verhindern, fügen Sie als letzten Parameter FALSCH in die Formel ein, damit bei Eingabe einer nicht existenten Nummer eine Fehlermeldung ausgegeben wird.

TABELLE

Gibt die Tabellennummer eines Bezugs oder einer Zeichenfolge, die einen Tabellennamen darstellt, zurück. Wenn Sie keine Parameter eingeben, ist das Ergebnis die Tabellennummer der Tabelle, welche die Formel enthält.

TABELLE([Bezug])

Bezug ist ein optionaler Parameter und stellt den Bezug auf eine Zelle, einen Bereich oder einen Tabellennamen dar.

=TABELLE(Tabelle2.A1) gibt 2 zurück, wenn Tabelle2 die zweite Tabelle im Tabellendokument ist.

=TABELLE("Tabelle3") gibt 3 zurück, wenn Tabelle3 die dritte Tabelle im Tabellendokument ist.

TABELLEN

Bestimmt die Anzahl der Tabellen eines Bezugs. Wird kein Parameter angegeben, ergibt es die Anzahl der Tabellen des aktuellen Dokuments.

TABELLEN([Bezug])

Bezug ist der Bezug auf eine Tabelle oder einen Bereich. Dies ist ein optionaler Parameter.

=TABELLEN(Tabelle1.A1:Tabelle3.G12) ergibt 3, wenn Tabelle1, Tabelle2 und Tabelle3 in der angegebenen Reihenfolge vorhanden sind.

VERGLEICH

Ergibt die relative Position eines Elements in einer Matrix, das mit einem angegebenen Wert übereinstimmt. Die Funktion liefert die Position des in Suchmatrix gefundenen Werts in Form einer Zahl.

VERGLEICH(Suchwert; Suchmatrix [; Typ])

Suchwert ist der Wert, nach dem in der einzeiligen oder einspaltigen Matrix gesucht werden soll.

Suchmatrix ist der durchsuchte Bezug. Eine Suchmatrix kann eine einzelne Zeile oder Spalte oder ein Teil einer einzelnen Zeile oder Spalte sein.

Typ kann die Werte 1, 0 oder -1 annehmen. Wenn Typ den Wert 1 hat oder dieser optionale Parameter fehlt, wird davon ausgegangen, dass die erste Spalte der Suchmatrix in aufsteigender Reihenfolge sortiert ist. Bei Typ = -1 wird von einer absteigend sortierten Spalte ausgegangen. Dies stimmt mit derselben Funktion in Microsoft Excel überein.

Wenn Typ = 0, dann werden nur exakte Übereinstimmungen gefunden. Wenn das Suchkriterium mehrmals gefunden wird, ergibt die Funktion den Index des ersten übereinstimmenden Werts. Sie können nur dann nach regulären Ausdrücken (falls in den Optionen aktiviert) oder Platzhaltern (falls in den Optionen aktiviert) suchen, wenn Typ = 0 ist.

Wenn Typ = 1 oder wenn der dritte Parameter nicht vorhanden ist, wird der Index des letzten Werts, der kleiner als das Suchkriterium oder gleich groß ist, zurückgegeben. Bei Typ = -1 wird der Index des letzten Werts, der größer oder gleich groß ist, zurückgegeben.

=VERGLEICH(200;D1:D100) durchsucht den Bereich D1:D100, der nach Spalte D sortiert ist, nach dem Wert 200. Sobald dieser Wert gefunden ist, wird die Nummer der Zeile, in der der Wert gefunden wurde, zurückgegeben. Wenn beim Suchen in der Spalte ein höherer Wert gefunden wird, wird die Nummer der vorhergehenden Zeile zurückgegeben.

VERSCHIEBUNG

Ergibt den Wert einer Zelle, die um eine bestimmte Anzahl von Zeilen und Spalten gegenüber einer anderen versetzt ist.

VERSCHIEBUNG(Bezug; Zeilen; Spalten [; Höhe [; Breite]])

Bezug ist der Bezug, von dem aus die Funktion nach dem neuen Bezug sucht.

Zeilen ist die Anzahl an Zeilen, die der Bezug nach oben (negativer Wert) oder unten korrigiert wird. Bei 0 wird dieselbe Zeile verwendet.

Spalten ist die Anzahl an Spalten, die der Bezug nach links (negativer Wert) oder rechts korrigiert wird. Bei 0 wird dieselbe Spalte verwendet.

Höhe (optional) ist die vertikale Höhe für einen Bereich, der an der neuen Bezugsposition beginnt.

Breite (optional) ist die horizontale Breite für einen Bereich, der an der neuen Bezugsposition beginnt.

Die Argumente Zeilen und Spalten dürfen weder Null sein noch einen negativen Beginn einer Zeile oder Spalte ergeben.

Die Argumente Höhe und Breite dürfen weder Null noch negativ sein.

In Collabora Office Calc Funktionen dürfen Parameter, die als "optional" gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als "optional" gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.

=VERSCHIEBUNG(A1;2;2) ergibt den Wert in Zelle C3 (A1 um zwei Zeilen nach unten und zwei Spalten nach rechts verschoben). Wenn C3 den Wert 100 enthält, gibt diese Funktion den Wert 100 zurück.

=VERSCHIEBUNG(B2:C3;1;1) ergibt einen Bezug auf den Bereich C3:D4 (B2:C3 um eine Zeile nach unten und eine Spalte nach rechts verschoben).

=VERSCHIEBUNG(B2:C3;-1;-1) ergibt einen Bezug auf den Bereich A1:B2 (B2:C3 um eine Zeile nach oben und eine Spalte nach links verschoben).

=VERSCHIEBUNG(B2:C3;0;0;3;4) ergibt einen Bezug auf den Bereich B2:E4 (B2:C3 auf 3 Zeilen und 4 Spalten geändert).

=VERSCHIEBUNG(B2:C3;1;0;3;4) ergibt einen Bezug auf den Bereich B3:E5 (B2:C3 um eine Zeile nach unten verschoben und die Größe auf 3 Zeilen und 4 Spalten geändert).

=SUMME(VERSCHIEBUNG(A1;2;2;5;6)) bestimmt die Summe des Bereichs C3:H7 (A1 um zwei Zeilen nach unten und zwei Spalten nach rechts auf C3 verschoben und die Größe auf 5 Zeilen und 6 Spalten geändert).

VERWEIS

Gibt den Inhalt einer Zelle entweder aus einem einzeiligen oder einspaltigen Bereich zurück. Optional wird der zugewiesene Wert (des gleichen Index) in einer anderen Spalte oder Zeile zurückgegeben. Anders als bei SVERWEIS und WVERWEIS können sich der Such- und der Ergebnisvektor in verschiedenen Positionen befinden; sie müssen nicht nebeneinander liegen. Außerdem muss der Suchvektor für den VERWEIS in aufsteigender Reihenfolge sortiert werden, anderenfalls liefert die Suche keine brauchbaren Ergebnisse.

VERWEIS(Suchwert; Suchvektor [; Ergebnisvektor])

Suchwert ist der Wert eines beliebigen Typs, nach dem gesucht werden soll; entweder direkt oder als Bezug eingegeben.

Suchvektor ist der einzeilige oder einspaltige Bereich, der durchsucht werden soll.

Ergebnisvektor ist ein weiterer einzeiliger oder einspaltiger Bereich, aus dem das Ergebnis der Funktion entnommen wird. Das Ergebnis ist die Zelle des Ergebnisvektors mit dem gleichen Index, wie sie im Suchvektor gefunden wurde.

=VERWEIS(A1;D1:D100;F1:F100) durchsucht die entsprechende Zelle im Bereich D1:D100 nach der Zahl, die Sie in A1 eingegeben haben. Für den gefundenen Wert Suchvektor wird der Index bestimmt, beispielsweise die 12. Zelle im Bereich. Dann wird der Inhalt der 12. Zelle des Ergebnisvektors zurückgegeben.

VORLAGE

Weist der Formelzelle eine Formatvorlage zu. Nach einstellbarer Zeit wird optional eine andere Vorlage zugewiesen. Diese Funktion gibt immer den Wert 0 zurück, sodass Sie die Funktion per Addition zu einer anderen Funktion hinzufügen können, ohne deren Wert zu verändern. Zusammen mit der Funktion AKTUELL können Sie damit eine Zelle in Abhängigkeit vom Wert einfärben, beispielsweise färbt =…+VORLAGE(WENN(AKTUELL()>3;"rot";"grün")) die Zelle mit der Vorlage "rot", wenn der Wert größer 3 ist, sonst mit der Vorlage "grün". Beide Zellformate "rot" und "grün" müssen vorher definiert sein.

VORLAGE("Vorlage" [; Zeit [; "Vorlage2"]])

Vorlage ist der Name einer der Zelle zugewiesenen Formatvorlage. Die Namen von Formatvorlagen sind in Anführungszeichen zu setzen.

Zeit ist eine optionale Zeitspanne in Sekunden. Fehlt dieser Parameter, wird die Vorlage nicht nach einer bestimmten Zeit gewechselt.

Vorlage2 ist der optionale Name einer Formatvorlage, die der Zelle nach Verstreichen einer bestimmten Zeit zugewiesen wird. Wenn dieser Parameter nicht vorhanden ist, wird von "Vorgaben" ausgegangen.

In Collabora Office Calc Funktionen dürfen Parameter, die als "optional" gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als "optional" gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.

=VORLAGE("Unsichtbar";60;"Standard") formatiert 60 Sekunden lang die Zelle in transparentem Format, nachdem das Dokument neu berechnet oder geladen wurde, anschließend wird das Standardformat zugewiesen. Beide Zellformate müssen vorher definiert werden.

Da VORLAGE() den numerischen Rückgabewert Null hat, wird dieser Rückgabewert an eine Zeichenfolge angefügt. Dies kann vermieden werden, indem T() verwendet wird, wie im folgenden Beispiel:

="Text"&T(VORLAGE("eigeneVorlage"))

Ein weiteres Beispiel finden Sie unter AKTUELL().

ORG.OPENOFFICE.STYLE

WAHL

Gibt den durch einen Index bestimmten Wert aus einer Liste von bis zu 30 Werten zurück.

WAHL(Index; Wert 1 [; Wert 2 [; … [; Wert 30]]])

Index als Bezug oder Zahl zwischen 1 und 30 gibt an, welcher Wert aus der Liste entnommen werden soll.

Wert 1, Wert 2, …, Wert 30 ist die Liste der Werte, die als Bezugszelle oder als einzelne Werte eingeben wird.

=WAHL(A1;B1;B2;B3;"Heute";"Gestern";"Morgen") beispielsweise ergibt den Inhalt der Zelle B2 bei A1 = 2; bei A1 = 4 ergibt die Funktion den Text "Heute".

WVERWEIS

Sucht einen Wert und einen Bezug auf die Zellen unter dem ausgewählten Bereich. Diese Funktion prüft, ob die erste Zeile einer Matrix einen bestimmten Wert enthält. Sie gibt den Wert dann in einer per Index angegebenen Zeile derselben Spalte der Matrix aus.

WVERWEIS(Suchwert; Matrix; Index [; Sortiert])

Eine Erläuterung der Parameter finden Sie unter: SVERWEIS (Spalten und Zeilen müssen ausgetauscht werden)

Angenommen, wir haben eine kleine Datenbanktabelle erstellt, die den Zellbereich A1:DO4 einnimmt und grundlegende Informationen über 118 chemische Elemente enthält. Die erste Spalte enthält die Zeilenüberschriften „Element“, „Symbol“, „Atomzahl“ und „Relative Atommasse“. Nachfolgende Spalten enthalten die relevanten Informationen für jedes der Elemente, von links nach rechts nach der Ordnungszahl geordnet. Zum Beispiel enthalten die Zellen B1:B4 „Wasserstoff“, „H“, „1“ und „1,008“, während die Zellen DO1:DO4 „Oganesson“, „Og“, „118“ und „294“ enthalten.

	A	B	C	D	...	DO
1	Element	Wasserstoff	Helium	Lithium	...	Oganesson
2	Symbol	H	He	Li	...	Og
3	Ordnungszahl	1	2	3	...	118
4	Relative Atommasse	1.008	4.0026	6.94	...	294

=WVERWEIS("Blei";$A$1:$DO$4;2;0) gibt "Pb" zurück, das Symbol für Blei.

=WVERWEIS("Gold";$A$1:$DO$4;3;0) gibt 79 zurück, die Ordnungszahl für Gold.

=HLOOKUP("Kohlenstoff";$A$1:$DO$4;4;0) gibt 12,011 zurück, die relative Atommasse von Kohlenstoff.

ZEILE

Ergibt die Zeilennummer eines Zellbezugs. Handelt es sich bei dem Bezug um eine Zelle, so ergibt sie die Zeilennummer der Zelle. Ist der Bezug ein Zellbereich, dann ergibt die Funktion die Nummern der entsprechenden Zeilen in einer einspaltigen Matrix sofern die Formel als Matrixformel eingegeben wurde. Wenn die Funktion ZEILE einen Bereichsbezugsparameter aufweist und nicht als Matrixformel verwendet wird, dann wird nur die Zeilennummer der ersten Zelle innerhalb des Bereichs ermittelt.

ZEILE([Bezug])

Bezug ist der Bezug auf einen Zellbereich, dessen Zeilennummern ermittelt werden sollen. Das Argument kann auch eine einzige Zelle sein.

Wird kein Bezug angegeben, wird die Zeilennummer der Zelle ermittelt, in der die Formel eingegeben wird. Collabora Office Calc setzt automatisch den Bezug auf die aktuelle Zelle.

=ZEILE(B3) ergibt 3, weil der Bezug auf die dritte Zeile in der Tabelle verweist.

{=ZEILE(D5:D8)} ergibt eine einspaltige Matrix (5, 6, 7, 8), weil der angegebene Bezug die Zeilen 5 bis 8 enthält.

=ZEILE(D5:D8) ergibt 5, weil die Funktion ZEILE nicht als Matrixformel verwendet wird und nur die Zahl der ersten Zeile des Bezugs zurückgegeben wird.

{=ZEILE(A1:E1)} und =ZEILE(A1:E1) ergeben 1, weil der Bezug nur Zeile 1 als erste Zeile in der Tabelle enthält. (Da einzeilige Bereiche nur eine Zeilennummer haben, ist es egal, ob die Formel als Matrixformel verwendet wird oder nicht.)

=ZEILE() ergibt 3, wenn die Formel in Zeile 3 eingegeben wurde.

{=ZEILE(Kaninchen)} ergibt eine einspaltige Matrix (1, 2, 3), wenn "Kaninchen" der benannte Bereich (C1:D3) ist.

ZEILEN

Ergibt die Anzahl der Zeilen in einem Bezug.

ZEILEN(Matrix)

Matrix ist der Bezug oder der benannte Bereich, dessen Gesamtanzahl von Zeilen bestimmt werden soll.

=Zeilen(B5) ergibt 1, weil eine Zelle nur eine Zeile enthält.

=ZEILEN(A10:B12) ergibt 3.

=ZEILEN(Kaninchen) ergibt 3, wenn "Kaninchen" der benannte Bereich (C1:D3) ist.