Mathematical Functions
This category contains the Mathematical functions for Calc. To open the Function Wizard, choose Insert - Function.
AGGREGATE
This function returns an aggregate result of the calculations in the range. You can use different aggregate functions listed below. The Aggregate function enables you to omit hidden rows, errors, SUBTOTAL and other AGGREGATE function results in the calculation.
SUMIFS
Returns the sum of the values of cells in a range that meets multiple criteria in multiple ranges.
ABS
Returns the absolute value of a number.
ABS(Number)
Number is the number whose absolute value is to be calculated. The absolute value of a number is its value without the +/- sign.
=ABS(-56) returns 56.
=ABS(12) returns 12.
=ABS(0) returns 0.
ACOS
Returns the inverse trigonometric cosine of a number.
ACOS(Number)
This function returns the inverse trigonometric cosine of Number, that is the angle (in radians) whose cosine is Number. The angle returned is between 0 and PI.
To return the angle in degrees, use the DEGREES function.
=ACOS(-1) returns 3.14159265358979 (PI radians)
=DEGREES(ACOS(0.5)) returns 60. The cosine of 60 degrees is 0.5.
ACOSH
Returns the inverse hyperbolic cosine of a number.
ACOSH(Number)
This function returns the inverse hyperbolic cosine of Number, that is the number whose hyperbolic cosine is Number.
Number must be greater than or equal to 1.
=ACOSH(1) returns 0.
=ACOSH(COSH(4)) returns 4.
ACOT
Returns the inverse cotangent (the arccotangent) of the given number.
ACOT(Number)
This function returns the inverse trigonometric cotangent of Number, that is the angle (in radians) whose cotangent is Number. The angle returned is between 0 and PI.
To return the angle in degrees, use the DEGREES function.
=ACOT(1) returns 0.785398163397448 (PI/4 radians).
=DEGREES(ACOT(1)) returns 45. The tangent of 45 degrees is 1.
ACOTH
Returns the inverse hyperbolic cotangent of the given number.
ACOTH(Number)
This function returns the inverse hyperbolic cotangent of Number, that is the number whose hyperbolic cotangent is Number.
An error results if Number is between -1 and 1 inclusive.
=ACOTH(1.1) returns inverse hyperbolic cotangent of 1.1, approximately 1.52226.
ASIN
Returns the inverse trigonometric sine of a number.
ASIN(Number)
This function returns the inverse trigonometric sine of Number, that is the angle (in radians) whose sine is Number. The angle returned is between -PI/2 and +PI/2.
To return the angle in degrees, use the DEGREES function.
=ASIN(0) returns 0.
=ASIN(1) returns 1.5707963267949 (PI/2 radians).
=DEGREES(ASIN(0.5)) returns 30. The sine of 30 degrees is 0.5.
ASINH
Returns the inverse hyperbolic sine of a number.
ASINH(Number)
This function returns the inverse hyperbolic sine of Number, that is the number whose hyperbolic sine is Number.
=ASINH(-90) returns approximately -5.1929877.
=ASINH(SINH(4)) returns 4.
ATAN
Returns the inverse trigonometric tangent of a number.
ATAN(Number)
This function returns the inverse trigonometric tangent of Number, that is the angle (in radians) whose tangent is Number. The angle returned is between -PI/2 and PI/2.
To return the angle in degrees, use the DEGREES function.
=ATAN(1) returns 0.785398163397448 (PI/4 radians).
=DEGREES(ATAN(1)) returns 45. The tangent of 45 degrees is 1.
ATAN2
Returns the inverse trigonometric tangent of the specified x and y coordinates.
ATAN2(NumberX; NumberY)
NumberX is the value of the x coordinate.
NumberY is the value of the y coordinate.
ATAN2 returns the inverse trigonometric tangent, that is, the angle (in radians) between the x-axis and a line from point NumberX, NumberY to the origin. The angle returned is between -PI and PI.
To return the angle in degrees, use the DEGREES function.
=ATAN2(20;20) returns 0.785398163397448 (PI/4 radians).
=DEGREES(ATAN2(12.3;12.3)) returns 45. The tangent of 45 degrees is 1.
ATANH
Returns the inverse hyperbolic tangent of a number.
ATANH(Number)
This function returns the inverse hyperbolic tangent of Number, that is the number whose hyperbolic tangent is Number.
Number must obey the condition -1 < number < 1.
=ATANH(0) returns 0.
CEILING
Rounds a number up to the nearest multiple of Significance.
CEILING(Number; Significance; Mode)
Number is the number that is to be rounded up.
Significance is the number to whose multiple the value is to be rounded up.
Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded away from zero. If the Mode value is equal to zero or is not given, negative numbers are rounded towards zero.
If the spreadsheet is exported to Microsoft Excel, the CEILING function is exported as the equivalent CEILING.MATH function that exists since Excel 2013. If you plan to use the spreadsheet with earlier Excel versions, use either CEILING.PRECISE that exists since Excel 2010, or CEILING.XCL that is exported as the CEILING function compatible with all Excel versions. Note that CEILING.XCL always rounds away from zero.
=CEILING(-11;-2) returns -10
=CEILING(-11;-2;0) returns -10
=CEILING(-11;-2;1) returns -12
CEILING.MATH
Rounds a number up to the nearest multiple of Significance.
CEILING.MATH(Number; Significance; Mode)
Number is the number that is to be rounded up.
Significance is the number to whose multiple the value is to be rounded up.
Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded away from zero. If the Mode value is equal to zero or is not given, negative numbers are rounded towards zero.
This function exists for interoperability with Microsoft Excel 2013 or newer.
=CEILING.MATH(-10;-3) returns -9
=CEILING.MATH(-10;-3;0) returns -9
=CEILING.MATH(-10;-3;1) returns -12
CEILING.PRECISE
Rounds a number up to the nearest multiple of Significance, regardless of sign of Significance
CEILING.PRECISE(Number; Significance)
Number (required) is the number that is to be rounded up.
Significance (optional) is the number to whose multiple the value is to be rounded up.
=CEILING.PRECISE(-11;-2) returns -10
CEILING.XCL
Rounds a number away from zero to the nearest multiple of Significance.
CEILING.XCL(Number; Significance)
Number is the number that is to be rounded.
Significance is the number to whose multiple the value is to be rounded.
This function exists for interoperability with Microsoft Excel 2007 or older versions.
=CEILING.XCL(1;3) returns 3
=CEILING.XCL(7;4) returns 8
=CEILING.XCL(-10;-3) returns -12
COMBIN
Returns the number of combinations for elements without repetition.
COMBIN(Count1; Count2)
Count1 is the number of items in the set.
Count2 is the number of items to choose from the set.
COMBIN returns the number of ordered ways to choose these items. For example if there are 3 items A, B and C in a set, you can choose 2 items in 3 different ways, namely AB, AC and BC.
COMBIN implements the formula: Count1!/(Count2!*(Count1-Count2)!)
=COMBIN(3;2) returns 3.
COMBINA
Returns the number of combinations of a subset of items including repetitions.
COMBINA(Count1; Count2)
Count1 is the number of items in the set.
Count2 is the number of items to choose from the set.
COMBINA returns the number of unique ways to choose these items, where the order of choosing is irrelevant, and repetition of items is allowed. For example if there are 3 items A, B and C in a set, you can choose 2 items in 6 different ways, namely AA, AB, AC, BB, BC and CC.
COMBINA implements the formula: (Count1+Count2-1)! / (Count2!(Count1-1)!)
=COMBINA(3;2) returns 6.
CONVERT_OOO
Converts a value from one unit of measurement to another unit of measurement. The conversion factors are given in a list in the configuration.
At one time the list of conversion factors included the legacy European currencies and the Euro (see examples below). We suggest using the new function EUROCONVERT for converting these currencies.
CONVERT_OOO(value;"text";"text")
=CONVERT_OOO(100;"ATS";"EUR") returns the Euro value of 100 Austrian Schillings.
=CONVERT_OOO(100;"EUR";"DEM") converts 100 Euros into German Marks.
COS
Returns the cosine of the given angle (in radians).
COS(Number)
Returns the (trigonometric) cosine of Number, the angle in radians.
To return the cosine of an angle in degrees, use the RADIANS function.
=COS(PI()*2) returns 1, the cosine of 2*PI radians.
=COS(RADIANS(60)) returns 0.5, the cosine of 60 degrees.
COSH
Returns the hyperbolic cosine of a number.
COSH(Number)
Returns the hyperbolic cosine of Number.
=COSH(0) returns 1, the hyperbolic cosine of 0.
COT
Returns the cotangent of the given angle (in radians).
COT(Number)
Returns the (trigonometric) cotangent of Number, the angle in radians.
To return the cotangent of an angle in degrees, use the RADIANS function.
The cotangent of an angle is equivalent to 1 divided by the tangent of that angle.
Examples:
=COT(PI()/4) returns 1, the cotangent of PI/4 radians.
=COT(RADIANS(45)) returns 1, the cotangent of 45 degrees.
COTH
Returns the hyperbolic cotangent of a given number (angle).
COTH(Number)
Returns the hyperbolic cotangent of Number.
=COTH(1) returns the hyperbolic cotangent of 1, approximately 1.3130.
CSC
Returns the cosecant of the given angle (in radians). The cosecant of an angle is equivalent to 1 divided by the sine of that angle
CSC(Number)
Returns the (trigonometric) cosecant of Number, the angle in radians.
To return the cosecant of an angle in degrees, use the RADIANS function.
=CSC(PI()/4) returns approximately 1.4142135624, the inverse of the sine of PI/4 radians.
=CSC(RADIANS(30)) returns 2, the cosecant of 30 degrees.
CSCH
Returns the hyperbolic cosecant of a number.
CSCH(Number)
Returns the hyperbolic cosecant of Number.
=CSCH(1) returns approximately 0.8509181282, the hyperbolic cosecant of 1.
DEGREES
Converts radians into degrees.
DEGREES(Number)
Number is the angle in radians to be converted to degrees.
=DEGREES(PI()) returns 180 degrees.
EUROCONVERT
Converts between old European national currency and to and from Euros.
EUROCONVERT(Value; "From_currency"; "To_currency", full_precision, triangulation_precision)
Value is the amount of the currency to be converted.
From_currency and To_currency are the currency units to convert from and to respectively. These must be text, the official abbreviation for the currency (for example, "EUR"). The rates (shown per Euro) were set by the European Commission.
Full_precision is optional. If omitted or False, the result is rounded according to the decimals of the To currency. If Full_precision is True, the result is not rounded.
Triangulation_precision is optional. If Triangulation_precision is given and >=3, the intermediate result of a triangular conversion (currency1,EUR,currency2) is rounded to that precision. If Triangulation_precision is omitted, the intermediate result is not rounded. Also if To currency is "EUR", Triangulation_precision is used as if triangulation was needed and conversion from EUR to EUR was applied.
Examples
=EUROCONVERT(100;"ATS";"EUR") converts 100 Austrian Schillings into Euros.
=EUROCONVERT(100;"EUR";"DEM") converts 100 Euros into German Marks.
EVEN
Rounds a positive number up to the next even integer and a negative number down to the next even integer.
EVEN(Number)
Returns Number rounded to the next even integer up, away from zero.
=EVEN(2.3) returns 4.
=EVEN(2) returns 2.
=EVEN(0) returns 0.
=EVEN(-0.5) returns -2.
EXP
Returns e raised to the power of a number. The constant e has a value of approximately 2.71828182845904.
EXP(Number)
Number is the power to which e is to be raised.
=EXP(1) returns 2.71828182845904, the mathematical constant e to Calc's accuracy.
FACT
Returns the factorial of a number.
FACT(Number)
Returns Number!, the factorial of Number, calculated as 1*2*3*4* ... * Number.
=FACT(0) returns 1 by definition.
The factorial of a negative number returns the "invalid argument" error.
=FACT(3) returns 6.
=FACT(0) returns 1.
FLOOR
Rounds a number down to the nearest multiple of Significance.
FLOOR(Number; Significance; Mode)
Number is the number that is to be rounded down.
Significance is the value to whose multiple the number is to be rounded down.
Mode is an optional value. If the Mode value is given and not equal to zero, and if Number and Significance are negative, then rounding is done based on the absolute value of Number, i.e. negative numbers are rounded towards zero. If the Mode value is equal to zero or is not given, negative numbers are rounded away from zero.
If the spreadsheet is exported to Microsoft Excel, the FLOOR function is exported as the equivalent FLOOR.MATH function that exists since Excel 2013. If you plan to use the spreadsheet with earlier Excel versions, use either FLOOR.PRECISE that exists since Excel 2010, or FLOOR.XCL that is exported as the FLOOR function compatible with all Excel versions. Note that FLOOR.XCL always rounds towards zero.
=FLOOR( -11;-2) returns -12
=FLOOR( -11;-2;0) returns -12
=FLOOR( -11;-2;1) returns -10
FLOOR.PRECISE
Rounds a number down to the nearest multiple of Significance, regardless of sign of Significance
FLOOR.PRECISE(Number; Significance)
Number is the number that is to be rounded down.
Significance is the value to whose multiple the number is to be rounded down.
=FLOOR.PRECISE( -11;-2) returns -12
GCD
Returns the greatest common divisor of two or more integers.
The greatest common divisor is the positive largest integer which will divide, without remainder, each of the given integers.
GCD(Integer1; Integer2; ...; Integer30)
Integer1 To 30 are up to 30 integers whose greatest common divisor is to be calculated.
=GCD(16;32;24) gives the result 8, because 8 is the largest number that can divide 16, 24 and 32 without a remainder.
=GCD(B1:B3) where cells B1, B2, B3 contain 9, 12, 9 gives 3.
GCD_EXCEL2003
The result is the greatest common divisor of a list of numbers.
The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.
GCD_EXCEL2003(Number(s))
Number(s) is a list of up to 30 numbers.
=GCD_EXCEL2003(5;15;25) returns 5.
INT
Rounds a number down to the nearest integer.
INT(Number)
Returns Number rounded down to the nearest integer.
Negative numbers round down to the integer below.
=INT(5.7) returns 5.
=INT(-1.3) returns -2.
ISO.CEILING
Rounds a number up to the nearest multiple of Significance, regardless of sign of Significance
ISO.CEILING(Number; Significance)
Number (required) is the number that is to be rounded up.
Significance (optional) is the number to whose multiple the value is to be rounded up.
=ISO.CEILING(-11;-2) returns -10
LCM
Returns the least common multiple of one or more integers.
LCM(Integer1; Integer2; ...; Integer30)
Integer1 to 30 are up to 30 integers whose lowest common multiple is to be calculated.
If you enter the numbers 512;1024 and 2000 in the Integer 1;2 and 3 text boxes, 128000 will be returned as the result.
LCM_EXCEL2003
The result is the lowest common multiple of a list of numbers.
The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.
LCM_EXCEL2003(Number(s))
Number(s) is a list of up to 30 numbers.
=LCM_EXCEL2003(5;15;25) returns 75.
LN
Returns the natural logarithm based on the constant e of a number. The constant e has a value of approximately 2.71828182845904.
LN(Number)
Number is the value whose natural logarithm is to be calculated.
=LN(3) returns the natural logarithm of 3 (approximately 1.0986).
=LN(EXP(321)) returns 321.
LOG
Returns the logarithm of a number to the specified base.
LOG(Number; Base)
Number is the value whose logarithm is to be calculated.
Base (optional) is the base for the logarithm calculation. If omitted, Base 10 is assumed.
=LOG(10;3) returns the logarithm to base 3 of 10 (approximately 2.0959).
=LOG(7^4;7) returns 4.
LOG10
Returns the base-10 logarithm of a number.
LOG10(Number)
Returns the logarithm to base 10 of Number.
=LOG10(5) returns the base-10 logarithm of 5 (approximately 0.69897).
MOD
Returns the remainder when one integer is divided by another.
MOD(Dividend; Divisor)
For integer arguments this function returns Dividend modulo Divisor, that is the remainder when Dividend is divided by Divisor.
This function is implemented as Dividend - Divisor * INT(Dividend/Divisor) , and this formula gives the result if the arguments are not integer.
=MOD(22;3) returns 1, the remainder when 22 is divided by 3.
=MOD(11.25;2.5) returns 1.25.
MROUND
Returns a number rounded to the nearest multiple of another number.
MROUND(Number; Multiple)
Returns Number rounded to the nearest multiple of Multiple.
An alternative implementation would be Multiple * ROUND(Number/Multiple).
=MROUND(15.5;3) returns 15, as 15.5 is closer to 15 (= 3*5) than to 18 (= 3*6).
=MROUND(1.4;0.5) returns 1.5 (= 0.5*3).
MULTINOMIAL
Returns the factorial of the sum of the arguments divided by the product of the factorials of the arguments.
MULTINOMIAL(Number(s))
Number(s) is a list of up to 30 numbers.
=MULTINOMIAL(F11:H11) returns 1260, if F11 to H11 contain the values 2, 3 and 4. This corresponds to the formula =(2+3+4)! / (2!*3!*4!)
ODD
Rounds a positive number up to the nearest odd integer and a negative number down to the nearest odd integer.
ODD(Number)
Returns Number rounded to the next odd integer up, away from zero.
=ODD(1.2) returns 3.
=ODD(1) returns 1.
=ODD(0) returns 1.
=ODD(-3.1) returns -5.
PI
Returns 3.14159265358979, the value of the mathematical constant PI to 14 decimal places.
PI()
=PI() returns 3.14159265358979.
POWER
Returns a number raised to another number.
POWER(Base; Exponent)
Returns Base raised to the power of Exponent.
The same result may be achieved by using the exponentiation operator ^:
Base^Exponent
=POWER(4;3) returns 64, which is 4 to the power of 3.
=4^3 also returns 4 to the power of 3.
PRODUCT
Multiplies all the numbers given as arguments and returns the product.
PRODUCT(Number1; Number2; ...; Number30)
Number1 to 30 are up to 30 arguments whose product is to be calculated.
PRODUCT returns number1 * number2 * number3 * ...
=PRODUCT(2;3;4) returns 24.
QUOTIENT
Returns the integer part of a division operation.
QUOTIENT(Numerator; Denominator)
Returns the integer part of Numerator divided by Denominator.
QUOTIENT is equivalent to INT(numerator/denominator) for same-sign numerator and denominator, except that it may report errors with different error codes. More generally, it is equivalent to INT(numerator/denominator/SIGN(numerator/denominator))*SIGN(numerator/denominator).
=QUOTIENT(11;3) returns 3. The remainder of 2 is lost.
RADIANS
Converts degrees to radians.
RADIANS(Number)
Number is the angle in degrees to be converted to radians.
=RADIANS(90) returns 1.5707963267949, which is PI/2 to Calc's accuracy.
RAND
Returns a random number between 0 and 1.
RAND()
This function produces a new random number each time Calc recalculates. To force Calc to recalculate manually press F9.
To generate random numbers which never recalculate, copy cells each containing =RAND(), and use (with and not marked and marked).
=RAND() returns a random number between 0 and 1.
RANDBETWEEN
Returns an integer random number in a specified range.
RANDBETWEEN(Bottom; Top)
Returns an integer random number between integers Bottom and Top (both inclusive).
This function produces a new random number each time Calc recalculates. To force Calc to recalculate manually press F9.
To generate random numbers which never recalculate, copy cells containing this function, and use (with and not marked and marked).
=RANDBETWEEN(20;30) returns an integer of between 20 and 30.
ROUND
Rounds a number to a certain number of decimal places.
ROUND(Number; Count)
Returns Number rounded to Count decimal places. If Count is omitted or zero, the function rounds to the nearest integer. If Count is negative, the function rounds to the nearest 10, 100, 1000, etc.
This function rounds to the nearest number. See ROUNDDOWN and ROUNDUP for alternatives.
=ROUND(2.348;2) returns 2.35
=ROUND(-32.4834;3) returns -32.483. Change the cell format to see all decimals.
=ROUND(2.348;0) returns 2.
=ROUND(2.5) returns 3.
=ROUND(987.65;-2) returns 1000.
ROUNDDOWN
Rounds a number down, toward zero, to a certain precision.
ROUNDDOWN(Number; Count)
Returns Number rounded down (towards zero) to Count decimal places. If Count is omitted or zero, the function rounds down to an integer. If Count is negative, the function rounds down to the next 10, 100, 1000, etc.
This function rounds towards zero. See ROUNDUP and ROUND for alternatives.
=ROUNDDOWN(1.234;2) returns 1.23.
=ROUNDDOWN(45.67;0) returns 45.
=ROUNDDOWN(-45.67) returns -45.
=ROUNDDOWN(987.65;-2) returns 900.
ROUNDUP
Rounds a number up, away from zero, to a certain precision.
ROUNDUP(Number; Count)
Returns Number rounded up (away from zero) to Count decimal places. If Count is omitted or zero, the function rounds up to an integer. If Count is negative, the function rounds up to the next 10, 100, 1000, etc.
This function rounds away from zero. See ROUNDDOWN and ROUND for alternatives.
=ROUNDUP(1.1111;2) returns 1.12.
=ROUNDUP(1.2345;1) returns 1.3.
=ROUNDUP(45.67;0) returns 46.
=ROUNDUP(-45.67) returns -46.
=ROUNDUP(987.65;-2) returns 1000.
SEC
Returns the secant of the given angle (in radians). The secant of an angle is equivalent to 1 divided by the cosine of that angle
SEC(Number)
Returns the (trigonometric) secant of Number, the angle in radians.
To return the secant of an angle in degrees, use the RADIANS function.
=SEC(PI()/4) returns approximately 1.4142135624, the inverse of the cosine of PI/4 radians.
=SEC(RADIANS(60)) returns 2, the secant of 60 degrees.
SECH
Returns the hyperbolic secant of a number.
SECH(Number)
Returns the hyperbolic secant of Number.
=SECH(0) returns 1, the hyperbolic secant of 0.
SERIESSUM
Sums the first terms of a power series.
SERIESSUM(x;n;m;coefficients) = coefficient_1*x^n + coefficient_2*x^(n+m) + coefficient_3*x^(n+2m) +...+ coefficient_i*x^(n+(i-1)m)
SERIESSUM(X; N; M; Coefficients)
X is the input value for the power series.
N is the initial power
M is the increment to increase N
Coefficients is a series of coefficients. For each coefficient the series sum is extended by one section.
SIGN
Returns the sign of a number. Returns 1 if the number is positive, -1 if negative and 0 if zero.
SIGN(Number)
Number is the number whose sign is to be determined.
=SIGN(3.4) returns 1.
=SIGN(-4.5) returns -1.
SIN
Returns the sine of the given angle (in radians).
SIN(Number)
Returns the (trigonometric) sine of Number, the angle in radians.
To return the sine of an angle in degrees, use the RADIANS function.
=SIN(PI()/2) returns 1, the sine of PI/2 radians.
=SIN(RADIANS(30)) returns 0.5, the sine of 30 degrees.
SINH
Returns the hyperbolic sine of a number.
SINH(Number)
Returns the hyperbolic sine of Number.
=SINH(0) returns 0, the hyperbolic sine of 0.
SQRT
Returns the positive square root of a number.
SQRT(Number)
Returns the positive square root of Number.
Number must be positive.
=SQRT(16) returns 4.
=SQRT(-16) returns an invalid argument error.
SQRTPI
Returns the square root of (PI times a number).
SQRTPI(Number)
Returns the positive square root of (PI multiplied by Number).
This is equivalent to SQRT(PI()*Number).
=SQRTPI(2) returns the squareroot of (2PI), approximately 2.506628.
SUBTOTAL
Calculates subtotals. If a range already contains subtotals, these are not used for further calculations. Use this function with the AutoFilters to take only the filtered records into account.
SUBTOTAL(Function; Range)
Function is a number that stands for one of the following functions:
|
Function index (includes hidden values) |
Function index (ignores hidden values) |
Function |
|
1 |
101 |
AVERAGE |
|
2 |
102 |
COUNT |
|
3 |
103 |
COUNTA |
|
4 |
104 |
MAX |
|
5 |
105 |
MIN |
|
6 |
106 |
PRODUCT |
|
7 |
107 |
STDEV |
|
8 |
108 |
STDEVP |
|
9 |
109 |
SUM |
|
10 |
110 |
VAR |
|
11 |
111 |
VARP |
Use numbers 1-11 to include manually hidden rows or 101-111 to exclude them; filtered-out cells are always excluded.
Range is the range whose cells are included.
You have a table in the cell range A1:B6 containing a bill of material for 10 students. Row 2 (Pen) is manually hidden. You want to see the sum of the figures that are displayed; that is, just the subtotal for the filtered rows. In this case the correct formula would be:
|
A |
B |
|
|
1 |
ITEM |
QUANTITY |
|
2 |
Pen |
10 |
|
3 |
Pencil |
10 |
|
4 |
Notebook |
10 |
|
5 |
Rubber |
10 |
|
6 |
Sharpener |
10 |
=SUBTOTAL(9;B2:B6) returns 50.
=SUBTOTAL(109;B2:B6) returns 40.
SUM
Adds all the numbers in a range of cells.
SUM(Number1; Number2; ...; Number30)
Number 1 to Number 30 are up to 30 arguments whose sum is to be calculated.
If you enter the numbers 2; 3 and 4 in the Number 1; 2 and 3 text boxes, 9 will be returned as the result.
=SUM(A1;A3;B5) calculates the sum of the three cells. =SUM (A1:E10) calculates the sum of all cells in the A1 to E10 cell range.
Conditions linked by AND can be used with the function SUM() in the following manner:
Example assumption: You have entered invoices into a table. Column A contains the date value of the invoice, column B the amounts. You want to find a formula that you can use to return the total of all amounts only for a specific month, e.g. only the amount for the period >=2008-01-01 to <2008-02-01. The range with the date values covers A1:A40, the range containing the amounts to be totaled is B1:B40. C1 contains the start date, 2008-01-01, of the invoices to be included and C2 the date, 2008-02-01, that is no longer included.
Enter the following formula as an array formula:
=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)
In order to enter this as an array formula, you must press the Shift+Command + Ctrl+ Enter keys instead of simply pressing the Enter key to close the formula. The formula will then be shown in the Formula bar enclosed in braces.
{=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}
The formula is based on the fact that the result of a comparison is 1 if the criterion is met and 0 if it is not met. The individual comparison results will be treated as an array and used in matrix multiplication, and at the end the individual values will be totaled to give the result matrix.
SUMIF
Adds the cells specified by a given criteria. This function is used to browse a range when you search for a certain value.
SUMIF(Range; Criteria; SumRange)
Range is the range to which the criteria are to be applied.
Criteria is the cell in which the search criterion is shown, or the search criterion itself. If the criteria is written into the formula, it has to be surrounded by double quotes.
SumRange is the range from which values are summed. If this parameter has not been indicated, the values found in the Range are summed.
SUMIF supports the reference concatenation operator (~) only in the Criteria parameter, and only if the optional SumRange parameter is not given.
To sum up only negative numbers: =SUMIF(A1:A10;"<0")
=SUMIF(A1:A10;">0";B1:10) - sums values from the range B1:B10 only if the corresponding values in the range A1:A10 are >0.
See COUNTIF() for some more syntax examples that can be used with SUMIF().
SUMSQ
If you want to calculate the sum of the squares of numbers (totaling up of the squares of the arguments), enter these into the text fields.
SUMSQ(Number1; Number2; ...; Number30)
Number1 to 30 are up to 30 arguments the sum of whose squares is to be calculated.
If you enter the numbers 2; 3 and 4 in the Number 1; 2 and 3 text boxes, 29 is returned as the result.
TAN
Returns the tangent of the given angle (in radians).
TAN(Number)
Returns the (trigonometric) tangent of Number, the angle in radians.
To return the tangent of an angle in degrees, use the RADIANS function.
=TAN(PI()/4) returns 1, the tangent of PI/4 radians.
=TAN(RADIANS(45)) returns 1, the tangent of 45 degrees.
TANH
Returns the hyperbolic tangent of a number.
TANH(Number)
Returns the hyperbolic tangent of Number.
=TANH(0) returns 0, the hyperbolic tangent of 0.
TRUNC
Truncates a number by removing decimal places.
TRUNC(Number; Count)
Returns Number with at most Count decimal places. Excess decimal places are simply removed, irrespective of sign.
TRUNC(Number; 0) behaves as INT(Number) for positive numbers, but effectively rounds towards zero for negative numbers.
The visible decimal places of the result are specified in Collabora Office - Preferences Tools - Options - Collabora Office Calc - Calculate.
=TRUNC(1.239;2) returns 1.23. The 9 is lost.
=TRUNC(-1.234999;3) returns -1.234. All the 9s are lost.