COUNTIFS

Returns the count of cells that meet criteria in multiple ranges.

Aquesta funció és disponible des de la versió 4.0 del Collabora Office.

Sintaxi

COUNTIFS(Range; Criterion[; Range2; Criterion2][; ... ; [Range127; Criterion127]])

Range1 – required argument. It is a range of cells, a name of a named range, or a label of a column or a row, to which the corresponding criterion is to be applied.

Criterion: A criterion is a single cell Reference, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

A Number or Logical value. A matching cell content equals the Number or Logical value.
A value beginning with a comparator (<, <=, =, >, >=, <>).

For =, if the value is empty it matches empty cells.

For <>, if the value is empty it matches non-empty cells.

For <>, if the value is not empty it matches any cell content except the value, including empty cells.

Note: "=0" does not match empty cells.

For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.
Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Range2 – Optional. Range2 and all the following mean the same as Range1.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in - Collabora Office Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

Range, Range2, ... and Criterion, Criterion2, ... must have the same size, otherwise the function returns err:502 - Invalid argument.

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.

The function can have up to 255 arguments, meaning that you can specify 127 criteria ranges and criteria for them.

If a cell contains TRUE, it is treated as 1, if a cell contains FALSE – as 0 (zero).

Aquesta funció forma part de l'estàndard Open Document Format for Office Applications (OpenDocument), versió 1.2 (ISO/IEC 26300:2-2015).

Exemple

Considereu la taula següent

	A	B	C
1	Nom del producte	Vendes	Ingressos
2	llapis	20	65
3	ploma	35	85
4	quadern	20	190
5	llibre	17	180
6	estoig	no	no

En tots els exemples següents, els intervals del càlcul contenen la fila 6, la qual és ignorada perquè conté text.

Ús simple

=COMPTASICONJUNT(B2:B6;">=20")

Compta la quantitat de files de l'interval B2:B6 amb valors majors o igual a 20. Retorna 3, perquè la cinquena i la sisena files no compleixen el criteri.

=COMPTASICONJUNT(B2:B6;">=20";C2:C6;">70")

Compta la quantitat de files que contenen simultàniament valors majors de 70 en l'interval C2:C6 i valors majors o iguals a 20 en l'interval B2:B6. Retorna 2, perquè la segona, la cinquena i la sisena files no compleixen almenys un criteri.

Ús d'expressions regulars i funcions imbricades

For these examples to work as described, make sure that Enable regular expressions in formulas is selected in - Collabora Office Calc - Calculate.

=COMPTASICONJUNT(B2:B6;"[:alpha:]*")

Compta la quantitat de files de l'interval B2:B6 que contenen només símbols alfabètics. Retorna 1, perquè només la sesena fila compleix el criteri.

=COMPTASICONJUNT(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Compta la quantitat de files de l'interval B2:B6 excloent les files amb valors mínims i màxims d'aquest interval. Retorna 2, perquè la tercera, la cinquena i la sisena files no compleixen com a mínim un criteri.

=COMPTASICONJUNT(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Compta la quantitat de files que corresponen a totes les cel·les de l'interval A2:A6 començant per "llapis" i a totes les cel·les de l'interval B2:B6 excepte el màxim. Retorna 1, perquè només la segona fila compleix tots els criteris.

Referència a una cel·la com a criteri

Si heu de canviar el criteri fàcilment, potser voleu indicar-lo en una cel·la separada i usar una referència a aquesta cel·la en la condició de la funció SUMASI. Per exemple, la funció superior es pot reescriure com a:

=COMPTASICONJUNT(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Si E2 = llapis, la funció retorna 1, perquè l'enllaç a la cel·la se substitueix amb el seu contingut i funciona com a funció a dalt.

Obre un fitxer amb un exemple:

COUNTIFS wiki page.

COUNT, COUNTIF, COUNTBLANK, COMPTAA

COUNTIFS, MINIFS, MAXIFS, funció MITJANASICONJUNT, SUMIFS

Llista d'expressions regulars