Finanzmathematische Funktionen Teil Eins
In dieser Kategorie finden Sie die finanzmathematischen Funktionen von Collabora Office Calc.
AMORLINEARK
Berechnet den Abschreibungsbetrag für eine Abrechnungsperiode als lineare Amortisation. Wird das Anlagegut während der Abrechnungsperiode gekauft, wird der anteilige Abschreibungsbetrag berücksichtigt.
AMORLINEARK(Anschaffungswert; Anschaffungsdatum; ErsterZeitraum; Restwert; Zeitraum; Zins; Basis)
Anschaffungswert ist der Wert der Anschaffung.
Anschaffungsdatum ist das Datum der Anschaffung.
ErsterZeitraum ist das Enddatum des ersten Abschreibungszeitraumes.
Restwert ist der Restwert des Anlagegutes am Ende der Abschreibungsdauer.
Zeitraum ist der zu betrachtende Abschreibungszeitraum.
Zins ist die Abschreibungsrate.
AMORDEGRK
Berechnet den Abschreibungsbetrag für einen Abrechnungszeitraum gemäß der degressiven Amortisation. Im Gegensatz zu AMORLINEARK wird hier ein von der Nutzungsdauer unabhängiger Abschreibungskoeffizient verwendet.
AMORDEGRK(Anschaffungswert; Anschaffungsdatum; ErsterZeitraum; Restwert; Zeitraum; Zins; Basis)
Anschaffungswert ist der Wert der Anschaffung.
Anschaffungsdatum ist das Datum der Anschaffung.
ErsterZeitraum ist das Enddatum des ersten Abschreibungszeitraumes.
Restwert ist der Restwert des Anlagegutes am Ende der Abschreibungsdauer.
Zeitraum ist der zu betrachtende Abschreibungszeitraum.
Zins ist die Abschreibungsrate.
AUSZAHLUNG
Berechnet den Auszahlungsbetrag eines Wertpapiers mit festem Zinssatz zu einem gegebenen Zeitpunkt.
AUSZAHLUNG("Abrechnung"; "Fälligkeit"; Investition; Disagio; Basis)
Abrechnung ist das Kaufdatum des Wertpapiers.
Fälligkeit ist das Datum, an dem das Wertpapier fällig wird (abläuft).
Investment ist die Kaufsumme.
Disagio ist der prozentuale Abschlag (Disagio) auf die Anschaffung des Wertpapiers.
Abrechnungstermin: 15. Februar 1999, Fälligkeitstermin: 15. Mai 1999, Anlagebetrag: 1000 Währungseinheiten, Disagio: 5,75 Prozent, Basis: Taggenau/360 = 2.
Der Auszahlungsbetrag zum Fälligkeitstermin berechnet sich wie folgt:
=AUSZAHLUNG("15.2.1999";"15.5.1999";1000;0,0575;2) ergibt 1014,420266.
IKV
Berechnet den internen Zinsfuß einer Investition. Die Werte stellen die Kapitalflusswerte in regelmäßigen Abständen dar. Mindestens ein Wert muss negativ sein (Zahlungen) und einer positiv (Ertrag).
Falls die Zahlungen in unregelmäßigen Abständen stattfinden, nutzen Sie die Funktion XIRR.
IKV(Werte; Schätzwert)
Werte ist eine Matrix mit den Werten.
Schätzwert (optional) ist der Schätzwert. Der interne Zinsfuß wird nach dem Iterationsverfahren berechnet. Sollten nur wenige Werte vorliegen, empfiehlt sich die Angabe eines Schätzwerts, um die Iteration zu ermöglichen.
Unter der Annahme, dass die Zellinhalte A1=-10000, A2=3500, A3=7600 and A4=1000 sind, ergibt die Formel =IKV(A1:A4) ein Ergebnis von 11,33 %.
Aufgrund der verwendeten iterativen Methode kann IKV versagen und den Fehler 523 mit der Meldung "Fehler: Rechenverfahren konvergiert nicht" in der Statusleiste zurückgeben. In diesem Fall probieren Sie, einen anderen Näherungswert für Schätzung einzugeben.
DISAGIO
Berechnet den prozentualen Abschlag (Disagio) eines Wertpapiers.
DISAGIO("Abrechnung"; "Fälligkeit"; Kurs; Rückzahlung; Basis)
Abrechnung ist das Kaufdatum des Wertpapiers.
Fälligkeit ist das Datum, an dem das Wertpapier fällig wird (abläuft).
Kurs ist der Kurs des Wertpapiers pro 100 Währungseinheiten des Nennwerts.
Rückzahlung ist der Rückzahlungswert des Wertpapiers pro 100 Währungseinheiten des Nennwerts.
Ein Wertpapier wird am 25.1.2001 gekauft; der Fälligkeitstermin ist der 15.11.2001. Der Kurswert (Kaufpreis) liegt bei 97, der Rückzahlungswert bei 100. Bei tagesgenauer Berechnung (Basis 3) ist der Abschlag (Disagio) wie hoch?
=DISAGIO("25.1.2001";"15.11.2001";97;100;3) ergibt ungefähr 0,0372 oder 3,72 %.
ISPMT
Berechnet die Höhe der Zinsen bei gleich bleibenden Tilgungsraten.
ISPMT(Zins; Zeitraum; SummeZeiträume; Invest)
Zins bestimmt den periodischen Zinssatz.
Zeitraum ist die Anzahl der Tilgungszeiträume für die Berechnung der Zinsen.
SummeZeiträume ist die Summe der Tilgungszeiträume.
Invest ist der Betrag der Investition.
Bei einer Kreditsumme von 120.000 Währungseinheiten mit zweijähriger Laufzeit und monatlicher Tilgung, bei einem jährlichen Zinssatz von 12 % wird die Höhe der Zinsen nach 1,5 Jahren gesucht.
=ISPMT(1%;18;24;120000) = -300 Währungseinheiten. Der monatliche Zins nach 1,5 Jahren beträgt 300 Währungseinheiten.
LAUFZEIT
Berechnet die Laufzeit eines festverzinslichen Wertpapiers in Jahren.
Die Funktionen, deren Namen mit _ADD oder _EXCEL2003 enden, geben dieselben Ergebnisse zurück wie die entsprechenden Funktionen in Microsoft Excel ohne Endung. Verwenden Sie die Funktionen ohne Endung, um Ergebnisse zu erhalten, die auf internationalen Standards basieren.
LAUFZEIT("Abrechnung"; "Fälligkeit"; Kupon; Rendite; Häufigkeit)
Abrechnung ist das Kaufdatum des Wertpapiers.
Fälligkeit ist das Datum, an dem das Wertpapier fällig wird (abläuft).
Kupon ist der jährliche Kuponzinssatz (Nominalzinssatz)
Rendite ist die jährliche Rendite des Wertpapiers.
Häufigkeit ist die Anzahl von Zinszahlen im Jahr (1, 2 oder 4).
Ein Wertpapier wird am 1.1.2001 gekauft; der Fälligkeitstermin ist der 1.1.2006. Der Anleihzins beträgt 8 %. Die Rendite beträgt 9,0 %. Die Zinszahlung erfolgt halbjährlich (Häufigkeit = 2). Wie lang ist die modifizierte Laufzeit bei tagesgenauer Berechnung (Basis 3)?
=LAUFZEIT("01.01.2001";"01.01.2006";0,08;0,09;2;3)
AUFGELZINSF
Berechnet die aufgelaufenen Zinsen (Stückzinsen) eines Wertpapiers, die bei Fälligkeit ausgezahlt werden.
AUFGELZINSF(Ausgabe; Abrechnung; Zins; Nennwert; Basis)
Ausgabe (erforderlich) ist das Ausgabedatum des Wertpapiers.
Abrechnung (erforderlich) ist das Abrechnungsdatum, an dem die bis dahin aufgelaufenen Zinsen berechnet werden.
Zins (erforderlich) ist der jährliche Nominalzins (Kuponzins).
Nennwert (erforderlich) ist der Nennwert des Wertpapiers.
Ein Wertpapier wird am 01.04.2001 ausgegeben. Der Fälligkeitstermin ist auf den 15.06.2001 festgelegt. Nominalzins sei 10 % oder 0,1 und der Nennwert sei 1000 Währungseinheiten. Basis der Berechnung ist taggenau (3). Wie hoch sind die aufgelaufenen Zinsen?
=AUFGELZINSF("01.04.2001";"15.06.2001";0,1;1000;3) ergibt 20,54795.
AUFGELZINS
Berechnet die aufgelaufenen Zinsen eines Wertpapiers mit periodischer Zinszahlung.
AUFGELZINS(Ausgabe; ErsterZins; Abrechnung; Zins; Nennwert; Häufigkeit; Basis)
Ausgabe (erforderlich) ist das Ausgabedatum des Wertpapiers.
ErsterZins (erforderlich) ist der erste Zinstermin des Wertpapiers.
Abrechnung (erforderlich) ist das Abrechnungsdatum, an dem die bis dahin aufgelaufenen Zinsen berechnet werden.
Zins (Erforderlich) ist der jährliche Nominalzins (Kuponzins)
Nennwert (erforderlich) ist der Nennwert des Wertpapiers.
Häufigkeit (erforderlich) ist die Anzahl der Zinszahlungen im Jahr (1, 2 oder 4).
Ein Wertpapier wird am 28.02.2001 ausgegeben. Der erste Zinstermin ist auf den 31.08.2001 festgelegt. Das Abrechnungsdatum ist der 01.05.2001. Nominalzins sei 10 % oder 0,1 und der Nennwert sei 1000 Währungseinheiten. Die Zinsen werden halbjährlich gezahlt (Häufigkeit ist 2). Basis ist US-Methode (0). Wie hoch sind die aufgelaufenen Zinsen?
=AUFGELZINS("28.02.2001";"31.08.2001";"01.05.2001";0,1;1000;2;0) ergibt 16,94444.
EFFEKTIV_ADD
Berechnet die jährliche Effektivverzinsung auf Grundlage des Nominalzinssatzes und der Anzahl der jährlichen Zinszahlungen.
Die Funktionen, deren Namen mit _ADD oder _EXCEL2003 enden, geben dieselben Ergebnisse zurück wie die entsprechenden Funktionen in Microsoft Excel ohne Endung. Verwenden Sie die Funktionen ohne Endung, um Ergebnisse zu erhalten, die auf internationalen Standards basieren.
EFFEKTIV_ADD(Nominalzins; AproJ)
Nominalzins ist der jährliche Nominalzins.
AproJ ist die Anzahl von Zinszahlungen pro Jahr.
Welcher Effektivzins ergibt sich bei 5,25 % Nominalzins und vierteljährlicher Zahlung?
=EFFEKTIV_ADD(0,0525;4) ergibt 0,053543 oder 5,3543 %.
BW
Ergibt den Barwert einer Investition, erwachsend aus einer Reihe regelmäßiger Zahlungen.
Sie können diese Funktion verwenden, um zu berechnen, wie viel Geld Sie heute fest anlegen müssen, um eine bestimmte Anzahl an Perioden jedes Mal einen bestimmten Betrag (Annuität) ausgezahlt zu erhalten. Dabei können Sie optional angeben, wie viel Geld am Ende dieser Perioden noch übrig sein soll. Auch lässt sich festlegen, ob der ausgezahlte Betrag jeweils am Beginn oder Ende einer Periode gezahlt wird.
Sie können die Werte als Zahlen, Ausdrücke oder Bezüge eingeben. Erhalten Sie beispielsweise 8 % Zinsen jährlich, wünschen als Periode aber den Monat, so geben Sie in das Feld Zinsen 8%/12 ein und Collabora Office Calc berechnet automatisch den korrekten Faktor.
BW(Zins; ZZr; Zahlung; ZW; Typ)
Zins legt den Zinssatz pro Periode fest.
ZZr ist die Gesamtzahl von Zeiträumen (Zahlungsperioden).
Zahlung ist die regelmäßige Zahlung pro Zeitraum.
ZW (optional) bestimmt den zukünftigen Wert, der nach Zahlung der letzten Rate übrigbleiben soll.
F (optional) bezeichnet die Fälligkeit. F = 1 heißt Fälligkeit am Anfang der Periode, F = 0 (Vorgabe) heißt Fälligkeit am Ende.
In Collabora Office Calc Funktionen dürfen Parameter, die als "optional" gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als "optional" gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.
Wie hoch ist der Barwert einer Investition, wenn monatlich 500 Währungseinheiten ausgezahlt werden, der Zinssatz 8 % pro Jahr beträgt? Der Zahlungszeitraum beträgt 48 Monate und als Endwert sollen noch 20.000 Währungseinheiten übrig bleiben.
=BW(8%/12;48;500;20000) = -35.019,37 Währungseinheiten. Unter den angegebenen Bedingungen müssen Sie heute 35.019,37 Währungseinheiten einzahlen, damit Sie über einen Zeitraum von 48 Monaten 500 Währungseinheiten pro Monat erhalten und am Ende 20.000 Währungseinheiten übrig bleiben. Eine Überprüfung zeigt: 48 x 500 Währungseinheiten + 20.000 Währungseinheiten = 44.000 Währungseinheiten. Die Differenz zwischen diesem Betrag und den eingezahlten 35.000 Währungseinheiten entspricht den gezahlten Zinsen.
Geben Sie die Werte nicht direkt, sondern als Bezug in die Formel ein, so können Sie bequem beliebige "Was-wäre-wenn"-Szenarien durchrechnen lassen. Denken Sie daran, die Bezüge auf die Konstanten als absolute Bezüge festzulegen. Beispiele für diese Art der Anwendung finden Sie bei den Abschreibungsfunktionen.
GDA2
Ergibt die Abschreibungsrate nach der geometrisch-degressiven Methode für einen bestimmten Abschreibungszeitraum.
Verwenden Sie diese Abschreibungsform, um (im Gegensatz zur linearen Abschreibung) am Beginn der Abschreibung einen höheren Abschreibungswert zu erhalten. Der Abschreibungswert verringert sich pro Abschreibungszeitraum um die vom Anschaffungswert bereits abgezogenen Abschreibungen.
GDA2(Anschaffungswert; Restwert; Nutzungsdauer; Zeitraum; Monat)
Anschaffungswert ist der Anschaffungswert des Wirtschaftsgutes.
Restwert ist der Restwert eines Wirtschaftsgutes am Ende der Abschreibung.
Nutzungsdauer definiert den Zeitraum, über den das Wirtschaftsgut abgeschrieben wird.
Zeitraum ist die Länge einer Periode. Die Länge muss in derselben Zeiteinheit wie die Nutzungsdauer angegeben werden.
Monat (optional) bezeichnet die Anzahl der Monate im ersten Jahr der Abschreibung. Wenn der Eintrag fehlt, wird 12 angenommen.
Eine EDV-Anlage mit einem Anschaffungswert von 25.000 Währungseinheiten soll über einen Zeitraum von drei Jahren abgeschrieben werden. Der Restwert soll nach Ablauf der Zeit 1.000 Währungseinheiten betragen. Eine Periode dauert 30 Tage.
=GDA2(25000;1000;36;1;6) = 1.075,00 Währungseinheiten
Die geometrische-degressive Abschreibung der EDV-Anlage beträgt 1.075,00 Währungseinheiten.
GDA
Ergibt die arithmetisch-degressive Abschreibung eines Wirtschaftsgutes für eine bestimmte Periode.
Verwenden Sie diese Abschreibungsmethode anstelle der arithmetischen Abschreibung, wenn ein höherer Anfangsabschreibungswert benötigt wird. Der Abschreibungswert verringert sich mit jeder Periode und wird normalerweise für Wirtschaftsgüter verwendet, die kurz nach der Anschaffung einen höheren Wertverlust aufweisen (beispielsweise Fahrzeuge, Computer). Beachten Sie bitte, dass der Restbuchwert in dieser Berechnungsmethode nie Null wird.
GDA(Anschaffungswert; Restwert; Nutzungsdauer; Zeitraum; Faktor)
Anschaffungswert legt den Anschaffungswert eines Wirtschaftsgutes fest.
Restwert legt den Restwert eines Wirtschaftsgutes fest.
Nutzungsdauer Ist die Anzahl der Perioden (zum Beispiel Jahre oder Monate), wie lang das Anlagevermögen verwendet wird.
Zeitraum steht für den Zeitraum, für den der Wert berechnet werden soll.
Faktor (optional) ist der Faktor für die Abnahme der Abschreibung. Wenn der Wert nicht angegeben wird, wird standardmäßig der Faktor 2 angenommen.
Eine EDV-Anlage mit einem Anschaffungspreis von 75.000 Währungseinheiten soll über 5 Jahre monatlich abgeschrieben werden. Der Restwert soll 1 Währungseinheit betragen. Der Faktor beträgt 2.
=GDA(75000;1;60;12;2) = 1.721,81 Währungseinheiten. Folglich beträgt die zweifach degressive Abschreibung während im zwölften Monat nach der Anschaffung 1.721,81 Währungseinheiten.
DIA
Ergibt die arithmetisch-degressive Abschreibungsrate.
Sie verwenden diese Funktion, um für eine Periode während der gesamten Abschreibungsdauer eines Objekts den Betrag der Abschreibung zu berechnen. Die digitale Abschreibung vermindert die Abschreibungssumme von Periode zu Periode um einen konstanten Betrag.
DIA(Anschaffungswert; Restwert; Nutzungsdauer; Zeitraum)
Anschaffungswert ist der Anschaffungswert des Wirtschaftsgutes.
Restwert ist der Restwert des Wirtschaftgutes.
Nutzungsdauer ist die Nutzungsdauer, die festlegt, über wieviele Zeiträume das Wirtschaftsgut abgeschrieben wird.
Zeitraum steht für den Zeitraum, für den die Abschreibung berechnet werden soll.
Eine Videoanlage mit dem Anschaffungswert von 50.000 Währungseinheiten soll über 5 Jahre jährlich abgeschrieben werden. Der Restwert soll 10.000 Währungseinheiten betragen. Die Abschreibung soll für das erste Jahr ermittelt werden.
=DIA(50000;10000;5;1)=13.333,33 Währungseinheiten. Der Abschreibungsbetrag für das erste Jahr beträgt 13.333,33 Währungseinheiten.
Am besten definieren Sie eine Abschreibungstabelle, damit Sie auf einen Blick die Abschreibungsraten pro Zeitraum sehen können. Wenn Sie die verschiedenen Abschreibungsformeln von Collabora Office Calc nebeneinander eingeben, sehen Sie auch, welche Form der Abschreibung für diesen Fall die günstigste ist. Geben Sie die Tabelle wie folgt ein:
|
A |
B |
C |
D |
E |
|
|
1 |
Anschaffungswert |
Restwert |
Nutzungsdauer |
Zeitraum |
Abschreibung DIA |
|
2 |
50.000 Währungseinheiten |
10.000 Währungseinheiten |
5 |
1 |
13.333,33 Währungseinheiten |
|
3 |
2 |
10.666,67 Währungseinheiten |
|||
|
4 |
3 |
8.000,00 Währungseinheiten |
|||
|
5 |
4 |
5.333,33 Währungseinheiten |
|||
|
6 |
5 |
2.666,67 Währungseinheiten |
|||
|
7 |
6 |
0,00 Währungseinheiten |
|||
|
8 |
7 |
||||
|
9 |
8 |
||||
|
10 |
9 |
||||
|
11 |
10 |
||||
|
12 |
|||||
|
13 |
>0 |
Summe |
40.000,00 Währungseinheiten |
Die Formel in E2 lautet wie folgt:
=DIA($A$2;$B$2;$C$2;D2)
Diese Formel wird in Spalte E bis nach E10 dupliziert (E2 auswählen, dann die rechte untere Ecke mit der Maus nach unten ziehen).
In Zelle E13 steht die Formel, die alle Abschreibungsbeträge zur Kontrolle summiert. Sie nutzt die Funktion SUMMEWENN, da die negativen Werte in E8:E11 nicht berücksichtigt werden dürfen. Die Bedingung >0 steht in Zelle A13. Die Formel in E13 lautet wie folgt:
=SUMMEWENN(E2:E11;A13)
Sie können jetzt die Abschreibung auf 10 Jahre ansehen, oder bei einem Restwert von 1 Währungseinheit, oder andere Anschaffungswerte eingeben und so weiter.
EFFEKTIV
Ergibt die jährliche Effektivverzinsung zu einer Nominalverzinsung.
Da sich die Nominalverzinsung auf eine Zinsfälligkeit am Ende des Berechnungszeitraumes bezieht, Zinsen aber oftmals monatlich, zum Quartal oder zu einem anderen Zeitraum vor Ende des Berechnungszeitraumes anteilig fällig werden, also praktisch im voraus gezahlt werden, erhöht sich der Effektivzins mit der Zahl der Zinsabschlagszahlungen.
EFFEKTIV(Nom; P)
Nom ist der Nominalzinssatz.
P ist die Anzahl der jährlichen Zinszahlungen pro Jahr.
Wenn der jährliche Nominalzins 9,75 % beträgt und vier Zinsberechnungszeiträume festgelegt sind, wie hoch ist dann tatsächliche Zinssatz (Effektivzins)?
=EFFEKTIV(9,75%;4) = 10,11 %. Der jährliche effektive Zins beträgt demzufolge 10,11 %.