Kategorie Logisch
Diese Kategorie enthält die Funktion vom Typ Logisch.
Handhabung nicht logischer Argumente in logischen Funktionen
-
Null(0) ist gleichwertig zu FALSCH und alle anderen Zahlen sind gleichwertig zu WAHR.
-
Leere Zellen und Text in Zellen werden ignoriert.
-
Wenn alle Argumente ignoriert werden, wird der Fehler #WERT ausgelöst.
-
Wenn ein Argument auf Text verweist (nicht Text in einer Zelle), wird der Fehler #WERT ausgelöst.
-
Fehler in Argumenten führen zu einem Fehler.
WENNFEHLER
Ergibt Wert, wenn die Zelle keinen Fehlerwert enthält, oder Alternativer Wert, wenn sie einen enthält.
WENNFEHLER(Wert; Alternativer Wert)
Wert ist der Wert oder Ausdruck, der zurückgegeben werden soll, wenn er ungleich ist oder zu einem Fehler führt.
Alternativer Wert ist der Wert oder Ausdruck, der zurückgegeben werden soll, wenn der Ausdruck oder Wert für Wert gleich ist oder zu einem Fehler führt.
WENNFEHLER(C8;C9), wobei C8 =1/0 enthält, ergibt den Wert aus C9, da 1/0 nicht berechnet werden kann.
WENNFEHLER(C8;C9), wobei C8 13 enthält, ergibt 13, den Wert von C8, da 13 kein Fehler ist.
FALSCH
Ergibt den Wahrheitswert FALSCH. Die Funktion FALSCH() benötigt keine Argumente und ergibt immer den logischen Wert FALSCH.
FALSCH()
=FALSCH() ergibt FALSCH
=NICHT(FALSCH()) ergibt WAHR
NICHT
Komplementiert (invertiert) einen logischen Wert.
NICHT(LogischerWert)
LogischerWert ist ein umzukehrender Wert.
=NICHT(A). Wenn A=WAHR, dann ergibt NICHT(A) FALSCH.
ODER
Ergibt WAHR, wenn mindestens ein Argument WAHR ist. Haben alle Argumente den Wert FALSCH, ergibt diese Funktion FALSCH.
Die Argumente sind entweder selbst logische Ausdrücke (WAHR, 1<5, 2+3=7, B8<10), die Wahrheitswerte zurückliefern, oder Matrizen (A1:C3), die Wahrheitswerte enthalten.
ODER(Logischer Wert 1 [; Logischer Wert 2 [; … [; Logischer Wert 255]]])
Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.
Die Einträge 12<11; 13>22 und 45=45 sollen auf Ihre logischen Werte hin überprüft werden.
=ODER(12<11;13>22;45=45) ergibt WAHR.
=ODER(FALSCH();WAHR()) ergibt WAHR.
UND
Ergibt WAHR, wenn alle Argumente WAHR sind. Hat eines der Argumente den Wert FALSCH, ergibt diese Funktion FALSCH.
Die Argumente sind entweder selbst logische Ausdrücke (WAHR, 1<5, 2+3=7, B8<10), die Wahrheitswerte zurückliefern, oder Matrizen (A1:C3), die Wahrheitswerte enthalten.
UND(Logischer Wert 1 [; Logischer Wert 2 [; … [; Logischer Wert 255]]])
Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.
Die Wahrheitswerte der Einträge 12<13; 14>12 und 7<6 sollen geprüft werden:
=UND(12<13;14>12;7<6) ergibt FALSCH.
=UND(FALSCH();WAHR()) ergibt FALSCH.
WAHR
Der Wahrheitswert WAHR wird gesetzt. Die Funktion WAHR() benötigt keine Argumente und ergibt immer den logischen Wert WAHR.
WAHR()
Wenn A=WAHR und B=FALSCH ergeben sich folgende Beispiele:
=UND(A;B) ergibt FALSCH
=ODER(A;B) ergibt WAHR
=NICHT(UND(A;B)) ergibt WAHR
WENN
Gibt die durchzuführende Wahrheitsprüfung an.
WENN(Prüfung [; [DannWert] [; [SonstWert]]])
Prüfung ist ein beliebiger Wert oder Ausdruck, der WAHR oder FALSCH sein kann.
DannWert (optional) ist der Wert, der zurückgegeben wird, wenn die logische Prüfung WAHR ist.
SonstWert (optional) ist der Wert, der zurückgegeben wird, wenn die logische Prüfung FALSCH ist.
In Collabora Office Calc Funktionen dürfen Parameter, die als "optional" gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als "optional" gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.
=WENN(A1>5;100;"zu klein") – Wenn der Wert in A1 größer als 5 ist, wird der Wert 100 wird zurückgegeben; anderenfalls wird der Text zu klein zurückgegeben.
=WENN(A1>5;;"zu klein") – Wenn der Wert in A1 größer als 5 ist, wird der Wert 0 zurückgegeben, da leere Parameter als 0 behandelt werden; anderenfalls wird der Text zu klein zurückgegeben.
=WENN(A1>5;100;) – Wenn der Wert in A1 kleiner als 5 ist, wird der Wert 0 zurückgegeben, weil der leere SonstWert als 0 interpretiert wird; anderenfalls wird 100 zurückgegeben.
XODER
Ergibt WAHR, wenn eine ungerade Anzahl von Argumenten WAHR liefert.
Die Argumente sind entweder selbst logische Ausdrücke (WAHR, 1<5, 2+3=7, B8<10), die Wahrheitswerte zurückliefern, oder Matrizen (A1:C3), die Wahrheitswerte enthalten.
XODER(Logischer Wert 1 [; Logischer Wert 2 [; … [; Logischer Wert 255]]])
=XODER(WAHR();WAHR()) ergibt FALSCH.
=XODER(WAHR();WAHR();WAHR()) ergibt WAHR.
=XODER(FALSCH();WAHR()) ergibt WAHR.