Kategorie Logisch

Diese Kategorie enthält die logischen Funktionen.

Handhabung nicht-logischer Argumente in logischen Funktionen

• Null(0) ist gleichwertig zu FALSCH und alle anderen Zahlen sind gleichwertig zu WAHR.

• Leere Zellen und Text in Zellen werden ignoriert.

• Wenn alle Argumente ignoriert werden, wird der Fehler #WERT ausgelöst.

• Wenn ein Argument auf Text verweist (nicht Text in einer Zelle), wird der Fehler #WERT ausgelöst.

• Fehler in Argumenten führen zu einem Fehler.

FALSCH

Ergibt den Wahrheitswert FALSCH. Die Funktion FALSCH() benötigt keine Argumente und ergibt immer den logischen Wert FALSCH.

FALSCH()

=FALSCH() ergibt FALSCH

=NICHT(FALSCH()) ergibt WAHR

NICHT

Komplementiert (invertiert) einen logischen Wert..

NICHT(LogischerWert)

LogischerWert ist ein umzukehrender Wert.

=NICHT(A). Wenn A=WAHR, dann ergibt NICHT(A) FALSCH.

ODER

Ergibt WAHR, wenn mindestens ein Argument WAHR ist. Haben alle Argumente den Wert FALSCH, ergibt diese Funktion FALSCH.

Die Argumente sind entweder selbst logische Ausdrücke (WAHR, 1<5, 2+3=7, B8<10), die Wahrheitswerte zurückliefern, oder Matrizen (A1:C3), die Wahrheitswerte enthalten.

ODER(LogischerWert1; LogischerWert2 ...LogischerWert30)

LogischerWert1; LogischerWert2; ... LogischerWert30 sind zu prüfende Bedingungen. Alle Bedingungen können entweder WAHR oder FALSCH sein. Wenn ein Bereich als Parameter eingegeben wird, verwendet die Funktion alle Werte des Bereichs.

Die Einträge 12<11; 13>22 und 45=45 sollen auf Ihre logischen Werte hin überprüft werden.

=ODER(12<11;13>22;45=45) ergibt WAHR.

=ODER(FALSCH;WAHR) ergibt WAHR.

UND

Ergibt WAHR, wenn alle Argumente WAHR sind. Hat eines der Argumente den Wert FALSCH, ergibt diese Funktion FALSCH.

Die Argumente sind entweder selbst logische Ausdrücke (WAHR, 1<5, 2+3=7, B8<10), die Wahrheitswerte zurückliefern, oder Matrizen (A1:C3), die Wahrheitswerte enthalten.

UND(LogischerWert1; LogischerWert2 ...LogischerWert30)

LogischerWert1; LogischerWert2; ... LogischerWert30 sind zu prüfende Bedingungen. Alle Bedingungen können entweder WAHR oder FALSCH sein. Wenn ein Bereich als Parameter eingegeben wird, verwendet die Funktion alle Werte des Bereichs. Das Ergebnis ist WAHR, wenn der logische Wert in allen Zellen innerhalb des Zellbereichs WAHR ist.

Die Wahrheitswerte der Einträge 12<13; 14>12 und 7<6 sollen geprüft werden:

=UND(12<13;14>12;7<6) ergibt FALSCH.

=UND (FALSCH;WAHR) ergibt FALSCH.

WAHR

Der Wahrheitswert WAHR wird gesetzt. Die Funktion WAHR() benötigt keine Argumente und ergibt immer den logischen Wert WAHR.

WAHR()

Wenn A=WAHR und B=FALSCH ergeben sich folgende Beispiele:

=UND(A;B) ergibt FALSCH

=ODER(A;B) ergibt WAHR

=NICHT(UND(A;B)) ergibt WAHR

WENN

Gibt die durchzuführende Wahrheitsprüfung an.

WENN(Prüfung; DannWert; SonstWert)

Prüfung ist ein beliebiger Wert oder Ausdruck, der WAHR oder FALSCH sein kann.

DannWert (optional) ist der Wert, der zurückgegeben wird, wenn die logische Prüfung WAHR ist.

SonstWert (optional) ist der Wert, der zurückgegeben wird, wenn die logische Prüfung FALSCH ist.

In Collabora Office Calc Funktionen dürfen Parameter, die als "optional" gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als "optional" gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.

=WENN(A1>5;100;"zu klein") Wenn der Wert in A1 größer als 5 ist, wird der Wert 100 in die aktuelle Zelle eingegeben; anderenfalls wird der Text "zu klein" (ohne Anführungszeichen) eingegeben.

XODER

Ergibt WAHR, wenn eine ungerade Anzahl von Argumenten WAHR liefert.

Die Argumente sind entweder selbst logische Ausdrücke (WAHR, 1<5, 2+3=7, B8<10), die Wahrheitswerte zurückliefern, oder Matrizen (A1:C3), die Wahrheitswerte enthalten.

XODER(LogischerWert1; LogischerWert2; ...; LogischerWert30)

=XODER(WAHR;WAHR) ergibt FALSCH

=XODER(WAHR;WAHR;WAHR) ergibt WAHR

=XODER(FALSCH;WAHR) ergibt WAHR